matita/matita/contribs/lambda-delta/Basic-2/substitution/tps.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic-2/substitution/drop.ma".
  16
  17 (* PARALLEL SUBSTITUTION ON TERMS *******************************************)
  18
  19 inductive tps: lenv → term → nat → nat → term → Prop ≝
  20 | tps_atom : ∀L,I,d,e. tps L (𝕒{I}) d e (𝕒{I})
  21 | tps_subst: ∀L,K,V,W,i,d,e. d ≤ i → i < d + e →
  22              ↓[0, i] L ≡ K. 𝕓{Abbr} V → ↑[0, i + 1] V ≡ W → tps L (#i) d e W
  23 | tps_bind : ∀L,I,V1,V2,T1,T2,d,e.
  24              tps L V1 d e V2 → tps (L. 𝕓{I} V2) T1 (d + 1) e T2 →
  25              tps L (𝕓{I} V1. T1) d e (𝕓{I} V2. T2)
  26 | tps_flat : ∀L,I,V1,V2,T1,T2,d,e.
  27              tps L V1 d e V2 → tps L T1 d e T2 →
  28              tps L (𝕗{I} V1. T1) d e (𝕗{I} V2. T2)
  29 .
  30
  31 interpretation "parallel substritution (term)"
  32    'PSubst L T1 d e T2 = (tps L T1 d e T2).
  33
  34 (* Basic properties *********************************************************)
  35
  36 lemma tps_leq_repl_dx: ∀L1,T1,T2,d,e. L1 ⊢ T1 [d, e] ≫ T2 →
  37                        ∀L2. L1 [d, e] ≈ L2 → L2 ⊢ T1 [d, e] ≫ T2.
  38 #L1 #T1 #T2 #d #e #H elim H -H L1 T1 T2 d e
  39 [ //
  40 | #L1 #K1 #V #W #i #d #e #Hdi #Hide #HLK1 #HVW #L2 #HL12
  41   elim (drop_leq_drop1 … HL12 … HLK1 ? ?) -HL12 HLK1 // /2/
  42 | /4/
  43 | /3/
  44 ]
  45 qed.
  46
  47 lemma tps_refl: ∀T,L,d,e. L ⊢ T [d, e] ≫ T.
  48 #T elim T -T //
  49 #I elim I -I /2/
  50 qed.
  51
  52 lemma tps_weak: ∀L,T1,T2,d1,e1. L ⊢ T1 [d1, e1] ≫ T2 →
  53                 ∀d2,e2. d2 ≤ d1 → d1 + e1 ≤ d2 + e2 →
  54                 L ⊢ T1 [d2, e2] ≫ T2.
  55 #L #T1 #T #d1 #e1 #H elim H -L T1 T d1 e1
  56 [ //
  57 | #L #K #V #W #i #d1 #e1 #Hid1 #Hide1 #HLK #HVW #d2 #e2 #Hd12 #Hde12
  58   lapply (transitive_le … Hd12 … Hid1) -Hd12 Hid1 #Hid2
  59   lapply (lt_to_le_to_lt … Hide1 … Hde12) -Hide1 /2/
  60 | /4/
  61 | /4/
  62 ]
  63 qed.
  64
  65 lemma tps_weak_top: ∀L,T1,T2,d,e.
  66                     L ⊢ T1 [d, e] ≫ T2 → L ⊢ T1 [d, |L| - d] ≫ T2.
  67 #L #T1 #T #d #e #H elim H -L T1 T d e
  68 [ //
  69 | #L #K #V #W #i #d #e #Hdi #_ #HLK #HVW
  70   lapply (drop_fwd_drop2_length … HLK) #Hi
  71   lapply (le_to_lt_to_lt … Hdi Hi) #Hd
  72   lapply (plus_minus_m_m_comm (|L|) d ?) /2/
  73 | normalize /2/
  74 | /2/
  75 ]
  76 qed.
  77
  78 lemma tps_weak_all: ∀L,T1,T2,d,e.
  79                     L ⊢ T1 [d, e] ≫ T2 → L ⊢ T1 [0, |L|] ≫ T2.
  80 #L #T1 #T #d #e #HT12
  81 lapply (tps_weak … HT12 0 (d + e) ? ?) -HT12 // #HT12
  82 lapply (tps_weak_top … HT12) //
  83 qed.
  84
  85 lemma tps_split_up: ∀L,T1,T2,d,e. L ⊢ T1 [d, e] ≫ T2 → ∀i. d ≤ i → i ≤ d + e →
  86                     ∃∃T. L ⊢ T1 [d, i - d] ≫ T & L ⊢ T [i, d + e - i] ≫ T2.
  87 #L #T1 #T2 #d #e #H elim H -L T1 T2 d e
  88 [ /2/
  89 | #L #K #V #W #i #d #e #Hdi #Hide #HLK #HVW #j #Hdj #Hjde
  90   elim (lt_or_ge i j)
  91   [ -Hide Hjde;
  92     >(plus_minus_m_m_comm j d) in ⊢ (% → ?) // -Hdj /3/
  93   | -Hdi Hdj; #Hid
  94     generalize in match Hide -Hide (**) (* rewriting in the premises, rewrites in the goal too *)
  95     >(plus_minus_m_m_comm … Hjde) in ⊢ (% → ?) -Hjde /4/
  96   ]
  97 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #i #Hdi #Hide
  98   elim (IHV12 i ? ?) -IHV12 // #V #HV1 #HV2
  99   elim (IHT12 (i + 1) ? ?) -IHT12 [2: /2 by arith4/ |3: /2/ ] (* just /2/ is too slow *)
 100   -Hdi Hide >arith_c1 >arith_c1x #T #HT1 #HT2
 101   lapply (tps_leq_repl_dx … HT1 (L. 𝕓{I} V) ?) -HT1 /3 width=5/
 102 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #i #Hdi #Hide
 103   elim (IHV12 i ? ?) -IHV12 // elim (IHT12 i ? ?) -IHT12 //
 104   -Hdi Hide /3 width=5/
 105 ]
 106 qed.
 107
 108 (* Basic inversion lemmas ***************************************************)
 109
 110 fact tps_inv_atom1_aux: ∀L,T1,T2,d,e. L ⊢ T1 [d, e] ≫ T2 → ∀I. T1 = 𝕒{I} →
 111                         T2 = 𝕒{I} ∨
 112                         ∃∃K,V,i. d ≤ i & i < d + e &
 113                                  ↓[O, i] L ≡ K. 𝕓{Abbr} V &
 114                                  ↑[O, i + 1] V ≡ T2 &
 115                                  I = LRef i.
 116 #L #T1 #T2 #d #e * -L T1 T2 d e
 117 [ #L #I #d #e #J #H destruct -I /2/
 118 | #L #K #V #T2 #i #d #e #Hdi #Hide #HLK #HVT2 #I #H destruct -I /3 width=8/
 119 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #J #H destruct
 120 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #J #H destruct
 121 ]
 122 qed.
 123
 124 lemma tps_inv_atom1: ∀L,T2,I,d,e. L ⊢ 𝕒{I} [d, e] ≫ T2 →
 125                      T2 = 𝕒{I} ∨
 126                      ∃∃K,V,i. d ≤ i & i < d + e &
 127                               ↓[O, i] L ≡ K. 𝕓{Abbr} V &
 128                               ↑[O, i + 1] V ≡ T2 &
 129                               I = LRef i.
 130 /2/ qed.
 131
 132
 133 (* Basic-1: was: subst1_gen_sort *)
 134 lemma tps_inv_sort1: ∀L,T2,k,d,e. L ⊢ ⋆k [d, e] ≫ T2 → T2 = ⋆k.
 135 #L #T2 #k #d #e #H
 136 elim (tps_inv_atom1 … H) -H //
 137 * #K #V #i #_ #_ #_ #_ #H destruct
 138 qed.
 139
 140 (* Basic-1: was: subst1_gen_lref *)
 141 lemma tps_inv_lref1: ∀L,T2,i,d,e. L ⊢ #i [d, e] ≫ T2 →
 142                      T2 = #i ∨
 143                      ∃∃K,V. d ≤ i & i < d + e &
 144                             ↓[O, i] L ≡ K. 𝕓{Abbr} V &
 145                             ↑[O, i + 1] V ≡ T2.
 146 #L #T2 #i #d #e #H
 147 elim (tps_inv_atom1 … H) -H /2/
 148 * #K #V #j #Hdj #Hjde #HLK #HVT2 #H destruct -i /3/
 149 qed.
 150
 151 fact tps_inv_bind1_aux: ∀d,e,L,U1,U2. L ⊢ U1 [d, e] ≫ U2 →
 152                         ∀I,V1,T1. U1 = 𝕓{I} V1. T1 →
 153                         ∃∃V2,T2. L ⊢ V1 [d, e] ≫ V2 &
 154                                  L. 𝕓{I} V2 ⊢ T1 [d + 1, e] ≫ T2 &
 155                                  U2 =  𝕓{I} V2. T2.
 156 #d #e #L #U1 #U2 * -d e L U1 U2
 157 [ #L #k #d #e #I #V1 #T1 #H destruct
 158 | #L #K #V #W #i #d #e #_ #_ #_ #_ #I #V1 #T1 #H destruct
 159 | #L #J #V1 #V2 #T1 #T2 #d #e #HV12 #HT12 #I #V #T #H destruct /2 width=5/
 160 | #L #J #V1 #V2 #T1 #T2 #d #e #_ #_ #I #V #T #H destruct
 161 ]
 162 qed.
 163
 164 lemma tps_inv_bind1: ∀d,e,L,I,V1,T1,U2. L ⊢ 𝕓{I} V1. T1 [d, e] ≫ U2 →
 165                      ∃∃V2,T2. L ⊢ V1 [d, e] ≫ V2 &
 166                               L. 𝕓{I} V2 ⊢ T1 [d + 1, e] ≫ T2 &
 167                               U2 =  𝕓{I} V2. T2.
 168 /2/ qed.
 169
 170 fact tps_inv_flat1_aux: ∀d,e,L,U1,U2. L ⊢ U1 [d, e] ≫ U2 →
 171                         ∀I,V1,T1. U1 = 𝕗{I} V1. T1 →
 172                         ∃∃V2,T2. L ⊢ V1 [d, e] ≫ V2 & L ⊢ T1 [d, e] ≫ T2 &
 173                                  U2 =  𝕗{I} V2. T2.
 174 #d #e #L #U1 #U2 * -d e L U1 U2
 175 [ #L #k #d #e #I #V1 #T1 #H destruct
 176 | #L #K #V #W #i #d #e #_ #_ #_ #_ #I #V1 #T1 #H destruct
 177 | #L #J #V1 #V2 #T1 #T2 #d #e #_ #_ #I #V #T #H destruct
 178 | #L #J #V1 #V2 #T1 #T2 #d #e #HV12 #HT12 #I #V #T #H destruct /2 width=5/
 179 ]
 180 qed.
 181
 182 lemma tps_inv_flat1: ∀d,e,L,I,V1,T1,U2. L ⊢ 𝕗{I} V1. T1 [d, e] ≫ U2 →
 183                      ∃∃V2,T2. L ⊢ V1 [d, e] ≫ V2 & L ⊢ T1 [d, e] ≫ T2 &
 184                               U2 =  𝕗{I} V2. T2.
 185 /2/ qed.
 186
 187 fact tps_inv_refl_O2_aux: ∀L,T1,T2,d,e. L ⊢ T1 [d, e] ≫ T2 → e = 0 → T1 = T2.
 188 #L #T1 #T2 #d #e #H elim H -H L T1 T2 d e
 189 [ //
 190 | #L #K #V #W #i #d #e #Hdi #Hide #_ #_ #H destruct -e;
 191   lapply (le_to_lt_to_lt … Hdi … Hide) -Hdi Hide <plus_n_O #Hdd
 192   elim (lt_refl_false … Hdd)
 193 | /3/
 194 | /3/
 195 ]
 196 qed.
 197
 198 lemma tps_inv_refl_O2: ∀L,T1,T2,d. L ⊢ T1 [d, 0] ≫ T2 → T1 = T2.
 199 /2 width=6/ qed.
 200
 201 (* Basic-1: removed theorems 23:
 202             subst0_gen_sort subst0_gen_lref subst0_gen_head subst0_gen_lift_lt
 203             subst0_gen_lift_false subst0_gen_lift_ge subst0_refl subst0_trans
 204             subst0_lift_lt subst0_lift_ge subst0_lift_ge_S subst0_lift_ge_s
 205             subst0_subst0 subst0_subst0_back subst0_weight_le subst0_weight_lt
 206             subst0_confluence_neq subst0_confluence_eq subst0_tlt_head
 207             subst0_confluence_lift subst0_tlt
 208             subst1_head subst1_gen_head
 209 *)