matita/matita/contribs/lambda-delta/Basic-2/substitution/tps.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic-2/substitution/drop.ma".
  16
  17 (* PARALLEL SUBSTITUTION ON TERMS *******************************************)
  18
  19 inductive tps: lenv → term → nat → nat → term → Prop ≝
  20 | tps_sort : ∀L,k,d,e. tps L (⋆k) d e (⋆k)
  21 | tps_lref : ∀L,i,d,e. tps L (#i) d e (#i)
  22 | tps_subst: ∀L,K,V,W,i,d,e. d ≤ i → i < d + e →
  23              ↓[0, i] L ≡ K. 𝕓{Abbr} V → ↑[0, i + 1] V ≡ W → tps L (#i) d e W
  24 | tps_bind : ∀L,I,V1,V2,T1,T2,d,e.
  25              tps L V1 d e V2 → tps (L. 𝕓{I} V1) T1 (d + 1) e T2 →
  26              tps L (𝕓{I} V1. T1) d e (𝕓{I} V2. T2)
  27 | tps_flat : ∀L,I,V1,V2,T1,T2,d,e.
  28              tps L V1 d e V2 → tps L T1 d e T2 →
  29              tps L (𝕗{I} V1. T1) d e (𝕗{I} V2. T2)
  30 .
  31
  32 interpretation "parallel substritution (term)"
  33    'PSubst L T1 d e T2 = (tps L T1 d e T2).
  34
  35 (* Basic properties *********************************************************)
  36
  37 lemma tps_leq_repl: ∀L1,T1,T2,d,e. L1 ⊢ T1 [d, e] ≫ T2 →
  38                     ∀L2. L1 [d, e] ≈ L2 → L2 ⊢ T1 [d, e] ≫ T2.
  39 #L1 #T1 #T2 #d #e #H elim H -H L1 T1 T2 d e
  40 [ //
  41 | //
  42 | #L1 #K1 #V #W #i #d #e #Hdi #Hide #HLK1 #HVW #L2 #HL12
  43   elim (drop_leq_drop1 … HL12 … HLK1 ? ?) -HL12 HLK1 // /2/
  44 | /4/
  45 | /3/
  46 ]
  47 qed.
  48
  49 lemma tps_refl: ∀T,L,d,e. L ⊢ T [d, e] ≫ T.
  50 #T elim T -T //
  51 #I elim I -I /2/
  52 qed.
  53
  54 lemma tps_weak: ∀L,T1,T2,d1,e1. L ⊢ T1 [d1, e1] ≫ T2 →
  55                 ∀d2,e2. d2 ≤ d1 → d1 + e1 ≤ d2 + e2 →
  56                 L ⊢ T1 [d2, e2] ≫ T2.
  57 #L #T1 #T #d1 #e1 #H elim H -L T1 T d1 e1
  58 [ //
  59 | //
  60 | #L #K #V #W #i #d1 #e1 #Hid1 #Hide1 #HLK #HVW #d2 #e2 #Hd12 #Hde12
  61   lapply (transitive_le … Hd12 … Hid1) -Hd12 Hid1 #Hid2
  62   lapply (lt_to_le_to_lt … Hide1 … Hde12) -Hide1 /2/
  63 | /4/
  64 | /4/
  65 ]
  66 qed.
  67
  68 lemma tps_weak_top: ∀L,T1,T2,d,e.
  69                     L ⊢ T1 [d, e] ≫ T2 → L ⊢ T1 [d, |L| - d] ≫ T2.
  70 #L #T1 #T #d #e #H elim H -L T1 T d e
  71 [ //
  72 | //
  73 | #L #K #V #W #i #d #e #Hdi #_ #HLK #HVW
  74   lapply (drop_fwd_drop2_length … HLK) #Hi
  75   lapply (le_to_lt_to_lt … Hdi Hi) #Hd
  76   lapply (plus_minus_m_m_comm (|L|) d ?) /2/
  77 | normalize /2/
  78 | /2/
  79 ]
  80 qed.
  81
  82 lemma tps_weak_all: ∀L,T1,T2,d,e.
  83                     L ⊢ T1 [d, e] ≫ T2 → L ⊢ T1 [0, |L|] ≫ T2.
  84 #L #T1 #T #d #e #HT12
  85 lapply (tps_weak … HT12 0 (d + e) ? ?) -HT12 // #HT12
  86 lapply (tps_weak_top … HT12) //
  87 qed.
  88
  89 lemma tps_split_up: ∀L,T1,T2,d,e. L ⊢ T1 [d, e] ≫ T2 → ∀i. d ≤ i → i ≤ d + e →
  90                     ∃∃T. L ⊢ T1 [d, i - d] ≫ T & L ⊢ T [i, d + e - i] ≫ T2.
  91 #L #T1 #T2 #d #e #H elim H -L T1 T2 d e
  92 [ /2/
  93 | /2/
  94 | #L #K #V #W #i #d #e #Hdi #Hide #HLK #HVW #j #Hdj #Hjde
  95   elim (lt_or_ge i j)
  96   [ -Hide Hjde;
  97     >(plus_minus_m_m_comm j d) in ⊢ (% → ?) // -Hdj /3/
  98   | -Hdi Hdj; #Hid
  99     generalize in match Hide -Hide (**) (* rewriting in the premises, rewrites in the goal too *)
 100     >(plus_minus_m_m_comm … Hjde) in ⊢ (% → ?) -Hjde /4/
 101   ]
 102 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #i #Hdi #Hide
 103   elim (IHV12 i ? ?) -IHV12 // #V #HV1 #HV2
 104   elim (IHT12 (i + 1) ? ?) -IHT12 [2: /2 by arith4/ |3: /2/ ] (* just /2/ is too slow *)
 105   -Hdi Hide >arith_c1 >arith_c1x #T #HT1 #HT2
 106   @ex2_1_intro [2,3: @tps_bind | skip ] (**) (* explicit constructors *)
 107   [3: @HV1 |4: @HT1 |5: // |1,2: skip | /3 width=5/ ]
 108 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #i #Hdi #Hide
 109   elim (IHV12 i ? ?) -IHV12 // elim (IHT12 i ? ?) -IHT12 //
 110   -Hdi Hide /3 width=5/
 111 ]
 112 qed.
 113
 114 (* Basic inversion lemmas ***************************************************)
 115
 116 fact tps_inv_lref1_aux: ∀L,T1,T2,d,e. L ⊢ T1 [d, e] ≫ T2 → ∀i. T1 = #i →
 117                         T2 = #i ∨
 118                         ∃∃K,V. d ≤ i & i < d + e &
 119                                ↓[O, i] L ≡ K. 𝕓{Abbr} V &
 120                                ↑[O, i + 1] V ≡ T2.
 121 #L #T1 #T2 #d #e * -L T1 T2 d e
 122 [ #L #k #d #e #i #H destruct
 123 | /2/
 124 | #L #K #V #T2 #i #d #e #Hdi #Hide #HLK #HVT2 #j #H destruct -i /3/
 125 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 126 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 127 ]
 128 qed.
 129
 130 lemma tps_inv_lref1: ∀L,T2,i,d,e. L ⊢ #i [d, e] ≫ T2 →
 131                      T2 = #i ∨
 132                      ∃∃K,V. d ≤ i & i < d + e &
 133                             ↓[O, i] L ≡ K. 𝕓{Abbr} V &
 134                             ↑[O, i + 1] V ≡ T2.
 135 /2/ qed.
 136
 137 fact tps_inv_bind1_aux: ∀d,e,L,U1,U2. L ⊢ U1 [d, e] ≫ U2 →
 138                         ∀I,V1,T1. U1 = 𝕓{I} V1. T1 →
 139                         ∃∃V2,T2. L ⊢ V1 [d, e] ≫ V2 &
 140                                  L. 𝕓{I} V1 ⊢ T1 [d + 1, e] ≫ T2 &
 141                                  U2 =  𝕓{I} V2. T2.
 142 #d #e #L #U1 #U2 * -d e L U1 U2
 143 [ #L #k #d #e #I #V1 #T1 #H destruct
 144 | #L #i #d #e #I #V1 #T1 #H destruct
 145 | #L #K #V #W #i #d #e #_ #_ #_ #_ #I #V1 #T1 #H destruct
 146 | #L #J #V1 #V2 #T1 #T2 #d #e #HV12 #HT12 #I #V #T #H destruct /2 width=5/
 147 | #L #J #V1 #V2 #T1 #T2 #d #e #_ #_ #I #V #T #H destruct
 148 ]
 149 qed.
 150
 151 lemma tps_inv_bind1: ∀d,e,L,I,V1,T1,U2. L ⊢ 𝕓{I} V1. T1 [d, e] ≫ U2 →
 152                      ∃∃V2,T2. L ⊢ V1 [d, e] ≫ V2 &
 153                               L. 𝕓{I} V1 ⊢ T1 [d + 1, e] ≫ T2 &
 154                               U2 =  𝕓{I} V2. T2.
 155 /2/ qed.
 156
 157 fact tps_inv_flat1_aux: ∀d,e,L,U1,U2. L ⊢ U1 [d, e] ≫ U2 →
 158                         ∀I,V1,T1. U1 = 𝕗{I} V1. T1 →
 159                         ∃∃V2,T2. L ⊢ V1 [d, e] ≫ V2 & L ⊢ T1 [d, e] ≫ T2 &
 160                                  U2 =  𝕗{I} V2. T2.
 161 #d #e #L #U1 #U2 * -d e L U1 U2
 162 [ #L #k #d #e #I #V1 #T1 #H destruct
 163 | #L #i #d #e #I #V1 #T1 #H destruct
 164 | #L #K #V #W #i #d #e #_ #_ #_ #_ #I #V1 #T1 #H destruct
 165 | #L #J #V1 #V2 #T1 #T2 #d #e #_ #_ #I #V #T #H destruct
 166 | #L #J #V1 #V2 #T1 #T2 #d #e #HV12 #HT12 #I #V #T #H destruct /2 width=5/
 167 ]
 168 qed.
 169
 170 lemma tps_inv_flat1: ∀d,e,L,I,V1,T1,U2. L ⊢ 𝕗{I} V1. T1 [d, e] ≫ U2 →
 171                      ∃∃V2,T2. L ⊢ V1 [d, e] ≫ V2 & L ⊢ T1 [d, e] ≫ T2 &
 172                               U2 =  𝕗{I} V2. T2.
 173 /2/ qed.
 174
 175 fact tps_inv_refl0_aux: ∀L,T1,T2,d,e. L ⊢ T1 [d, e] ≫ T2 → e = 0 → T1 = T2.
 176 #L #T1 #T2 #d #e #H elim H -H L T1 T2 d e
 177 [ //
 178 | //
 179 | #L #K #V #W #i #d #e #Hdi #Hide #_ #_ #H destruct -e;
 180   lapply (le_to_lt_to_lt … Hdi … Hide) -Hdi Hide <plus_n_O #Hdd
 181   elim (lt_refl_false … Hdd)
 182 | /3/
 183 | /3/
 184 ]
 185 qed.
 186
 187 lemma tps_inv_refl0: ∀L,T1,T2,d. L ⊢ T1 [d, 0] ≫ T2 → T1 = T2.
 188 /2 width=6/ qed.