matita/matita/contribs/lambda-delta/Ground-2/star.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basics/star.ma".
  16 include "Ground-2/xoa_props.ma".
  17
  18 (* PROPERTIES of RELATIONS **************************************************)
  19
  20 definition confluent: ∀A. ∀R1,R2: relation A. Prop ≝ λA,R1,R2.
  21                       ∀a0,a1. R1 a0 a1 → ∀a2. R2 a0 a2 →
  22                       ∃∃a. R2 a1 a & R1 a2 a.
  23
  24 definition transitive: ∀A. ∀R1,R2: relation A. Prop ≝ λA,R1,R2.
  25                        ∀a1,a0. R1 a1 a0 → ∀a2. R2 a0 a2 →
  26                        ∃∃a. R2 a1 a & R1 a a2.
  27
  28 lemma TC_strip1: ∀A,R1,R2. confluent A R1 R2 →
  29                  ∀a0,a1. TC … R1 a0 a1 → ∀a2. R2 a0 a2 →
  30                  ∃∃a. R2 a1 a & TC … R1 a2 a.
  31 #A #R1 #R2 #HR12 #a0 #a1 #H elim H -H a1
  32 [ #a1 #Ha01 #a2 #Ha02
  33   elim (HR12 … Ha01 … Ha02) -HR12 a0 /3/
  34 | #a #a1 #_ #Ha1 #IHa0 #a2 #Ha02
  35   elim (IHa0 … Ha02) -IHa0 Ha02 a0 #a0 #Ha0 #Ha20
  36   elim (HR12 … Ha1 … Ha0) -HR12 a /4/
  37 ]
  38 qed.
  39
  40 lemma TC_strip2: ∀A,R1,R2. confluent A R1 R2 →
  41                  ∀a0,a2. TC … R2 a0 a2 → ∀a1. R1 a0 a1 →
  42                  ∃∃a. R1 a2 a & TC … R2 a1 a.
  43 #A #R1 #R2 #HR12 #a0 #a2 #H elim H -H a2
  44 [ #a2 #Ha02 #a1 #Ha01
  45   elim (HR12 … Ha01 … Ha02) -HR12 a0 /3/
  46 | #a #a2 #_ #Ha2 #IHa0 #a1 #Ha01
  47   elim (IHa0 … Ha01) -IHa0 Ha01 a0 #a0 #Ha0 #Ha21
  48   elim (HR12 … Ha0 … Ha2) -HR12 a /4/
  49 ]
  50 qed.
  51
  52 lemma TC_confluent: ∀A,R1,R2.
  53                     confluent A R1 R2 → confluent A (TC … R1) (TC … R2).
  54 #A #R1 #R2 #HR12 #a0 #a1 #H elim H -H a1
  55 [ #a1 #Ha01 #a2 #Ha02
  56   elim (TC_strip2 … HR12 … Ha02 … Ha01) -HR12 a0 /3/
  57 | #a #a1 #_ #Ha1 #IHa0 #a2 #Ha02
  58   elim (IHa0 … Ha02) -IHa0 Ha02 a0 #a0 #Ha0 #Ha20
  59   elim (TC_strip2 … HR12 … Ha0 … Ha1) -HR12 a /4/
  60 ]
  61 qed.
  62
  63 lemma TC_strap1: ∀A,R1,R2. transitive A R1 R2 →
  64                  ∀a1,a0. TC … R1 a1 a0 → ∀a2. R2 a0 a2 →
  65                  ∃∃a. R2 a1 a & TC … R1 a a2.
  66 #A #R1 #R2 #HR12 #a1 #a0 #H elim H -H a0
  67 [ #a0 #Ha10 #a2 #Ha02
  68   elim (HR12 … Ha10 … Ha02) -HR12 a0 /3/
  69 | #a #a0 #_ #Ha0 #IHa #a2 #Ha02
  70   elim (HR12 … Ha0 … Ha02) -HR12 a0 #a0 #Ha0 #Ha02
  71   elim (IHa … Ha0) -a /4/
  72 ]
  73 qed.
  74
  75 lemma TC_strap2: ∀A,R1,R2. transitive A R1 R2 →
  76                  ∀a0,a2. TC … R2 a0 a2 → ∀a1. R1 a1 a0 →
  77                  ∃∃a. R1 a a2 & TC … R2 a1 a.
  78 #A #R1 #R2 #HR12 #a0 #a2 #H elim H -H a2
  79 [ #a2 #Ha02 #a1 #Ha10
  80   elim (HR12 … Ha10 … Ha02) -HR12 a0 /3/
  81 | #a #a2 #_ #Ha02 #IHa #a1 #Ha10
  82   elim (IHa … Ha10) -a0 #a0 #Ha0 #Ha10
  83   elim (HR12 … Ha0 … Ha02) -HR12 a /4/
  84 ]
  85 qed.
  86
  87 lemma TC_transitive: ∀A,R1,R2.
  88                      transitive A R1 R2 → transitive A (TC … R1) (TC … R2).
  89 #A #R1 #R2 #HR12 #a1 #a0 #H elim H -a0
  90 [ #a0 #Ha10 #a2 #Ha02
  91   elim (TC_strap2 … HR12 … Ha02 … Ha10) -HR12 a0 /3/
  92 | #a #a0 #_ #Ha0 #IHa #a2 #Ha02
  93   elim (TC_strap2 … HR12 … Ha02 … Ha0) -HR12 a0 #a0 #Ha02 #Ha0
  94   elim (IHa … Ha0) -a /4/
  95 ]
  96 qed.
  97
  98 lemma TC_reflexive: ∀A,R. reflexive A R → reflexive A (TC … R).
  99 /2/ qed.
 100
 101 lemma TC_star_ind: ∀A,R. reflexive A R → ∀a1. ∀P:A→Prop.
 102                    P a1 → (∀a,a2. TC … R a1 a → R a a2 → P a → P a2) →
 103                    ∀a2. TC … R a1 a2 → P a2.
 104 #A #R #H #a1 #P #Ha1 #IHa1 #a2 #Ha12 elim Ha12 -Ha12 a2 /3/
 105 qed.