matita/matita/contribs/lambda-delta/Basic-2/substitution/tps_lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic-2/substitution/drop_drop.ma".
  16 include "Basic-2/substitution/tps.ma".
  17
  18 (* PARTIAL SUBSTITUTION ON TERMS ********************************************)
  19
  20 (* Relocation properties ****************************************************)
  21
  22 lemma tps_lift_le: ∀K,T1,T2,dt,et. K ⊢ T1 [dt, et] ≫ T2 →
  23                    ∀L,U1,U2,d,e. ↓[d, e] L ≡ K →
  24                    ↑[d, e] T1 ≡ U1 → ↑[d, e] T2 ≡ U2 →
  25                    dt + et ≤ d →
  26                    L ⊢ U1 [dt, et] ≫ U2.
  27 #K #T1 #T2 #dt #et #H elim H -H K T1 T2 dt et
  28 [ #K #k #dt #et #L #U1 #U2 #d #e #_ #H1 #H2 #_
  29   >(lift_mono … H1 … H2) -H1 H2 //
  30 | #K #i #dt #et #L #U1 #U2 #d #e #_ #H1 #H2 #_
  31   >(lift_mono … H1 … H2) -H1 H2 //
  32 | #K #KV #V #W #i #dt #et #Hdti #Hidet #HKV #HVW #L #U1 #U2 #d #e #HLK #H #HVU2 #Hdetd
  33   lapply (lt_to_le_to_lt … Hidet … Hdetd) -Hdetd #Hid
  34   lapply (lift_inv_lref1_lt … H … Hid) -H #H destruct -U1;
  35   elim (lift_trans_ge … HVW … HVU2 ?) -HVW HVU2 W // <minus_plus #W #HVW #HWU2
  36   elim (drop_trans_le … HLK … HKV ?) -HLK HKV K [2: /2/] #X #HLK #H
  37   elim (drop_inv_skip2 … H ?) -H [2: /2/] -Hid #K #Y #_ #HVY
  38   >(lift_mono … HVY … HVW) -HVY HVW Y #H destruct -X /2/
  39 | #K #I #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #d #e #HLK #H1 #H2 #Hdetd
  40   elim (lift_inv_bind1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  41   elim (lift_inv_bind1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct -U1 U2;
  42   @tps_bind [ /2 width=6/ | @IHT12 [3,4,5: /2/ |1,2: skip | /2/ ] ] (**) (* /3 width=6/ is too slow, arith3 needed to avoid crash *)
  43 | #K #I #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #d #e #HLK #H1 #H2 #Hdetd
  44   elim (lift_inv_flat1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  45   elim (lift_inv_flat1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct -U1 U2;
  46   /3 width=6/
  47 ]
  48 qed.
  49
  50 lemma tps_lift_ge: ∀K,T1,T2,dt,et. K ⊢ T1 [dt, et] ≫ T2 →
  51                    ∀L,U1,U2,d,e. ↓[d, e] L ≡ K →
  52                    ↑[d, e] T1 ≡ U1 → ↑[d, e] T2 ≡ U2 →
  53                    d ≤ dt →
  54                    L ⊢ U1 [dt + e, et] ≫ U2.
  55 #K #T1 #T2 #dt #et #H elim H -H K T1 T2 dt et
  56 [ #K #k #dt #et #L #U1 #U2 #d #e #_ #H1 #H2 #_
  57   >(lift_mono … H1 … H2) -H1 H2 //
  58 | #K #i #dt #et #L #U1 #U2 #d #e #_ #H1 #H2 #_
  59   >(lift_mono … H1 … H2) -H1 H2 //
  60 | #K #KV #V #W #i #dt #et #Hdti #Hidet #HKV #HVW #L #U1 #U2 #d #e #HLK #H #HWU2 #Hddt
  61   lapply (transitive_le … Hddt … Hdti) -Hddt #Hid
  62   lapply (lift_inv_lref1_ge … H … Hid) -H #H destruct -U1;
  63   lapply (lift_trans_be … HVW … HWU2 ? ?) -HVW HWU2 W // [ /2/ ] >plus_plus_comm_23 #HVU2
  64   lapply (drop_trans_ge_comm … HLK … HKV ?) -HLK HKV K // -Hid /3/
  65 | #K #I #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #d #e #HLK #H1 #H2 #Hddt
  66   elim (lift_inv_bind1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  67   elim (lift_inv_bind1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct -U1 U2;
  68   @tps_bind [ /2 width=5/ | /3 width=5/ ] (**) (* explicit constructor *)
  69 | #K #I #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #d #e #HLK #H1 #H2 #Hddt
  70   elim (lift_inv_flat1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  71   elim (lift_inv_flat1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct -U1 U2;
  72   /3 width=5/
  73 ]
  74 qed.
  75
  76 lemma tps_inv_lift1_le: ∀L,U1,U2,dt,et. L ⊢ U1 [dt, et] ≫ U2 →
  77                         ∀K,d,e. ↓[d, e] L ≡ K → ∀T1. ↑[d, e] T1 ≡ U1 →
  78                         dt + et ≤ d →
  79                         ∃∃T2. K ⊢ T1 [dt, et] ≫ T2 & ↑[d, e] T2 ≡ U2.
  80 #L #U1 #U2 #dt #et #H elim H -H L U1 U2 dt et
  81 [ #L #k #dt #et #K #d #e #_ #T1 #H #_
  82   lapply (lift_inv_sort2 … H) -H #H destruct -T1 /2/
  83 | #L #i #dt #et #K #d #e #_ #T1 #H #_
  84   elim (lift_inv_lref2 … H) -H * #Hid #H destruct -T1 /3/
  85 | #L #KV #V #W #i #dt #et #Hdti #Hidet #HLKV #HVW #K #d #e #HLK #T1 #H #Hdetd
  86   lapply (lt_to_le_to_lt … Hidet … Hdetd) -Hdetd #Hid
  87   lapply (lift_inv_lref2_lt … H … Hid) -H #H destruct -T1;
  88   elim (drop_conf_lt … HLK … HLKV ?) -HLK HLKV L // #L #U #HKL #_ #HUV
  89   elim (lift_trans_le … HUV … HVW ?) -HUV HVW V // >arith_a2 // -Hid /3/
  90 | #L #I #V1 #V2 #U1 #U2 #dt #et #_ #_ #IHV12 #IHU12 #K #d #e #HLK #X #H #Hdetd
  91   elim (lift_inv_bind2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct -X;
  92   elim (IHV12 … HLK … HWV1 ?) -IHV12 //
  93   elim (IHU12 … HTU1 ?) -IHU12 HTU1 [3: /2/ |4: @drop_skip // |2: skip ] -HLK HWV1 Hdetd /3 width=5/ (**) (* just /3 width=5/ is too slow *)
  94 | #L #I #V1 #V2 #U1 #U2 #dt #et #_ #_ #IHV12 #IHU12 #K #d #e #HLK #X #H #Hdetd
  95   elim (lift_inv_flat2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct -X;
  96   elim (IHV12 … HLK … HWV1 ?) -IHV12 HWV1 //
  97   elim (IHU12 … HLK … HTU1 ?) -IHU12 HLK HTU1 // /3 width=5/
  98 ]
  99 qed.
 100
 101 lemma tps_inv_lift1_ge: ∀L,U1,U2,dt,et. L ⊢ U1 [dt, et] ≫ U2 →
 102                         ∀K,d,e. ↓[d, e] L ≡ K → ∀T1. ↑[d, e] T1 ≡ U1 →
 103                         d + e ≤ dt →
 104                         ∃∃T2. K ⊢ T1 [dt - e, et] ≫ T2 & ↑[d, e] T2 ≡ U2.
 105 #L #U1 #U2 #dt #et #H elim H -H L U1 U2 dt et
 106 [ #L #k #dt #et #K #d #e #_ #T1 #H #_
 107   lapply (lift_inv_sort2 … H) -H #H destruct -T1 /2/
 108 | #L #i #dt #et #K #d #e #_ #T1 #H #_
 109   elim (lift_inv_lref2 … H) -H * #Hid #H destruct -T1 /3/
 110 | #L #KV #V #W #i #dt #et #Hdti #Hidet #HLKV #HVW #K #d #e #HLK #T1 #H #Hdedt
 111   lapply (transitive_le … Hdedt … Hdti) #Hdei
 112   lapply (plus_le_weak … Hdedt) -Hdedt #Hedt
 113   lapply (plus_le_weak … Hdei) #Hei
 114   lapply (lift_inv_lref2_ge … H … Hdei) -H #H destruct -T1;
 115   lapply (drop_conf_ge … HLK … HLKV ?) -HLK HLKV L // #HKV
 116   elim (lift_split … HVW d (i - e + 1) ? ? ?) -HVW; [2,3,4: normalize /2/ ] -Hdei >arith_e2 // #V0 #HV10 #HV02
 117   @ex2_1_intro
 118   [2: @tps_subst [3: /2/ |5,6: // |1,2: skip |4: @arith5 // ]
 119   |1: skip
 120   | //
 121   ] (**) (* explicitc constructors *)
 122 | #L #I #V1 #V2 #U1 #U2 #dt #et #_ #_ #IHV12 #IHU12 #K #d #e #HLK #X #H #Hdetd
 123   elim (lift_inv_bind2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct -X;
 124   lapply (plus_le_weak … Hdetd) #Hedt
 125   elim (IHV12 … HLK … HWV1 ?) -IHV12 // #W2 #HW12 #HWV2
 126   elim (IHU12 … HTU1 ?) -IHU12 HTU1 [4: @drop_skip // |2: skip |3: /2/ ]
 127   <plus_minus // /3 width=5/
 128 | #L #I #V1 #V2 #U1 #U2 #dt #et #_ #_ #IHV12 #IHU12 #K #d #e #HLK #X #H #Hdetd
 129   elim (lift_inv_flat2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct -X;
 130   elim (IHV12 … HLK … HWV1 ?) -IHV12 HWV1 //
 131   elim (IHU12 … HLK … HTU1 ?) -IHU12 HLK HTU1 // /3 width=5/
 132 ]
 133 qed.
 134
 135 lemma tps_inv_lift1_eq: ∀L,U1,U2,d,e.
 136                         L ⊢ U1 [d, e] ≫ U2 → ∀T1. ↑[d, e] T1 ≡ U1 → U1 = U2.
 137 #L #U1 #U2 #d #e #H elim H -H L U1 U2 d e
 138 [ //
 139 | //
 140 | #L #K #V #W #i #d #e #Hdi #Hide #_ #_ #T1 #H
 141   elim (lift_inv_lref2 … H) -H * #H
 142   [ lapply (le_to_lt_to_lt … Hdi … H) -Hdi H #H
 143     elim (lt_refl_false … H)
 144   | lapply (lt_to_le_to_lt … Hide … H) -Hide H #H
 145     elim (lt_refl_false … H)
 146   ]
 147 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
 148   elim (lift_inv_bind2 … HX) -HX #V #T #HV1 #HT1 #H destruct -X
 149   >IHV12 // >IHT12 //
 150 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
 151   elim (lift_inv_flat2 … HX) -HX #V #T #HV1 #HT1 #H destruct -X
 152   >IHV12 // >IHT12 //
 153 ]
 154 qed.
 155 (*
 156       Theorem subst0_gen_lift_ge : (u,t1,x:?; i,h,d:?) (subst0 i u (lift h d t1) x) ->
 157                                    (le (plus d h) i) ->
 158                                    (EX t2 | x = (lift h d t2) & (subst0 (minus i h) u t1 t2)).
 159
 160       Theorem subst0_gen_lift_rev_ge: (t1,v,u2:?; i,h,d:?)
 161                                       (subst0 i v t1 (lift h d u2)) ->
 162                                       (le (plus d h) i) ->
 163                                       (EX u1 | (subst0 (minus i h) v u1 u2) &
 164                                                t1 = (lift h d u1)
 165                                       ).
 166
 167
 168       Theorem subst0_gen_lift_rev_lelt: (t1,v,u2:?; i,h,d:?)
 169                                         (subst0 i v t1 (lift h d u2)) ->
 170                                         (le d i) -> (lt i (plus d h)) ->
 171                                         (EX u1 | t1 = (lift (minus (plus d h) (S i)) (S i) u1)).
 172 *)
 173
 174 lemma tps_inv_lift1_up: ∀L,U1,U2,dt,et. L ⊢ U1 [dt, et] ≫ U2 →
 175                         ∀K,d,e. ↓[d, e] L ≡ K → ∀T1. ↑[d, e] T1 ≡ U1 →
 176                         d ≤ dt → dt ≤ d + e → d + e ≤ dt + et →
 177                         ∃∃T2. K ⊢ T1 [d, dt + et - (d + e)] ≫ T2 & ↑[d, e] T2 ≡ U2.
 178 #L #U1 #U2 #dt #et #HU12 #K #d #e #HLK #T1 #HTU1 #Hddt #Hdtde #Hdedet
 179 elim (tps_split_up … HU12 (d + e) ? ?) -HU12 // -Hdedet #U #HU1 #HU2
 180 lapply (tps_weak … HU1 d e ? ?) -HU1 // <plus_minus_m_m_comm // -Hddt Hdtde #HU1
 181 lapply (tps_inv_lift1_eq … HU1 … HTU1) -HU1 #HU1 destruct -U1;
 182 elim (tps_inv_lift1_ge … HU2 … HLK … HTU1 ?) -HU2 HLK HTU1 // <minus_plus_m_m /2/
 183 qed.
 184
 185 (* Advanced inversion lemmas ************************************************)
 186
 187 fact tps_inv_refl1_aux: ∀L,T1,T2,d,e. L ⊢ T1 [d, e] ≫ T2 → e = 1 →
 188                         ∀K,V. ↓[0, d] L ≡ K. 𝕓{Abst} V → T1 = T2.
 189 #L #T1 #T2 #d #e #H elim H -H L T1 T2 d e
 190 [ //
 191 | //
 192 | #L #K0 #V0 #W #i #d #e #Hdi #Hide #HLK0 #_ #H destruct -e;
 193   >(le_to_le_to_eq … Hdi ?) /2/ -d #K #V #HLK
 194   lapply (drop_mono … HLK0 … HLK) #H destruct
 195 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #H1 #K #V #HLK
 196   >(IHV12 H1 … HLK) -IHV12 >(IHT12 H1 K V) -IHT12 /2/
 197 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #H1 #K #V #HLK
 198   >(IHV12 H1 … HLK) -IHV12 >(IHT12 H1 … HLK) -IHT12 //
 199 ]
 200 qed.
 201
 202 lemma tps_inv_refl1: ∀L,T1,T2,d. L ⊢ T1 [d, 1] ≫ T2 →
 203                      ∀K,V. ↓[0, d] L ≡ K. 𝕓{Abst} V → T1 = T2.
 204 /2 width=8/ qed.