matita/matita/contribs/lambda_delta/Basic_2/computation/cprs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic_2/reducibility/cpr.ma".
  16
  17 (* CONTEXT-SENSITIVE PARALLEL COMPUTATION ON TERMS **************************)
  18
  19 (* Basic_1: includes: pr3_pr2 *)
  20 definition cprs: lenv → relation term ≝
  21                  λL. TC … (cpr L).
  22
  23 interpretation "context-sensitive parallel computation (term)"
  24    'PRedStar L T1 T2 = (cprs L T1 T2).
  25
  26 (* Basic eliminators ********************************************************)
  27
  28 lemma cprs_ind: ∀L,T1. ∀R:predicate term. R T1 →
  29                 (∀T,T2. L ⊢ T1 ➡* T → L ⊢ T ➡ T2 → R T → R T2) →
  30                 ∀T2. L ⊢ T1 ➡* T2 → R T2.
  31 #L #T1 #R #HT1 #IHT1 #T2 #HT12 @(TC_star_ind … HT1 IHT1 … HT12) //
  32 qed-.
  33
  34 axiom cprs_ind_dx: ∀L,T2. ∀R:predicate term. R T2 →
  35                    (∀T1,T. L ⊢ T1 ➡ T → L ⊢ T ➡* T2 → R T → R T1) →
  36                    ∀T1. L ⊢ T1 ➡* T2 → R T1.
  37
  38 (* Basic properties *********************************************************)
  39
  40 (* Basic_1: was: pr3_refl *)
  41 lemma cprs_refl: ∀L,T. L ⊢ T ➡* T.
  42 /2 width=1/ qed.
  43
  44 lemma cprs_strap1: ∀L,T1,T,T2.
  45                    L ⊢ T1 ➡* T → L ⊢ T ➡ T2 → L ⊢ T1 ➡* T2.
  46 /2 width=3/ qed.
  47
  48 (* Basic_1: was: pr3_step *)
  49 lemma cprs_strap2: ∀L,T1,T,T2.
  50                    L ⊢ T1 ➡ T → L ⊢ T ➡* T2 → L ⊢ T1 ➡* T2.
  51 /2 width=3/ qed.
  52
  53 (* Note: it does not hold replacing |L1| with |L2| *)
  54 lemma cprs_lsubs_conf: ∀L1,T1,T2. L1 ⊢ T1 ➡* T2 →
  55                        ∀L2. L1 [0, |L1|] ≼ L2 → L2 ⊢ T1 ➡* T2.
  56 /3 width=3/
  57 qed.
  58
  59 lemma cprs_flat_dx: ∀I,L,V1,V2. L ⊢ V1 ➡ V2 → ∀T1,T2. L ⊢ T1 ➡* T2 →
  60                     L ⊢ ⓕ{I} V1. T1 ➡* ⓕ{I} V2. T2.
  61 #I #L #V1 #V2 #HV12 #T1 #T2 #HT12 @(cprs_ind … HT12) -T2 /3 width=1/
  62 #T #T2 #_ #HT2 #IHT2
  63 @(cprs_strap1 … IHT2) -IHT2 /2 width=1/
  64 qed.
  65
  66 (* Basic_1: removed theorems 2: clear_pr3_trans pr3_cflat *)