matita/matita/contribs/lambda-delta/Basic-2/substitution/tps_lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic-2/substitution/drop_drop.ma".
  16 include "Basic-2/substitution/tps.ma".
  17
  18 (* PARTIAL SUBSTITUTION ON TERMS ********************************************)
  19
  20 (* Relocation properties ****************************************************)
  21
  22 lemma tps_lift_le: ∀K,T1,T2,dt,et. K ⊢ T1 [dt, et] ≫ T2 →
  23                    ∀L,U1,U2,d,e. ↓[d, e] L ≡ K →
  24                    ↑[d, e] T1 ≡ U1 → ↑[d, e] T2 ≡ U2 →
  25                    dt + et ≤ d →
  26                    L ⊢ U1 [dt, et] ≫ U2.
  27 #K #T1 #T2 #dt #et #H elim H -H K T1 T2 dt et
  28 [ #K #I #dt #et #L #U1 #U2 #d #e #_ #H1 #H2 #_
  29   >(lift_mono … H1 … H2) -H1 H2 //
  30 | #K #KV #V #W #i #dt #et #Hdti #Hidet #HKV #HVW #L #U1 #U2 #d #e #HLK #H #HVU2 #Hdetd
  31   lapply (lt_to_le_to_lt … Hidet … Hdetd) -Hdetd #Hid
  32   lapply (lift_inv_lref1_lt … H … Hid) -H #H destruct -U1;
  33   elim (lift_trans_ge … HVW … HVU2 ?) -HVW HVU2 W // <minus_plus #W #HVW #HWU2
  34   elim (drop_trans_le … HLK … HKV ?) -HLK HKV K [2: /2/] #X #HLK #H
  35   elim (drop_inv_skip2 … H ?) -H [2: /2/] -Hid #K #Y #_ #HVY
  36   >(lift_mono … HVY … HVW) -HVY HVW Y #H destruct -X /2/
  37 | #K #I #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #d #e #HLK #H1 #H2 #Hdetd
  38   elim (lift_inv_bind1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  39   elim (lift_inv_bind1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct -U1 U2;
  40   @tps_bind [ /2 width=6/ | @IHT12 [3,4,5: /2/ |1,2: skip | /2/ ] ] (**) (* /3 width=6/ is too slow, arith3 needed to avoid crash *)
  41 | #K #I #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #d #e #HLK #H1 #H2 #Hdetd
  42   elim (lift_inv_flat1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  43   elim (lift_inv_flat1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct -U1 U2;
  44   /3 width=6/
  45 ]
  46 qed.
  47
  48 lemma tps_lift_ge: ∀K,T1,T2,dt,et. K ⊢ T1 [dt, et] ≫ T2 →
  49                    ∀L,U1,U2,d,e. ↓[d, e] L ≡ K →
  50                    ↑[d, e] T1 ≡ U1 → ↑[d, e] T2 ≡ U2 →
  51                    d ≤ dt →
  52                    L ⊢ U1 [dt + e, et] ≫ U2.
  53 #K #T1 #T2 #dt #et #H elim H -H K T1 T2 dt et
  54 [ #K #I #dt #et #L #U1 #U2 #d #e #_ #H1 #H2 #_
  55   >(lift_mono … H1 … H2) -H1 H2 //
  56 | #K #KV #V #W #i #dt #et #Hdti #Hidet #HKV #HVW #L #U1 #U2 #d #e #HLK #H #HWU2 #Hddt
  57   lapply (transitive_le … Hddt … Hdti) -Hddt #Hid
  58   lapply (lift_inv_lref1_ge … H … Hid) -H #H destruct -U1;
  59   lapply (lift_trans_be … HVW … HWU2 ? ?) -HVW HWU2 W // [ /2/ ] >plus_plus_comm_23 #HVU2
  60   lapply (drop_trans_ge_comm … HLK … HKV ?) -HLK HKV K // -Hid /3/
  61 | #K #I #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #d #e #HLK #H1 #H2 #Hddt
  62   elim (lift_inv_bind1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  63   elim (lift_inv_bind1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct -U1 U2;
  64   @tps_bind [ /2 width=5/ | /3 width=5/ ] (**) (* explicit constructor *)
  65 | #K #I #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #d #e #HLK #H1 #H2 #Hddt
  66   elim (lift_inv_flat1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  67   elim (lift_inv_flat1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct -U1 U2;
  68   /3 width=5/
  69 ]
  70 qed.
  71
  72 lemma tps_inv_lift1_le: ∀L,U1,U2,dt,et. L ⊢ U1 [dt, et] ≫ U2 →
  73                         ∀K,d,e. ↓[d, e] L ≡ K → ∀T1. ↑[d, e] T1 ≡ U1 →
  74                         dt + et ≤ d →
  75                         ∃∃T2. K ⊢ T1 [dt, et] ≫ T2 & ↑[d, e] T2 ≡ U2.
  76 #L #U1 #U2 #dt #et #H elim H -H L U1 U2 dt et
  77 [ #L * #i #dt #et #K #d #e #_ #T1 #H #_
  78   [ lapply (lift_inv_sort2 … H) -H #H destruct -T1 /2/
  79   | elim (lift_inv_lref2 … H) -H * #Hid #H destruct -T1 /3/
  80   ]
  81 | #L #KV #V #W #i #dt #et #Hdti #Hidet #HLKV #HVW #K #d #e #HLK #T1 #H #Hdetd
  82   lapply (lt_to_le_to_lt … Hidet … Hdetd) -Hdetd #Hid
  83   lapply (lift_inv_lref2_lt … H … Hid) -H #H destruct -T1;
  84   elim (drop_conf_lt … HLK … HLKV ?) -HLK HLKV L // #L #U #HKL #_ #HUV
  85   elim (lift_trans_le … HUV … HVW ?) -HUV HVW V // >arith_a2 // -Hid /3/
  86 | #L #I #V1 #V2 #U1 #U2 #dt #et #_ #_ #IHV12 #IHU12 #K #d #e #HLK #X #H #Hdetd
  87   elim (lift_inv_bind2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct -X;
  88   elim (IHV12 … HLK … HWV1 ?) -IHV12 HWV1 // #W2 #HW12 #HWV2
  89   elim (IHU12 … HTU1 ?) -IHU12 HTU1 [3: /2/ |4: @drop_skip // |2: skip ] -HLK Hdetd (**) (* /3 width=5/ is too slow *)
  90   /3 width=5/
  91 | #L #I #V1 #V2 #U1 #U2 #dt #et #_ #_ #IHV12 #IHU12 #K #d #e #HLK #X #H #Hdetd
  92   elim (lift_inv_flat2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct -X;
  93   elim (IHV12 … HLK … HWV1 ?) -IHV12 HWV1 //
  94   elim (IHU12 … HLK … HTU1 ?) -IHU12 HLK HTU1 // /3 width=5/
  95 ]
  96 qed.
  97
  98 lemma tps_inv_lift1_ge: ∀L,U1,U2,dt,et. L ⊢ U1 [dt, et] ≫ U2 →
  99                         ∀K,d,e. ↓[d, e] L ≡ K → ∀T1. ↑[d, e] T1 ≡ U1 →
 100                         d + e ≤ dt →
 101                         ∃∃T2. K ⊢ T1 [dt - e, et] ≫ T2 & ↑[d, e] T2 ≡ U2.
 102 #L #U1 #U2 #dt #et #H elim H -H L U1 U2 dt et
 103 [ #L * #i #dt #et #K #d #e #_ #T1 #H #_
 104   [ lapply (lift_inv_sort2 … H) -H #H destruct -T1 /2/
 105   | elim (lift_inv_lref2 … H) -H * #Hid #H destruct -T1 /3/
 106   ]
 107 | #L #KV #V #W #i #dt #et #Hdti #Hidet #HLKV #HVW #K #d #e #HLK #T1 #H #Hdedt
 108   lapply (transitive_le … Hdedt … Hdti) #Hdei
 109   lapply (plus_le_weak … Hdedt) -Hdedt #Hedt
 110   lapply (plus_le_weak … Hdei) #Hei
 111   lapply (lift_inv_lref2_ge … H … Hdei) -H #H destruct -T1;
 112   lapply (drop_conf_ge … HLK … HLKV ?) -HLK HLKV L // #HKV
 113   elim (lift_split … HVW d (i - e + 1) ? ? ?) -HVW; [2,3,4: normalize /2/ ] -Hdei >arith_e2 // #V0 #HV10 #HV02
 114   @ex2_1_intro
 115   [2: @tps_subst [3: /2/ |5,6: // |1,2: skip |4: @arith5 // ]
 116   |1: skip
 117   | //
 118   ] (**) (* explicitc constructors *)
 119 | #L #I #V1 #V2 #U1 #U2 #dt #et #_ #_ #IHV12 #IHU12 #K #d #e #HLK #X #H #Hdetd
 120   elim (lift_inv_bind2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct -X;
 121   lapply (plus_le_weak … Hdetd) #Hedt
 122   elim (IHV12 … HLK … HWV1 ?) -IHV12 HWV1 // #W2 #HW12 #HWV2
 123   elim (IHU12 … HTU1 ?) -IHU12 HTU1 [4: @drop_skip // |2: skip |3: /2/ ]
 124   <plus_minus // /3 width=5/
 125 | #L #I #V1 #V2 #U1 #U2 #dt #et #_ #_ #IHV12 #IHU12 #K #d #e #HLK #X #H #Hdetd
 126   elim (lift_inv_flat2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct -X;
 127   elim (IHV12 … HLK … HWV1 ?) -IHV12 HWV1 //
 128   elim (IHU12 … HLK … HTU1 ?) -IHU12 HLK HTU1 // /3 width=5/
 129 ]
 130 qed.
 131
 132 lemma tps_inv_lift1_eq: ∀L,U1,U2,d,e.
 133                         L ⊢ U1 [d, e] ≫ U2 → ∀T1. ↑[d, e] T1 ≡ U1 → U1 = U2.
 134 #L #U1 #U2 #d #e #H elim H -H L U1 U2 d e
 135 [ //
 136 | #L #K #V #W #i #d #e #Hdi #Hide #_ #_ #T1 #H
 137   elim (lift_inv_lref2 … H) -H * #H
 138   [ lapply (le_to_lt_to_lt … Hdi … H) -Hdi H #H
 139     elim (lt_refl_false … H)
 140   | lapply (lt_to_le_to_lt … Hide … H) -Hide H #H
 141     elim (lt_refl_false … H)
 142   ]
 143 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
 144   elim (lift_inv_bind2 … HX) -HX #V #T #HV1 #HT1 #H destruct -X
 145   >IHV12 // >IHT12 //
 146 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
 147   elim (lift_inv_flat2 … HX) -HX #V #T #HV1 #HT1 #H destruct -X
 148   >IHV12 // >IHT12 //
 149 ]
 150 qed.
 151 (*
 152       Theorem subst0_gen_lift_ge : (u,t1,x:?; i,h,d:?) (subst0 i u (lift h d t1) x) ->
 153                                    (le (plus d h) i) ->
 154                                    (EX t2 | x = (lift h d t2) & (subst0 (minus i h) u t1 t2)).
 155
 156       Theorem subst0_gen_lift_rev_ge: (t1,v,u2:?; i,h,d:?)
 157                                       (subst0 i v t1 (lift h d u2)) ->
 158                                       (le (plus d h) i) ->
 159                                       (EX u1 | (subst0 (minus i h) v u1 u2) &
 160                                                t1 = (lift h d u1)
 161                                       ).
 162
 163
 164       Theorem subst0_gen_lift_rev_lelt: (t1,v,u2:?; i,h,d:?)
 165                                         (subst0 i v t1 (lift h d u2)) ->
 166                                         (le d i) -> (lt i (plus d h)) ->
 167                                         (EX u1 | t1 = (lift (minus (plus d h) (S i)) (S i) u1)).
 168 *)
 169
 170 lemma tps_inv_lift1_up: ∀L,U1,U2,dt,et. L ⊢ U1 [dt, et] ≫ U2 →
 171                         ∀K,d,e. ↓[d, e] L ≡ K → ∀T1. ↑[d, e] T1 ≡ U1 →
 172                         d ≤ dt → dt ≤ d + e → d + e ≤ dt + et →
 173                         ∃∃T2. K ⊢ T1 [d, dt + et - (d + e)] ≫ T2 & ↑[d, e] T2 ≡ U2.
 174 #L #U1 #U2 #dt #et #HU12 #K #d #e #HLK #T1 #HTU1 #Hddt #Hdtde #Hdedet
 175 elim (tps_split_up … HU12 (d + e) ? ?) -HU12 // -Hdedet #U #HU1 #HU2
 176 lapply (tps_weak … HU1 d e ? ?) -HU1 // <plus_minus_m_m_comm // -Hddt Hdtde #HU1
 177 lapply (tps_inv_lift1_eq … HU1 … HTU1) -HU1 #HU1 destruct -U1;
 178 elim (tps_inv_lift1_ge … HU2 … HLK … HTU1 ?) -HU2 HLK HTU1 // <minus_plus_m_m /2/
 179 qed.
 180
 181 (* Advanced inversion lemmas ************************************************)
 182
 183 fact tps_inv_refl_SO2_aux: ∀L,T1,T2,d,e. L ⊢ T1 [d, e] ≫ T2 → e = 1 →
 184                            ∀K,V. ↓[0, d] L ≡ K. 𝕓{Abst} V → T1 = T2.
 185 #L #T1 #T2 #d #e #H elim H -H L T1 T2 d e
 186 [ //
 187 | #L #K0 #V0 #W #i #d #e #Hdi #Hide #HLK0 #_ #H destruct -e;
 188   >(le_to_le_to_eq … Hdi ?) /2/ -d #K #V #HLK
 189   lapply (drop_mono … HLK0 … HLK) #H destruct
 190 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #H1 #K #V #HLK
 191   >(IHV12 H1 … HLK) -IHV12 >(IHT12 H1 K V) -IHT12 /2/
 192 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #H1 #K #V #HLK
 193   >(IHV12 H1 … HLK) -IHV12 >(IHT12 H1 … HLK) -IHT12 //
 194 ]
 195 qed.
 196
 197 lemma tps_inv_refl_SO2: ∀L,T1,T2,d. L ⊢ T1 [d, 1] ≫ T2 →
 198                         ∀K,V. ↓[0, d] L ≡ K. 𝕓{Abst} V → T1 = T2.
 199 /2 width=8/ qed.