matita/matita/contribs/lambda-delta/Basic-2/substitution/lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic-2/grammar/term_weight.ma".
  16
  17 (* RELOCATION ***************************************************************)
  18
  19 inductive lift: term → nat → nat → term → Prop ≝
  20 | lift_sort   : ∀k,d,e. lift (⋆k) d e (⋆k)
  21 | lift_lref_lt: ∀i,d,e. i < d → lift (#i) d e (#i)
  22 | lift_lref_ge: ∀i,d,e. d ≤ i → lift (#i) d e (#(i + e))
  23 | lift_bind   : ∀I,V1,V2,T1,T2,d,e.
  24                 lift V1 d e V2 → lift T1 (d + 1) e T2 →
  25                 lift (𝕓{I} V1. T1) d e (𝕓{I} V2. T2)
  26 | lift_flat   : ∀I,V1,V2,T1,T2,d,e.
  27                 lift V1 d e V2 → lift T1 d e T2 →
  28                 lift (𝕗{I} V1. T1) d e (𝕗{I} V2. T2)
  29 .
  30
  31 interpretation "relocation" 'RLift T1 d e T2 = (lift T1 d e T2).
  32
  33 (* Basic properties *********************************************************)
  34
  35 lemma lift_lref_ge_minus: ∀d,e,i. d + e ≤ i → ↑[d, e] #(i - e) ≡ #i.
  36 #d #e #i #H >(plus_minus_m_m i e) in ⊢ (? ? ? ? %) /3/
  37 qed.
  38
  39 lemma lift_refl: ∀T,d. ↑[d, 0] T ≡ T.
  40 #T elim T -T
  41 [ //
  42 | #i #d elim (lt_or_ge i d) /2/
  43 | #I elim I -I /2/
  44 ]
  45 qed.
  46
  47 lemma lift_total: ∀T1,d,e. ∃T2. ↑[d,e] T1 ≡ T2.
  48 #T1 elim T1 -T1
  49 [ /2/
  50 | #i #d #e elim (lt_or_ge i d) /3/
  51 | * #I #V1 #T1 #IHV1 #IHT1 #d #e
  52   elim (IHV1 d e) -IHV1 #V2 #HV12
  53   [ elim (IHT1 (d+1) e) -IHT1 /3/
  54   | elim (IHT1 d e) -IHT1 /3/
  55   ]
  56 ]
  57 qed.
  58
  59 lemma lift_split: ∀d1,e2,T1,T2. ↑[d1, e2] T1 ≡ T2 → ∀d2,e1.
  60                                 d1 ≤ d2 → d2 ≤ d1 + e1 → e1 ≤ e2 →
  61                                 ∃∃T. ↑[d1, e1] T1 ≡ T & ↑[d2, e2 - e1] T ≡ T2.
  62 #d1 #e2 #T1 #T2 #H elim H -H d1 e2 T1 T2
  63 [ /3/
  64 | #i #d1 #e2 #Hid1 #d2 #e1 #Hd12 #_ #_
  65   lapply (lt_to_le_to_lt … Hid1 Hd12) -Hd12 #Hid2 /4/
  66 | #i #d1 #e2 #Hid1 #d2 #e1 #_ #Hd21 #He12
  67   lapply (transitive_le …(i+e1) Hd21 ?) /2/ -Hd21 #Hd21
  68   <(arith_d1 i e2 e1) // /3/
  69 | #I #V1 #V2 #T1 #T2 #d1 #e2 #_ #_ #IHV #IHT #d2 #e1 #Hd12 #Hd21 #He12
  70   elim (IHV … Hd12 Hd21 He12) -IHV #V0 #HV0a #HV0b
  71   elim (IHT (d2+1) … ? ? He12) /3 width = 5/
  72 | #I #V1 #V2 #T1 #T2 #d1 #e2 #_ #_ #IHV #IHT #d2 #e1 #Hd12 #Hd21 #He12
  73   elim (IHV … Hd12 Hd21 He12) -IHV #V0 #HV0a #HV0b
  74   elim (IHT d2 … ? ? He12) /3 width = 5/
  75 ]
  76 qed.
  77
  78 (* Basic forward lemmas *****************************************************)
  79
  80 lemma tw_lift: ∀d,e,T1,T2. ↑[d, e] T1 ≡ T2 → #[T1] = #[T2].
  81 #d #e #T1 #T2 #H elim H -d e T1 T2; normalize //
  82 qed.
  83
  84 (* Basic inversion lemmas ***************************************************)
  85
  86 fact lift_inv_refl_aux: ∀d,e,T1,T2. ↑[d, e] T1 ≡ T2 → e = 0 → T1 = T2.
  87 #d #e #T1 #T2 #H elim H -H d e T1 T2 /3/
  88 qed.
  89
  90 lemma lift_inv_refl: ∀d,T1,T2. ↑[d, 0] T1 ≡ T2 → T1 = T2.
  91 /2/ qed.
  92
  93 fact lift_inv_sort1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀k. T1 = ⋆k → T2 = ⋆k.
  94 #d #e #T1 #T2 * -d e T1 T2 //
  95 [ #i #d #e #_ #k #H destruct
  96 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
  97 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
  98 ]
  99 qed.
 100
 101 lemma lift_inv_sort1: ∀d,e,T2,k. ↑[d,e] ⋆k ≡ T2 → T2 = ⋆k.
 102 /2 width=5/ qed.
 103
 104 fact lift_inv_lref1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀i. T1 = #i →
 105                          (i < d ∧ T2 = #i) ∨ (d ≤ i ∧ T2 = #(i + e)).
 106 #d #e #T1 #T2 * -d e T1 T2
 107 [ #k #d #e #i #H destruct
 108 | #j #d #e #Hj #i #Hi destruct /3/
 109 | #j #d #e #Hj #i #Hi destruct /3/
 110 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 111 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 112 ]
 113 qed.
 114
 115 lemma lift_inv_lref1: ∀d,e,T2,i. ↑[d,e] #i ≡ T2 →
 116                       (i < d ∧ T2 = #i) ∨ (d ≤ i ∧ T2 = #(i + e)).
 117 /2/ qed.
 118
 119 lemma lift_inv_lref1_lt: ∀d,e,T2,i. ↑[d,e] #i ≡ T2 → i < d → T2 = #i.
 120 #d #e #T2 #i #H elim (lift_inv_lref1 … H) -H * //
 121 #Hdi #_ #Hid lapply (le_to_lt_to_lt … Hdi Hid) -Hdi Hid #Hdd
 122 elim (lt_refl_false … Hdd)
 123 qed.
 124
 125 lemma lift_inv_lref1_ge: ∀d,e,T2,i. ↑[d,e] #i ≡ T2 → d ≤ i → T2 = #(i + e).
 126 #d #e #T2 #i #H elim (lift_inv_lref1 … H) -H * //
 127 #Hid #_ #Hdi lapply (le_to_lt_to_lt … Hdi Hid) -Hdi Hid #Hdd
 128 elim (lt_refl_false … Hdd)
 129 qed.
 130
 131 fact lift_inv_bind1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 132                          ∀I,V1,U1. T1 = 𝕓{I} V1.U1 →
 133                          ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 134                                   T2 = 𝕓{I} V2. U2.
 135 #d #e #T1 #T2 * -d e T1 T2
 136 [ #k #d #e #I #V1 #U1 #H destruct
 137 | #i #d #e #_ #I #V1 #U1 #H destruct
 138 | #i #d #e #_ #I #V1 #U1 #H destruct
 139 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct /2 width=5/
 140 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct
 141 ]
 142 qed.
 143
 144 lemma lift_inv_bind1: ∀d,e,T2,I,V1,U1. ↑[d,e] 𝕓{I} V1. U1 ≡ T2 →
 145                       ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 146                                T2 = 𝕓{I} V2. U2.
 147 /2/ qed.
 148
 149 fact lift_inv_flat1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 150                          ∀I,V1,U1. T1 = 𝕗{I} V1.U1 →
 151                          ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 152                                   T2 = 𝕗{I} V2. U2.
 153 #d #e #T1 #T2 * -d e T1 T2
 154 [ #k #d #e #I #V1 #U1 #H destruct
 155 | #i #d #e #_ #I #V1 #U1 #H destruct
 156 | #i #d #e #_ #I #V1 #U1 #H destruct
 157 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct
 158 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct /2 width=5/
 159 ]
 160 qed.
 161
 162 lemma lift_inv_flat1: ∀d,e,T2,I,V1,U1. ↑[d,e] 𝕗{I} V1. U1 ≡ T2 →
 163                       ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 164                                T2 = 𝕗{I} V2. U2.
 165 /2/ qed.
 166
 167 fact lift_inv_sort2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀k. T2 = ⋆k → T1 = ⋆k.
 168 #d #e #T1 #T2 * -d e T1 T2 //
 169 [ #i #d #e #_ #k #H destruct
 170 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 171 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 172 ]
 173 qed.
 174
 175 lemma lift_inv_sort2: ∀d,e,T1,k. ↑[d,e] T1 ≡ ⋆k → T1 = ⋆k.
 176 /2 width=5/ qed.
 177
 178 fact lift_inv_lref2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀i. T2 = #i →
 179                          (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
 180 #d #e #T1 #T2 * -d e T1 T2
 181 [ #k #d #e #i #H destruct
 182 | #j #d #e #Hj #i #Hi destruct /3/
 183 | #j #d #e #Hj #i #Hi destruct <minus_plus_m_m /4/
 184 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 185 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 186 ]
 187 qed.
 188
 189 lemma lift_inv_lref2: ∀d,e,T1,i. ↑[d,e] T1 ≡ #i →
 190                       (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
 191 /2/ qed.
 192
 193 lemma lift_inv_lref2_lt: ∀d,e,T1,i. ↑[d,e] T1 ≡ #i → i < d → T1 = #i.
 194 #d #e #T1 #i #H elim (lift_inv_lref2 … H) -H * //
 195 #Hdi #_ #Hid lapply (le_to_lt_to_lt … Hdi Hid) -Hdi Hid #Hdd
 196 elim (plus_lt_false … Hdd)
 197 qed.
 198
 199 lemma lift_inv_lref2_ge: ∀d,e,T1,i. ↑[d,e] T1 ≡ #i → d + e ≤ i → T1 = #(i - e).
 200 #d #e #T1 #i #H elim (lift_inv_lref2 … H) -H * //
 201 #Hid #_ #Hdi lapply (le_to_lt_to_lt … Hdi Hid) -Hdi Hid #Hdd
 202 elim (plus_lt_false … Hdd)
 203 qed.
 204
 205 fact lift_inv_bind2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 206                          ∀I,V2,U2. T2 = 𝕓{I} V2.U2 →
 207                          ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 208                                   T1 = 𝕓{I} V1. U1.
 209 #d #e #T1 #T2 * -d e T1 T2
 210 [ #k #d #e #I #V2 #U2 #H destruct
 211 | #i #d #e #_ #I #V2 #U2 #H destruct
 212 | #i #d #e #_ #I #V2 #U2 #H destruct
 213 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct /2 width=5/
 214 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct
 215 ]
 216 qed.
 217
 218 lemma lift_inv_bind2: ∀d,e,T1,I,V2,U2. ↑[d,e] T1 ≡  𝕓{I} V2. U2 →
 219                       ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 220                                T1 = 𝕓{I} V1. U1.
 221 /2/ qed.
 222
 223 fact lift_inv_flat2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 224                          ∀I,V2,U2. T2 = 𝕗{I} V2.U2 →
 225                          ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 226                                   T1 = 𝕗{I} V1. U1.
 227 #d #e #T1 #T2 * -d e T1 T2
 228 [ #k #d #e #I #V2 #U2 #H destruct
 229 | #i #d #e #_ #I #V2 #U2 #H destruct
 230 | #i #d #e #_ #I #V2 #U2 #H destruct
 231 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct
 232 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct /2 width = 5/
 233 ]
 234 qed.
 235
 236 lemma lift_inv_flat2: ∀d,e,T1,I,V2,U2. ↑[d,e] T1 ≡  𝕗{I} V2. U2 →
 237                       ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 238                                T1 = 𝕗{I} V1. U1.
 239 /2/ qed.