matita/matita/contribs/lambda_delta/Basic_2/reduction/tpr_lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic_2/substitution/tps_lift.ma".
  16 include "Basic_2/reduction/tpr.ma".
  17
  18 (* CONTEXT-FREE PARALLEL REDUCTION ON TERMS *********************************)
  19
  20 (* Relocation properties ****************************************************)
  21
  22 (* Basic_1: was: pr0_lift *)
  23 lemma tpr_lift: ∀T1,T2. T1 ⇒ T2 →
  24                 ∀d,e,U1. ↑[d, e] T1 ≡ U1 → ∀U2. ↑[d, e] T2 ≡ U2 → U1 ⇒ U2.
  25 #T1 #T2 #H elim H -H T1 T2
  26 [ * #i #d #e #U1 #HU1 #U2 #HU2
  27   lapply (lift_mono … HU1 … HU2) -HU1 #H destruct -U1
  28   [ lapply (lift_inv_sort1 … HU2) -HU2 #H destruct -U2 //
  29   | lapply (lift_inv_lref1 … HU2) * * #Hid #H destruct -U2 //
  30   | lapply (lift_inv_gref1 … HU2) -HU2 #H destruct -U2 //
  31   ]
  32 | #I #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #d #e #X1 #HX1 #X2 #HX2
  33   elim (lift_inv_flat1 … HX1) -HX1 #W1 #U1 #HVW1 #HTU1 #HX1 destruct -X1;
  34   elim (lift_inv_flat1 … HX2) -HX2 #W2 #U2 #HVW2 #HTU2 #HX2 destruct -X2 /3/
  35 | #V1 #V2 #W #T1 #T2 #_ #_ #IHV12 #IHT12 #d #e #X1 #HX1 #X2 #HX2
  36   elim (lift_inv_flat1 … HX1) -HX1 #V0 #X #HV10 #HX #HX1 destruct -X1;
  37   elim (lift_inv_bind1 … HX) -HX #W0 #T0 #HW0 #HT10 #HX destruct -X;
  38   elim (lift_inv_bind1 … HX2) -HX2 #V3 #T3 #HV23 #HT23 #HX2 destruct -X2 /3/
  39 | #I #V1 #V2 #T1 #T2 #T0 #HV12 #HT12 #HT2 #IHV12 #IHT12 #d #e #X1 #HX1 #X2 #HX2
  40   elim (lift_inv_bind1 … HX1) -HX1 #W1 #U1 #HVW1 #HTU1 #HX1 destruct -X1;
  41   elim (lift_inv_bind1 … HX2) -HX2 #W2 #U0 #HVW2 #HTU0 #HX2 destruct -X2;
  42   elim (lift_total T2 (d + 1) e) #U2 #HTU2
  43   @tpr_delta
  44   [4: @(tps_lift_le … HT2 … HTU2 HTU0 ?) /2/ |1: skip |2: /2/ |3: /2/ ] (**) (*/3. is too slow *)
  45 | #V #V1 #V2 #W1 #W2 #T1 #T2 #_ #HV2 #_ #_ #IHV12 #IHW12 #IHT12 #d #e #X1 #HX1 #X2 #HX2
  46   elim (lift_inv_flat1 … HX1) -HX1 #V0 #X #HV10 #HX #HX1 destruct -X1;
  47   elim (lift_inv_bind1 … HX) -HX #W0 #T0 #HW0 #HT10 #HX destruct -X;
  48   elim (lift_inv_bind1 … HX2) -HX2 #W3 #X #HW23 #HX #HX2 destruct -X2;
  49   elim (lift_inv_flat1 … HX) -HX #V3 #T3 #HV3 #HT23 #HX destruct -X;
  50   elim (lift_trans_ge … HV2 … HV3 ?) -HV2 HV3 V // /3/
  51 | #V #T #T1 #T2 #HT1 #_ #IHT12 #d #e #X #HX #T0 #HT20
  52   elim (lift_inv_bind1 … HX) -HX #V3 #T3 #_ #HT3 #HX destruct -X;
  53   elim (lift_trans_ge … HT1 … HT3 ?) -HT1 HT3 T // /3 width=6/
  54 | #V #T1 #T2 #_ #IHT12 #d #e #X #HX #T #HT2
  55   elim (lift_inv_flat1 … HX) -HX #V0 #T0 #_ #HT0 #HX destruct -X /3/
  56 ]
  57 qed.
  58
  59 (* Basic_1: was: pr0_gen_lift *)
  60 lemma tpr_inv_lift: ∀T1,T2. T1 ⇒ T2 →
  61                     ∀d,e,U1. ↑[d, e] U1 ≡ T1 →
  62                     ∃∃U2. ↑[d, e] U2 ≡ T2 & U1 ⇒ U2.
  63 #T1 #T2 #H elim H -H T1 T2
  64 [ * #i #d #e #U1 #HU1
  65   [ lapply (lift_inv_sort2 … HU1) -HU1 #H destruct -U1 /2/
  66   | lapply (lift_inv_lref2 … HU1) -HU1 * * #Hid #H destruct -U1 /3/
  67   | lapply (lift_inv_gref2 … HU1) -HU1 #H destruct -U1 /2/
  68   ]
  69 | #I #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #d #e #X #HX
  70   elim (lift_inv_flat2 … HX) -HX #V0 #T0 #HV01 #HT01 #HX destruct -X;
  71   elim (IHV12 … HV01) -IHV12 HV01;
  72   elim (IHT12 … HT01) -IHT12 HT01 /3 width=5/
  73 | #V1 #V2 #W1 #T1 #T2 #_ #_ #IHV12 #IHT12 #d #e #X #HX
  74   elim (lift_inv_flat2 … HX) -HX #V0 #Y #HV01 #HY #HX destruct -X;
  75   elim (lift_inv_bind2 … HY) -HY #W0 #T0 #HW01 #HT01 #HY destruct -Y;
  76   elim (IHV12 … HV01) -IHV12 HV01;
  77   elim (IHT12 … HT01) -IHT12 HT01 /3 width=5/
  78 | #I #V1 #V2 #T1 #T2 #T0 #_ #_ #HT20 #IHV12 #IHT12 #d #e #X #HX
  79   elim (lift_inv_bind2 … HX) -HX #W1 #U1 #HWV1 #HUT1 #HX destruct -X;
  80   elim (IHV12 … HWV1) -IHV12 HWV1 #W2 #HWV2 #HW12
  81   elim (IHT12 … HUT1) -IHT12 HUT1 #U2 #HUT2 #HU12
  82   elim (tps_inv_lift1_le … HT20 … HUT2 ?) -HT20 HUT2 // [3: /2 width=5/ |2: skip ] #U0 #HU20 #HUT0
  83   @ex2_1_intro  [2: /2/ |1: skip |3: /2/ ] (**) (* /3 width=5/ is slow *)
  84 | #V #V1 #V2 #W1 #W2 #T1 #T2 #_ #HV2 #_ #_ #IHV12 #IHW12 #IHT12 #d #e #X #HX
  85   elim (lift_inv_flat2 … HX) -HX #V0 #Y #HV01 #HY #HX destruct -X;
  86   elim (lift_inv_bind2 … HY) -HY #W0 #T0 #HW01 #HT01 #HY destruct -Y;
  87   elim (IHV12 … HV01) -IHV12 HV01 #V3 #HV32 #HV03
  88   elim (IHW12 … HW01) -IHW12 HW01 #W3 #HW32 #HW03
  89   elim (IHT12 … HT01) -IHT12 HT01 #T3 #HT32 #HT03
  90   elim (lift_trans_le … HV32 … HV2 ?) -HV32 HV2 V2 // #V2 #HV32 #HV2
  91   @ex2_1_intro [2: /3/ |1: skip |3: /2/ ] (**) (* /4 width=5/ is slow *)
  92 | #V #T #T1 #T2 #HT1 #_ #IHT12 #d #e #X #HX
  93   elim (lift_inv_bind2 … HX) -HX #V0 #T0 #_ #HT0 #H destruct -X;
  94   elim (lift_div_le … HT1 … HT0 ?) -HT1 HT0 T // #T #HT0 #HT1
  95   elim (IHT12 … HT1) -IHT12 HT1 /3 width=5/
  96 | #V #T1 #T2 #_ #IHT12 #d #e #X #HX
  97   elim (lift_inv_flat2 … HX) -HX #V0 #T0 #_ #HT01 #H destruct -X;
  98   elim (IHT12 … HT01) -IHT12 HT01 /3/
  99 ]
 100 qed.
 101
 102 (* Advanced inversion lemmas ************************************************)
 103
 104 fact tpr_inv_abst1_aux: ∀U1,U2. U1 ⇒ U2 → ∀V1,T1. U1 = 𝕔{Abst} V1. T1 →
 105                         ∃∃V2,T2. V1 ⇒ V2 & T1 ⇒ T2 & U2 = 𝕔{Abst} V2. T2.
 106 #U1 #U2 * -U1 U2
 107 [ #I #V #T #H destruct
 108 | #I #V1 #V2 #T1 #T2 #_ #_ #V #T #H destruct
 109 | #V1 #V2 #W #T1 #T2 #_ #_ #V #T #H destruct
 110 | #I #V1 #V2 #T1 #T2 #T #HV12 #HT12 #HT2 #V0 #T0 #H destruct -I V1 T1;
 111   <(tps_inv_refl_SO2 … HT2 ? ? ?) -HT2 T /2 width=5/
 112 | #V #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #V0 #T0 #H destruct
 113 | #V #T #T1 #T2 #_ #_ #V0 #T0 #H destruct
 114 | #V #T1 #T2 #_ #V0 #T0 #H destruct
 115 ]
 116 qed.
 117
 118 (* Basic_1: was pr0_gen_abst *)
 119 lemma tpr_inv_abst1: ∀V1,T1,U2. 𝕔{Abst} V1. T1 ⇒ U2 →
 120                      ∃∃V2,T2. V1 ⇒ V2 & T1 ⇒ T2 & U2 = 𝕔{Abst} V2. T2.
 121 /2/ qed.