matita/matita/contribs/lambda_delta/Basic_2/substitution/drop.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic_2/grammar/lenv_weight.ma".
  16 include "Basic_2/grammar/lsubs.ma".
  17 include "Basic_2/substitution/lift.ma".
  18
  19 (* DROPPING *****************************************************************)
  20
  21 (* Basic_1: includes: drop_skip_bind *)
  22 inductive drop: nat → nat → relation lenv ≝
  23 | drop_atom: ∀d,e. drop d e (⋆) (⋆)
  24 | drop_pair: ∀L,I,V. drop 0 0 (L. 𝕓{I} V) (L. 𝕓{I} V)
  25 | drop_drop: ∀L1,L2,I,V,e. drop 0 e L1 L2 → drop 0 (e + 1) (L1. 𝕓{I} V) L2
  26 | drop_skip: ∀L1,L2,I,V1,V2,d,e.
  27              drop d e L1 L2 → ↑[d,e] V2 ≡ V1 →
  28              drop (d + 1) e (L1. 𝕓{I} V1) (L2. 𝕓{I} V2)
  29 .
  30
  31 interpretation "dropping" 'RDrop d e L1 L2 = (drop d e L1 L2).
  32
  33 (* Basic inversion lemmas ***************************************************)
  34
  35 fact drop_inv_refl_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → d = 0 → e = 0 → L1 = L2.
  36 #d #e #L1 #L2 * -d e L1 L2
  37 [ //
  38 | //
  39 | #L1 #L2 #I #V #e #_ #_ #H
  40   elim (plus_S_eq_O_false … H)
  41 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H
  42   elim (plus_S_eq_O_false … H)
  43 ]
  44 qed.
  45
  46 (* Basic_1: was: drop_gen_refl *)
  47 lemma drop_inv_refl: ∀L1,L2. ↓[0, 0] L1 ≡ L2 → L1 = L2.
  48 /2 width=5/ qed.
  49
  50 fact drop_inv_atom1_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → L1 = ⋆ →
  51                          L2 = ⋆.
  52 #d #e #L1 #L2 * -d e L1 L2
  53 [ //
  54 | #L #I #V #H destruct
  55 | #L1 #L2 #I #V #e #_ #H destruct
  56 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H destruct
  57 ]
  58 qed.
  59
  60 (* Basic_1: was: drop_gen_sort *)
  61 lemma drop_inv_atom1: ∀d,e,L2. ↓[d, e] ⋆ ≡ L2 → L2 = ⋆.
  62 /2 width=5/ qed.
  63
  64 fact drop_inv_O1_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → d = 0 →
  65                       ∀K,I,V. L1 = K. 𝕓{I} V →
  66                       (e = 0 ∧ L2 = K. 𝕓{I} V) ∨
  67                       (0 < e ∧ ↓[d, e - 1] K ≡ L2).
  68 #d #e #L1 #L2 * -d e L1 L2
  69 [ #d #e #_ #K #I #V #H destruct
  70 | #L #I #V #_ #K #J #W #HX destruct -L I V /3/
  71 | #L1 #L2 #I #V #e #HL12 #_ #K #J #W #H destruct -L1 I V /3/
  72 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H elim (plus_S_eq_O_false … H)
  73 ]
  74 qed.
  75
  76 lemma drop_inv_O1: ∀e,K,I,V,L2. ↓[0, e] K. 𝕓{I} V ≡ L2 →
  77                    (e = 0 ∧ L2 = K. 𝕓{I} V) ∨
  78                    (0 < e ∧ ↓[0, e - 1] K ≡ L2).
  79 /2/ qed.
  80
  81 (* Basic_1: was: drop_gen_drop *)
  82 lemma drop_inv_drop1: ∀e,K,I,V,L2.
  83                       ↓[0, e] K. 𝕓{I} V ≡ L2 → 0 < e → ↓[0, e - 1] K ≡ L2.
  84 #e #K #I #V #L2 #H #He
  85 elim (drop_inv_O1 … H) -H * // #H destruct -e;
  86 elim (lt_refl_false … He)
  87 qed.
  88
  89 fact drop_inv_skip1_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → 0 < d →
  90                          ∀I,K1,V1. L1 = K1. 𝕓{I} V1 →
  91                          ∃∃K2,V2. ↓[d - 1, e] K1 ≡ K2 &
  92                                   ↑[d - 1, e] V2 ≡ V1 &
  93                                   L2 = K2. 𝕓{I} V2.
  94 #d #e #L1 #L2 * -d e L1 L2
  95 [ #d #e #_ #I #K #V #H destruct
  96 | #L #I #V #H elim (lt_refl_false … H)
  97 | #L1 #L2 #I #V #e #_ #H elim (lt_refl_false … H)
  98 | #X #L2 #Y #Z #V2 #d #e #HL12 #HV12 #_ #I #L1 #V1 #H destruct -X Y Z
  99   /2 width=5/
 100 ]
 101 qed.
 102
 103 (* Basic_1: was: drop_gen_skip_l *)
 104 lemma drop_inv_skip1: ∀d,e,I,K1,V1,L2. ↓[d, e] K1. 𝕓{I} V1 ≡ L2 → 0 < d →
 105                       ∃∃K2,V2. ↓[d - 1, e] K1 ≡ K2 &
 106                                ↑[d - 1, e] V2 ≡ V1 &
 107                                L2 = K2. 𝕓{I} V2.
 108 /2/ qed.
 109
 110 fact drop_inv_skip2_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → 0 < d →
 111                          ∀I,K2,V2. L2 = K2. 𝕓{I} V2 →
 112                          ∃∃K1,V1. ↓[d - 1, e] K1 ≡ K2 &
 113                                   ↑[d - 1, e] V2 ≡ V1 &
 114                                   L1 = K1. 𝕓{I} V1.
 115 #d #e #L1 #L2 * -d e L1 L2
 116 [ #d #e #_ #I #K #V #H destruct
 117 | #L #I #V #H elim (lt_refl_false … H)
 118 | #L1 #L2 #I #V #e #_ #H elim (lt_refl_false … H)
 119 | #L1 #X #Y #V1 #Z #d #e #HL12 #HV12 #_ #I #L2 #V2 #H destruct -X Y Z
 120   /2 width=5/
 121 ]
 122 qed.
 123
 124 (* Basic_1: was: drop_gen_skip_r *)
 125 lemma drop_inv_skip2: ∀d,e,I,L1,K2,V2. ↓[d, e] L1 ≡ K2. 𝕓{I} V2 → 0 < d →
 126                       ∃∃K1,V1. ↓[d - 1, e] K1 ≡ K2 & ↑[d - 1, e] V2 ≡ V1 &
 127                                L1 = K1. 𝕓{I} V1.
 128 /2/ qed.
 129
 130 (* Basic properties *********************************************************)
 131
 132 (* Basic_1: was by definition: drop_refl *)
 133 lemma drop_refl: ∀L. ↓[0, 0] L ≡ L.
 134 #L elim L -L //
 135 qed.
 136
 137 lemma drop_drop_lt: ∀L1,L2,I,V,e.
 138                     ↓[0, e - 1] L1 ≡ L2 → 0 < e → ↓[0, e] L1. 𝕓{I} V ≡ L2.
 139 #L1 #L2 #I #V #e #HL12 #He >(plus_minus_m_m e 1) /2/
 140 qed.
 141
 142 lemma drop_lsubs_drop1_abbr: ∀L1,L2,d,e. L1 [d, e] ≼ L2 →
 143                              ∀K1,V,i. ↓[0, i] L1 ≡ K1. 𝕓{Abbr} V →
 144                              d ≤ i → i < d + e →
 145                              ∃∃K2. K1 [0, d + e - i - 1] ≼ K2 &
 146                                    ↓[0, i] L2 ≡ K2. 𝕓{Abbr} V.
 147 #L1 #L2 #d #e #H elim H -H L1 L2 d e
 148 [ #d #e #K1 #V #i #H
 149   lapply (drop_inv_atom1 … H) -H #H destruct
 150 | #L1 #L2 #K1 #V #i #_ #_ #H
 151   elim (lt_zero_false … H)
 152 | #L1 #L2 #V #e #HL12 #IHL12 #K1 #W #i #H #_ #Hie
 153   elim (drop_inv_O1 … H) -H * #Hi #HLK1
 154   [ -IHL12 Hie; destruct -i K1 W;
 155     <minus_n_O <minus_plus_m_m /2/
 156   | -HL12;
 157     elim (IHL12 … HLK1 ? ?) -IHL12 HLK1 // [2: /2/ ] -Hie >arith_g1 // /3/
 158   ]
 159 | #L1 #L2 #I #V1 #V2 #e #_ #IHL12 #K1 #W #i #H #_ #Hie
 160   elim (drop_inv_O1 … H) -H * #Hi #HLK1
 161   [ -IHL12 Hie Hi; destruct
 162   | elim (IHL12 … HLK1 ? ?) -IHL12 HLK1 // [2: /2/ ] -Hie >arith_g1 // /3/
 163   ]
 164 | #L1 #L2 #I1 #I2 #V1 #V2 #d #e #_ #IHL12 #K1 #V #i #H #Hdi >plus_plus_comm_23 #Hide
 165   lapply (plus_S_le_to_pos … Hdi) #Hi
 166   lapply (drop_inv_drop1 … H ?) -H // #HLK1
 167   elim (IHL12 … HLK1 ? ?) -IHL12 HLK1 [2: /2/ |3: /2/ ] -Hdi Hide >arith_g1 // /3/
 168 ]
 169 qed.
 170
 171 (* Basic forvard lemmas *****************************************************)
 172
 173 (* Basic_1: was: drop_S *)
 174 lemma drop_fwd_drop2: ∀L1,I2,K2,V2,e. ↓[O, e] L1 ≡ K2. 𝕓{I2} V2 →
 175                       ↓[O, e + 1] L1 ≡ K2.
 176 #L1 elim L1 -L1
 177 [ #I2 #K2 #V2 #e #H lapply (drop_inv_atom1 … H) -H #H destruct
 178 | #K1 #I1 #V1 #IHL1 #I2 #K2 #V2 #e #H
 179   elim (drop_inv_O1 … H) -H * #He #H
 180   [ -IHL1; destruct -e K2 I2 V2 /2/
 181   | @drop_drop >(plus_minus_m_m e 1) /2/
 182   ]
 183 ]
 184 qed.
 185
 186 lemma drop_fwd_lw: ∀L1,L2,d,e. ↓[d, e] L1 ≡ L2 → #[L2] ≤ #[L1].
 187 #L1 #L2 #d #e #H elim H -H L1 L2 d e // normalize
 188 [ /2/
 189 | #L1 #L2 #I #V1 #V2 #d #e #_ #HV21 #IHL12
 190   >(tw_lift … HV21) -HV21 /2/
 191 ]
 192 qed.
 193
 194 lemma drop_fwd_drop2_length: ∀L1,I2,K2,V2,e.
 195                              ↓[0, e] L1 ≡ K2. 𝕓{I2} V2 → e < |L1|.
 196 #L1 elim L1 -L1
 197 [ #I2 #K2 #V2 #e #H lapply (drop_inv_atom1 … H) -H #H destruct
 198 | #K1 #I1 #V1 #IHL1 #I2 #K2 #V2 #e #H
 199   elim (drop_inv_O1 … H) -H * #He #H
 200   [ -IHL1; destruct -e K2 I2 V2 //
 201   | lapply (IHL1 … H) -IHL1 H #HeK1 whd in ⊢ (? ? %) /2/
 202   ]
 203 ]
 204 qed.
 205
 206 lemma drop_fwd_O1_length: ∀L1,L2,e. ↓[0, e] L1 ≡ L2 → |L2| = |L1| - e.
 207 #L1 elim L1 -L1
 208 [ #L2 #e #H >(drop_inv_atom1 … H) -H //
 209 | #K1 #I1 #V1 #IHL1 #L2 #e #H
 210   elim (drop_inv_O1 … H) -H * #He #H
 211   [ -IHL1; destruct -e L2 //
 212   | lapply (IHL1 … H) -IHL1 H #H >H -H; normalize
 213     >minus_le_minus_minus_comm //
 214   ]
 215 ]
 216 qed.
 217
 218 (* Basic_1: removed theorems 49:
 219             drop_skip_flat
 220             cimp_flat_sx cimp_flat_dx cimp_bind cimp_getl_conf
 221             drop_clear drop_clear_O drop_clear_S
 222             clear_gen_sort clear_gen_bind clear_gen_flat clear_gen_flat_r
 223             clear_gen_all clear_clear clear_mono clear_trans clear_ctail clear_cle
 224             getl_ctail_clen getl_gen_tail clear_getl_trans getl_clear_trans
 225             getl_clear_bind getl_clear_conf getl_dec getl_drop getl_drop_conf_lt
 226             getl_drop_conf_ge getl_conf_ge_drop getl_drop_conf_rev
 227             drop_getl_trans_lt drop_getl_trans_le drop_getl_trans_ge
 228             getl_drop_trans getl_flt getl_gen_all getl_gen_sort getl_gen_O
 229             getl_gen_S getl_gen_2 getl_gen_flat getl_gen_bind getl_conf_le
 230             getl_trans getl_refl getl_head getl_flat getl_ctail getl_mono
 231 *)