matita/matita/contribs/lambda-delta/Basic-2/substitution/tps.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic-2/substitution/drop.ma".
  16
  17 (* PARALLEL SUBSTITUTION ON TERMS *******************************************)
  18
  19 inductive tps: lenv → term → nat → nat → term → Prop ≝
  20 | tps_sort : ∀L,k,d,e. tps L (⋆k) d e (⋆k)
  21 | tps_lref : ∀L,i,d,e. tps L (#i) d e (#i)
  22 | tps_subst: ∀L,K,V,W,i,d,e. d ≤ i → i < d + e →
  23              ↓[0, i] L ≡ K. 𝕓{Abbr} V → ↑[0, i + 1] V ≡ W → tps L (#i) d e W
  24 | tps_bind : ∀L,I,V1,V2,T1,T2,d,e.
  25              tps L V1 d e V2 → tps (L. 𝕓{I} V1) T1 (d + 1) e T2 →
  26              tps L (𝕓{I} V1. T1) d e (𝕓{I} V2. T2)
  27 | tps_flat : ∀L,I,V1,V2,T1,T2,d,e.
  28              tps L V1 d e V2 → tps L T1 d e T2 →
  29              tps L (𝕗{I} V1. T1) d e (𝕗{I} V2. T2)
  30 .
  31
  32 interpretation "parallel substritution (term)"
  33    'PSubst L T1 d e T2 = (tps L T1 d e T2).
  34
  35 (* Basic properties *********************************************************)
  36
  37 lemma tps_leq_repl: ∀L1,T1,T2,d,e. L1 ⊢ T1 [d, e] ≫ T2 →
  38                     ∀L2. L1 [d, e] ≈ L2 → L2 ⊢ T1 [d, e] ≫ T2.
  39 #L1 #T1 #T2 #d #e #H elim H -H L1 T1 T2 d e
  40 [ //
  41 | //
  42 | #L1 #K1 #V #W #i #d #e #Hdi #Hide #HLK1 #HVW #L2 #HL12
  43   elim (drop_leq_drop1 … HL12 … HLK1 ? ?) -HL12 HLK1 // /2/
  44 | /4/
  45 | /3/
  46 ]
  47 qed.
  48
  49 lemma tps_refl: ∀T,L,d,e. L ⊢ T [d, e] ≫ T.
  50 #T elim T -T //
  51 #I elim I -I /2/
  52 qed.
  53
  54 lemma tps_weak: ∀L,T1,T2,d1,e1. L ⊢ T1 [d1, e1] ≫ T2 →
  55                 ∀d2,e2. d2 ≤ d1 → d1 + e1 ≤ d2 + e2 →
  56                 L ⊢ T1 [d2, e2] ≫ T2.
  57 #L #T1 #T #d1 #e1 #H elim H -L T1 T d1 e1
  58 [ //
  59 | //
  60 | #L #K #V #W #i #d1 #e1 #Hid1 #Hide1 #HLK #HVW #d2 #e2 #Hd12 #Hde12
  61   lapply (transitive_le … Hd12 … Hid1) -Hd12 Hid1 #Hid2
  62   lapply (lt_to_le_to_lt … Hide1 … Hde12) -Hide1 /2/
  63 | /4/
  64 | /4/
  65 ]
  66 qed.
  67
  68 lemma tps_weak_top: ∀L,T1,T2,d,e.
  69                     L ⊢ T1 [d, e] ≫ T2 → L ⊢ T1 [d, |L| - d] ≫ T2.
  70 #L #T1 #T #d #e #H elim H -L T1 T d e
  71 [ //
  72 | //
  73 | #L #K #V #W #i #d #e #Hdi #_ #HLK #HVW
  74   lapply (drop_fwd_drop2_length … HLK) #Hi
  75   lapply (le_to_lt_to_lt … Hdi Hi) #Hd
  76   lapply (plus_minus_m_m_comm (|L|) d ?) /2/
  77 | normalize /2/
  78 | /2/
  79 ]
  80 qed.
  81
  82 lemma tps_weak_all: ∀L,T1,T2,d,e.
  83                     L ⊢ T1 [d, e] ≫ T2 → L ⊢ T1 [0, |L|] ≫ T2.
  84 #L #T1 #T #d #e #HT12
  85 lapply (tps_weak … HT12 0 (d + e) ? ?) -HT12 // #HT12
  86 lapply (tps_weak_top … HT12) //
  87 qed.
  88
  89 (* Basic inversion lemmas ***************************************************)
  90
  91 lemma tps_inv_lref1_aux: ∀L,T1,T2,d,e. L ⊢ T1 [d, e] ≫ T2 → ∀i. T1 = #i →
  92                          T2 = #i ∨
  93                          ∃∃K,V,i. d ≤ i & i < d + e &
  94                                   ↓[O, i] L ≡ K. 𝕓{Abbr} V &
  95                                   ↑[O, i + 1] V ≡ T2.
  96 #L #T1 #T2 #d #e * -L T1 T2 d e
  97 [ #L #k #d #e #i #H destruct
  98 | /2/
  99 | #L #K #V #T2 #i #d #e #Hdi #Hide #HLK #HVT2 #j #H destruct -i /3 width=7/
 100 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 101 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 102 ]
 103 qed.
 104
 105 lemma tps_inv_lref1: ∀L,T2,i,d,e. L ⊢ #i [d, e] ≫ T2 →
 106                      T2 = #i ∨
 107                      ∃∃K,V,i. d ≤ i & i < d + e &
 108                               ↓[O, i] L ≡ K. 𝕓{Abbr} V &
 109                               ↑[O, i + 1] V ≡ T2.
 110 /2/ qed.
 111
 112 lemma tps_inv_bind1_aux: ∀d,e,L,U1,U2. L ⊢ U1 [d, e] ≫ U2 →
 113                          ∀I,V1,T1. U1 = 𝕓{I} V1. T1 →
 114                          ∃∃V2,T2. L ⊢ V1 [d, e] ≫ V2 &
 115                                   L. 𝕓{I} V1 ⊢ T1 [d + 1, e] ≫ T2 &
 116                                   U2 =  𝕓{I} V2. T2.
 117 #d #e #L #U1 #U2 * -d e L U1 U2
 118 [ #L #k #d #e #I #V1 #T1 #H destruct
 119 | #L #i #d #e #I #V1 #T1 #H destruct
 120 | #L #K #V #W #i #d #e #_ #_ #_ #_ #I #V1 #T1 #H destruct
 121 | #L #J #V1 #V2 #T1 #T2 #d #e #HV12 #HT12 #I #V #T #H destruct /2 width=5/
 122 | #L #J #V1 #V2 #T1 #T2 #d #e #_ #_ #I #V #T #H destruct
 123 ]
 124 qed.
 125
 126 lemma tps_inv_bind1: ∀d,e,L,I,V1,T1,U2. L ⊢ 𝕓{I} V1. T1 [d, e] ≫ U2 →
 127                      ∃∃V2,T2. L ⊢ V1 [d, e] ≫ V2 &
 128                               L. 𝕓{I} V1 ⊢ T1 [d + 1, e] ≫ T2 &
 129                               U2 =  𝕓{I} V2. T2.
 130 /2/ qed.
 131
 132 lemma tps_inv_flat1_aux: ∀d,e,L,U1,U2. L ⊢ U1 [d, e] ≫ U2 →
 133                          ∀I,V1,T1. U1 = 𝕗{I} V1. T1 →
 134                          ∃∃V2,T2. L ⊢ V1 [d, e] ≫ V2 & L ⊢ T1 [d, e] ≫ T2 &
 135                                   U2 =  𝕗{I} V2. T2.
 136 #d #e #L #U1 #U2 * -d e L U1 U2
 137 [ #L #k #d #e #I #V1 #T1 #H destruct
 138 | #L #i #d #e #I #V1 #T1 #H destruct
 139 | #L #K #V #W #i #d #e #_ #_ #_ #_ #I #V1 #T1 #H destruct
 140 | #L #J #V1 #V2 #T1 #T2 #d #e #_ #_ #I #V #T #H destruct
 141 | #L #J #V1 #V2 #T1 #T2 #d #e #HV12 #HT12 #I #V #T #H destruct /2 width=5/
 142 ]
 143 qed.
 144
 145 lemma tps_inv_flat1: ∀d,e,L,I,V1,T1,U2. L ⊢ 𝕗{I} V1. T1 [d, e] ≫ U2 →
 146                      ∃∃V2,T2. L ⊢ V1 [d, e] ≫ V2 & L ⊢ T1 [d, e] ≫ T2 &
 147                               U2 =  𝕗{I} V2. T2.
 148 /2/ qed.