matita/matita/contribs/lambda_delta/Basic_2/grammar/thom.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic_2/grammar/term_simple.ma".
  16
  17 (* HOMOMORPHIC TERMS ********************************************************)
  18
  19 inductive thom: relation term ≝
  20    | thom_atom: ∀I. thom (⓪{I}) (⓪{I})
  21    | thom_abst: ∀V1,V2,T1,T2. thom (ⓛV1. T1) (ⓛV2. T2)
  22    | thom_appl: ∀V1,V2,T1,T2. thom T1 T2 → 𝐒[T1] → 𝐒[T2] →
  23                 thom (ⓐV1. T1) (ⓐV2. T2)
  24 .
  25
  26 interpretation "homomorphic (term)" 'napart T1 T2 = (thom T1 T2).
  27
  28 (* Basic properties *********************************************************)
  29
  30 lemma thom_sym: ∀T1,T2. T1 ≈ T2 → T2 ≈ T1.
  31 #T1 #T2 #H elim H -T1 -T2 /2 width=1/
  32 qed.
  33
  34 lemma thom_refl2: ∀T1,T2. T1 ≈ T2 → T2 ≈ T2.
  35 #T1 #T2 #H elim H -T1 -T2 // /2 width=1/
  36 qed.
  37
  38 lemma thom_refl1: ∀T1,T2. T1 ≈ T2 → T1 ≈ T1.
  39 /3 width=2/ qed.
  40
  41 lemma simple_thom_repl_dx: ∀T1,T2. T1 ≈ T2 → 𝐒[T1] → 𝐒[T2].
  42 #T1 #T2 #H elim H -T1 -T2 //
  43 #V1 #V2 #T1 #T2 #H
  44 elim (simple_inv_bind … H)
  45 qed. (**) (* remove from index *)
  46
  47 lemma simple_thom_repl_sn: ∀T1,T2. T1 ≈ T2 → 𝐒[T2] → 𝐒[T1].
  48 /3 width=3/ qed-.
  49
  50 (* Basic inversion lemmas ***************************************************)
  51
  52 fact thom_inv_bind1_aux: ∀T1,T2. T1 ≈ T2 → ∀I,W1,U1. T1 = ⓑ{I}W1.U1 →
  53                          ∃∃W2,U2. I = Abst & T2 = ⓛW2. U2.
  54 #T1 #T2 * -T1 -T2
  55 [ #J #I #W1 #U1 #H destruct
  56 | #V1 #V2 #T1 #T2 #I #W1 #U1 #H destruct /2 width=3/
  57 | #V1 #V2 #T1 #T2 #H_ #_ #_ #I #W1 #U1 #H destruct
  58 ]
  59 qed.
  60
  61 lemma thom_inv_bind1: ∀I,W1,U1,T2. ⓑ{I}W1.U1 ≈ T2 →
  62                       ∃∃W2,U2. I = Abst & T2 = ⓛW2. U2.
  63 /2 width=5/ qed-.
  64
  65 fact thom_inv_flat1_aux: ∀T1,T2. T1 ≈ T2 → ∀I,W1,U1. T1 = ⓕ{I}W1.U1 →
  66                          ∃∃W2,U2. U1 ≈ U2 & 𝐒[U1] & 𝐒[U2] &
  67                                   I = Appl & T2 = ⓐW2. U2.
  68 #T1 #T2 * -T1 -T2
  69 [ #J #I #W1 #U1 #H destruct
  70 | #V1 #V2 #T1 #T2 #I #W1 #U1 #H destruct
  71 | #V1 #V2 #T1 #T2 #HT12 #HT1 #HT2 #I #W1 #U1 #H destruct /2 width=5/
  72 ]
  73 qed.
  74
  75 lemma thom_inv_flat1: ∀I,W1,U1,T2. ⓕ{I}W1.U1 ≈ T2 →
  76                       ∃∃W2,U2. U1 ≈ U2 & 𝐒[U1] & 𝐒[U2] &
  77                                I = Appl & T2 = ⓐW2. U2.
  78 /2 width=4/ qed-.
  79
  80 (* Basic_1: removed theorems 7:
  81             iso_gen_sort iso_gen_lref iso_gen_head iso_refl iso_trans
  82             iso_flats_lref_bind_false iso_flats_flat_bind_false
  83 *)