matita/matita/contribs/lambda_delta/Basic_2/computation/csn_lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic_2/reducibility/cnf_lift.ma".
  16 include "Basic_2/computation/acp.ma".
  17 include "Basic_2/computation/csn.ma".
  18
  19 (* CONTEXT-SENSITIVE STRONGLY NORMALIZING TERMS *****************************)
  20
  21 (* Relocation properties ****************************************************)
  22
  23 (* Basic_1: was: sn3_lift *)
  24 lemma csn_lift: ∀L2,L1,T1,d,e. L1 ⊢ ⬇* T1 →
  25                 ∀T2. ⇩[d, e] L2 ≡ L1 → ⇧[d, e] T1 ≡ T2 → L2 ⊢ ⬇* T2.
  26 #L2 #L1 #T1 #d #e #H elim H -T1 #T1 #_ #IHT1 #T2 #HL21 #HT12
  27 @csn_intro #T #HLT2 #HT2
  28 elim (cpr_inv_lift … HL21 … HT12 … HLT2) -HLT2 #T0 #HT0 #HLT10
  29 @(IHT1 … HLT10) // -L1 -L2 #H destruct
  30 >(lift_mono … HT0 … HT12) in HT2; -T0 /2 width=1/
  31 qed.
  32
  33 (* Basic_1: was: sn3_gen_lift *)
  34 lemma csn_inv_lift: ∀L2,L1,T1,d,e. L1 ⊢ ⬇* T1 →
  35                     ∀T2. ⇩[d, e] L1 ≡ L2 → ⇧[d, e] T2 ≡ T1 → L2 ⊢ ⬇* T2.
  36 #L2 #L1 #T1 #d #e #H elim H -T1 #T1 #_ #IHT1 #T2 #HL12 #HT21
  37 @csn_intro #T #HLT2 #HT2
  38 elim (lift_total T d e) #T0 #HT0
  39 lapply (cpr_lift … HL12 … HT21 … HT0 HLT2) -HLT2 #HLT10
  40 @(IHT1 … HLT10) // -L1 -L2 #H destruct
  41 >(lift_inj … HT0 … HT21) in HT2; -T0 /2 width=1/
  42 qed.
  43
  44 (* Advanced properties ******************************************************)
  45
  46 lemma csn_acp: acp cpr (eq …) (csn …).
  47 @mk_acp
  48 [ /2 width=1/
  49 | /2 width=3/
  50 | /2 width=5/
  51 | @cnf_lift
  52 ]
  53 qed.
  54
  55 (* Basic_1: was: sn3_abbr *)
  56 lemma csn_lref_abbr: ∀L,K,V,i. ⇩[0, i] L ≡ K. ⓓV → K ⊢ ⬇* V → L ⊢ ⬇* #i.
  57 #L #K #V #i #HLK #HV
  58 @csn_intro #X #H #Hi
  59 elim (cpr_inv_lref1 … H) -H
  60 [ #H destruct elim (Hi ?) //
  61 | -Hi * #K0 #V0 #V1 #HLK0 #HV01 #HV1 #_
  62   lapply (ldrop_mono … HLK0 … HLK) -HLK #H destruct
  63   lapply (ldrop_fwd_ldrop2 … HLK0) -HLK0 #HLK
  64   @(csn_lift … HLK HV1) -HLK -HV1
  65   @(csn_cpr_trans … HV) -HV
  66   @(cpr_intro … HV01) -HV01 //
  67 ]
  68 qed.
  69
  70 lemma csn_abst: ∀L,W. L ⊢ ⬇* W → ∀I,V,T. L. ⓑ{I} V ⊢ ⬇* T → L ⊢ ⬇* ⓛW. T.
  71 #L #W #HW elim HW -W #W #_ #IHW #I #V #T #HT @(csn_ind … HT) -T #T #HT #IHT
  72 @csn_intro #X #H1 #H2
  73 elim (cpr_inv_abst1 … H1 I V) -H1
  74 #W0 #T0 #HLW0 #HLT0 #H destruct
  75 elim (eq_false_inv_tpair … H2) -H2
  76 [ /3 width=5/
  77 | -HLW0 * #H destruct /3 width=1/
  78 ]
  79 qed.
  80 (*
  81 axiom eq_false_inv_tpair_dx: ∀I,V1,T1,V2,T2.
  82                              (②{I} V1. T1 = ②{I} V2. T2 → False) →
  83                              (T1 = T2 → False) ∨ (T1 = T2 ∧ (V1 = V2 → False)).
  84
  85 #I #V1 #T1 #V2 #T2 #H
  86 elim (term_eq_dec V1 V2) /3 width=1/ #HV12 destruct
  87 @or_intror @conj // #HT12 destruct /2 width=1/
  88 qed-.
  89
  90 lemma csn_appl_simple: ∀L,T. L ⊢ ⬇* T → 𝐒[T] → ∀V. L ⊢ ⬇* V → L ⊢ ⬇* ⓐV. T.
  91 #L #T #H elim H -T #T #_ #IHT #HT #V #H @(csn_ind … H) -V #V #HV #IHV
  92 @csn_intro #X #H1 #H2
  93 elim (cpr_inv_appl1_simple … H1 ?) // -H1
  94 #V0 #T0 #HLV0 #HLT0 #H destruct
  95 elim (eq_false_inv_tpair_dx … H2) -H2
  96 [ -IHV #HT0 @IHT -IHT // -HLT0 /2 width=1/ -HT0 /2 width=3/
  97 | -HV -HT -IHT -HLT0 * #H #HV0 destruct /3 width=1/
  98 ]
  99 qed.
 100 *)