matita/matita/contribs/lambda-delta/Basic-2/substitution/lift.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||  This file is distributed under the terms of the
   8     \   /  GNU General Public License Version 2
   9      \ /
  10       V_______________________________________________________________ *)
  11
  12 include "lambda-delta/syntax/term.ma".
  13
  14 (* RELOCATION ***************************************************************)
  15
  16 inductive lift: term → nat → nat → term → Prop ≝
  17 | lift_sort   : ∀k,d,e. lift (⋆k) d e (⋆k)
  18 | lift_lref_lt: ∀i,d,e. i < d → lift (#i) d e (#i)
  19 | lift_lref_ge: ∀i,d,e. d ≤ i → lift (#i) d e (#(i + e))
  20 | lift_bind   : ∀I,V1,V2,T1,T2,d,e.
  21                 lift V1 d e V2 → lift T1 (d + 1) e T2 →
  22                 lift (𝕓{I} V1. T1) d e (𝕓{I} V2. T2)
  23 | lift_flat   : ∀I,V1,V2,T1,T2,d,e.
  24                 lift V1 d e V2 → lift T1 d e T2 →
  25                 lift (𝕗{I} V1. T1) d e (𝕗{I} V2. T2)
  26 .
  27
  28 interpretation "relocation" 'RLift T1 d e T2 = (lift T1 d e T2).
  29
  30 (* Basic properties *********************************************************)
  31
  32 lemma lift_lref_ge_minus: ∀d,e,i. d + e ≤ i → ↑[d, e] #(i - e) ≡ #i.
  33 #d #e #i #H >(plus_minus_m_m i e) in ⊢ (? ? ? ? %) /3/
  34 qed.
  35
  36 lemma lift_refl: ∀T,d. ↑[d, 0] T ≡ T.
  37 #T elim T -T
  38 [ //
  39 | #i #d elim (lt_or_ge i d) /2/
  40 | #I elim I -I /2/
  41 ]
  42 qed.
  43
  44 lemma lift_total: ∀T1,d,e. ∃T2. ↑[d,e] T1 ≡ T2.
  45 #T1 elim T1 -T1
  46 [ /2/
  47 | #i #d #e elim (lt_or_ge i d) /3/
  48 | * #I #V1 #T1 #IHV1 #IHT1 #d #e
  49   elim (IHV1 d e) -IHV1 #V2 #HV12
  50   [ elim (IHT1 (d+1) e) -IHT1 /3/
  51   | elim (IHT1 d e) -IHT1 /3/
  52   ]
  53 ]
  54 qed.
  55
  56 lemma lift_split: ∀d1,e2,T1,T2. ↑[d1, e2] T1 ≡ T2 → ∀d2,e1.
  57                                 d1 ≤ d2 → d2 ≤ d1 + e1 → e1 ≤ e2 →
  58                                 ∃∃T. ↑[d1, e1] T1 ≡ T & ↑[d2, e2 - e1] T ≡ T2.
  59 #d1 #e2 #T1 #T2 #H elim H -H d1 e2 T1 T2
  60 [ /3/
  61 | #i #d1 #e2 #Hid1 #d2 #e1 #Hd12 #_ #_
  62   lapply (lt_to_le_to_lt … Hid1 Hd12) -Hd12 #Hid2 /4/
  63 | #i #d1 #e2 #Hid1 #d2 #e1 #_ #Hd21 #He12
  64   lapply (transitive_le …(i+e1) Hd21 ?) /2/ -Hd21 #Hd21
  65   <(arith_d1 i e2 e1) // /3/
  66 | #I #V1 #V2 #T1 #T2 #d1 #e2 #_ #_ #IHV #IHT #d2 #e1 #Hd12 #Hd21 #He12
  67   elim (IHV … Hd12 Hd21 He12) -IHV #V0 #HV0a #HV0b
  68   elim (IHT (d2+1) … ? ? He12) /3 width = 5/
  69 | #I #V1 #V2 #T1 #T2 #d1 #e2 #_ #_ #IHV #IHT #d2 #e1 #Hd12 #Hd21 #He12
  70   elim (IHV … Hd12 Hd21 He12) -IHV #V0 #HV0a #HV0b
  71   elim (IHT d2 … ? ? He12) /3 width = 5/
  72 ]
  73 qed.
  74
  75 (* Basic inversion lemmas ***************************************************)
  76
  77 lemma lift_inv_refl_aux: ∀d,e,T1,T2. ↑[d, e] T1 ≡ T2 → e = 0 → T1 = T2.
  78 #d #e #T1 #T2 #H elim H -H d e T1 T2 /3/
  79 qed.
  80
  81 lemma lift_inv_refl: ∀d,T1,T2. ↑[d, 0] T1 ≡ T2 → T1 = T2.
  82 /2/ qed.
  83
  84 lemma lift_inv_sort1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀k. T1 = ⋆k → T2 = ⋆k.
  85 #d #e #T1 #T2 * -d e T1 T2 //
  86 [ #i #d #e #_ #k #H destruct
  87 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
  88 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
  89 ]
  90 qed.
  91
  92 lemma lift_inv_sort1: ∀d,e,T2,k. ↑[d,e] ⋆k ≡ T2 → T2 = ⋆k.
  93 /2 width=5/ qed.
  94
  95 lemma lift_inv_lref1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀i. T1 = #i →
  96                           (i < d ∧ T2 = #i) ∨ (d ≤ i ∧ T2 = #(i + e)).
  97 #d #e #T1 #T2 * -d e T1 T2
  98 [ #k #d #e #i #H destruct
  99 | #j #d #e #Hj #i #Hi destruct /3/
 100 | #j #d #e #Hj #i #Hi destruct /3/
 101 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 102 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 103 ]
 104 qed.
 105
 106 lemma lift_inv_lref1: ∀d,e,T2,i. ↑[d,e] #i ≡ T2 →
 107                       (i < d ∧ T2 = #i) ∨ (d ≤ i ∧ T2 = #(i + e)).
 108 /2/ qed.
 109
 110 lemma lift_inv_lref1_lt: ∀d,e,T2,i. ↑[d,e] #i ≡ T2 → i < d → T2 = #i.
 111 #d #e #T2 #i #H elim (lift_inv_lref1 … H) -H * //
 112 #Hdi #_ #Hid lapply (le_to_lt_to_lt … Hdi Hid) -Hdi Hid #Hdd
 113 elim (lt_refl_false … Hdd)
 114 qed.
 115
 116 lemma lift_inv_lref1_ge: ∀d,e,T2,i. ↑[d,e] #i ≡ T2 → d ≤ i → T2 = #(i + e).
 117 #d #e #T2 #i #H elim (lift_inv_lref1 … H) -H * //
 118 #Hid #_ #Hdi lapply (le_to_lt_to_lt … Hdi Hid) -Hdi Hid #Hdd
 119 elim (lt_refl_false … Hdd)
 120 qed.
 121
 122 lemma lift_inv_bind1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 123                           ∀I,V1,U1. T1 = 𝕓{I} V1.U1 →
 124                           ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 125                                    T2 = 𝕓{I} V2. U2.
 126 #d #e #T1 #T2 * -d e T1 T2
 127 [ #k #d #e #I #V1 #U1 #H destruct
 128 | #i #d #e #_ #I #V1 #U1 #H destruct
 129 | #i #d #e #_ #I #V1 #U1 #H destruct
 130 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct /2 width=5/
 131 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct
 132 ]
 133 qed.
 134
 135 lemma lift_inv_bind1: ∀d,e,T2,I,V1,U1. ↑[d,e] 𝕓{I} V1. U1 ≡ T2 →
 136                       ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 137                                T2 = 𝕓{I} V2. U2.
 138 /2/ qed.
 139
 140 lemma lift_inv_flat1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 141                           ∀I,V1,U1. T1 = 𝕗{I} V1.U1 →
 142                           ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 143                                    T2 = 𝕗{I} V2. U2.
 144 #d #e #T1 #T2 * -d e T1 T2
 145 [ #k #d #e #I #V1 #U1 #H destruct
 146 | #i #d #e #_ #I #V1 #U1 #H destruct
 147 | #i #d #e #_ #I #V1 #U1 #H destruct
 148 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct
 149 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct /2 width=5/
 150 ]
 151 qed.
 152
 153 lemma lift_inv_flat1: ∀d,e,T2,I,V1,U1. ↑[d,e] 𝕗{I} V1. U1 ≡ T2 →
 154                       ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 155                                T2 = 𝕗{I} V2. U2.
 156 /2/ qed.
 157
 158 lemma lift_inv_sort2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀k. T2 = ⋆k → T1 = ⋆k.
 159 #d #e #T1 #T2 * -d e T1 T2 //
 160 [ #i #d #e #_ #k #H destruct
 161 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 162 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 163 ]
 164 qed.
 165
 166 lemma lift_inv_sort2: ∀d,e,T1,k. ↑[d,e] T1 ≡ ⋆k → T1 = ⋆k.
 167 /2 width=5/ qed.
 168
 169 lemma lift_inv_lref2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀i. T2 = #i →
 170                           (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
 171 #d #e #T1 #T2 * -d e T1 T2
 172 [ #k #d #e #i #H destruct
 173 | #j #d #e #Hj #i #Hi destruct /3/
 174 | #j #d #e #Hj #i #Hi destruct <minus_plus_m_m /4/
 175 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 176 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 177 ]
 178 qed.
 179
 180 lemma lift_inv_lref2: ∀d,e,T1,i. ↑[d,e] T1 ≡ #i →
 181                       (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
 182 /2/ qed.
 183
 184 lemma lift_inv_lref2_lt: ∀d,e,T1,i. ↑[d,e] T1 ≡ #i → i < d → T1 = #i.
 185 #d #e #T1 #i #H elim (lift_inv_lref2 … H) -H * //
 186 #Hdi #_ #Hid lapply (le_to_lt_to_lt … Hdi Hid) -Hdi Hid #Hdd
 187 elim (plus_lt_false … Hdd)
 188 qed.
 189
 190 lemma lift_inv_lref2_ge: ∀d,e,T1,i. ↑[d,e] T1 ≡ #i → d + e ≤ i → T1 = #(i - e).
 191 #d #e #T1 #i #H elim (lift_inv_lref2 … H) -H * //
 192 #Hid #_ #Hdi lapply (le_to_lt_to_lt … Hdi Hid) -Hdi Hid #Hdd
 193 elim (plus_lt_false … Hdd)
 194 qed.
 195
 196 lemma lift_inv_bind2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 197                           ∀I,V2,U2. T2 = 𝕓{I} V2.U2 →
 198                           ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 199                                    T1 = 𝕓{I} V1. U1.
 200 #d #e #T1 #T2 * -d e T1 T2
 201 [ #k #d #e #I #V2 #U2 #H destruct
 202 | #i #d #e #_ #I #V2 #U2 #H destruct
 203 | #i #d #e #_ #I #V2 #U2 #H destruct
 204 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct /2 width=5/
 205 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct
 206 ]
 207 qed.
 208
 209 lemma lift_inv_bind2: ∀d,e,T1,I,V2,U2. ↑[d,e] T1 ≡  𝕓{I} V2. U2 →
 210                       ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 211                                T1 = 𝕓{I} V1. U1.
 212 /2/ qed.
 213
 214 lemma lift_inv_flat2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 215                           ∀I,V2,U2. T2 = 𝕗{I} V2.U2 →
 216                           ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 217                                    T1 = 𝕗{I} V1. U1.
 218 #d #e #T1 #T2 * -d e T1 T2
 219 [ #k #d #e #I #V2 #U2 #H destruct
 220 | #i #d #e #_ #I #V2 #U2 #H destruct
 221 | #i #d #e #_ #I #V2 #U2 #H destruct
 222 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct
 223 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct /2 width = 5/
 224 ]
 225 qed.
 226
 227 lemma lift_inv_flat2: ∀d,e,T1,I,V2,U2. ↑[d,e] T1 ≡  𝕗{I} V2. U2 →
 228                       ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 229                                T1 = 𝕗{I} V1. U1.
 230 /2/ qed.