matita/matita/contribs/lambda_delta/Basic_2/substitution/ldrop.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic_2/grammar/lenv_weight.ma".
  16 include "Basic_2/grammar/lsubs.ma".
  17 include "Basic_2/substitution/lift.ma".
  18
  19 (* LOCAL ENVIRONMENT SLICING ************************************************)
  20
  21 (* Basic_1: includes: ldrop_skip_bind *)
  22 inductive ldrop: nat → nat → relation lenv ≝
  23 | ldrop_atom: ∀d,e. ldrop d e (⋆) (⋆)
  24 | ldrop_pair: ∀L,I,V. ldrop 0 0 (L. 𝕓{I} V) (L. 𝕓{I} V)
  25 | ldrop_ldrop: ∀L1,L2,I,V,e. ldrop 0 e L1 L2 → ldrop 0 (e + 1) (L1. 𝕓{I} V) L2
  26 | ldrop_skip: ∀L1,L2,I,V1,V2,d,e.
  27               ldrop d e L1 L2 → ↑[d,e] V2 ≡ V1 →
  28               ldrop (d + 1) e (L1. 𝕓{I} V1) (L2. 𝕓{I} V2)
  29 .
  30
  31 interpretation "ldropping" 'RDrop d e L1 L2 = (ldrop d e L1 L2).
  32
  33 (* Basic inversion lemmas ***************************************************)
  34
  35 fact ldrop_inv_refl_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → d = 0 → e = 0 → L1 = L2.
  36 #d #e #L1 #L2 * -d -e -L1 -L2
  37 [ //
  38 | //
  39 | #L1 #L2 #I #V #e #_ #_ #H
  40   elim (plus_S_eq_O_false … H)
  41 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H
  42   elim (plus_S_eq_O_false … H)
  43 ]
  44 qed.
  45
  46 (* Basic_1: was: ldrop_gen_refl *)
  47 lemma ldrop_inv_refl: ∀L1,L2. ↓[0, 0] L1 ≡ L2 → L1 = L2.
  48 /2 width=5/ qed-.
  49
  50 fact ldrop_inv_atom1_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → L1 = ⋆ →
  51                           L2 = ⋆.
  52 #d #e #L1 #L2 * -d -e -L1 -L2
  53 [ //
  54 | #L #I #V #H destruct
  55 | #L1 #L2 #I #V #e #_ #H destruct
  56 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H destruct
  57 ]
  58 qed.
  59
  60 (* Basic_1: was: ldrop_gen_sort *)
  61 lemma ldrop_inv_atom1: ∀d,e,L2. ↓[d, e] ⋆ ≡ L2 → L2 = ⋆.
  62 /2 width=5/ qed-.
  63
  64 fact ldrop_inv_O1_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → d = 0 →
  65                        ∀K,I,V. L1 = K. 𝕓{I} V →
  66                        (e = 0 ∧ L2 = K. 𝕓{I} V) ∨
  67                        (0 < e ∧ ↓[d, e - 1] K ≡ L2).
  68 #d #e #L1 #L2 * -d -e -L1 -L2
  69 [ #d #e #_ #K #I #V #H destruct
  70 | #L #I #V #_ #K #J #W #HX destruct /3 width=1/
  71 | #L1 #L2 #I #V #e #HL12 #_ #K #J #W #H destruct /3 width=1/
  72 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H elim (plus_S_eq_O_false … H)
  73 ]
  74 qed.
  75
  76 lemma ldrop_inv_O1: ∀e,K,I,V,L2. ↓[0, e] K. 𝕓{I} V ≡ L2 →
  77                     (e = 0 ∧ L2 = K. 𝕓{I} V) ∨
  78                     (0 < e ∧ ↓[0, e - 1] K ≡ L2).
  79 /2 width=3/ qed-.
  80
  81 (* Basic_1: was: ldrop_gen_ldrop *)
  82 lemma ldrop_inv_ldrop1: ∀e,K,I,V,L2.
  83                         ↓[0, e] K. 𝕓{I} V ≡ L2 → 0 < e → ↓[0, e - 1] K ≡ L2.
  84 #e #K #I #V #L2 #H #He
  85 elim (ldrop_inv_O1 … H) -H * // #H destruct
  86 elim (lt_refl_false … He)
  87 qed-.
  88
  89 fact ldrop_inv_skip1_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → 0 < d →
  90                           ∀I,K1,V1. L1 = K1. 𝕓{I} V1 →
  91                           ∃∃K2,V2. ↓[d - 1, e] K1 ≡ K2 &
  92                                    ↑[d - 1, e] V2 ≡ V1 &
  93                                    L2 = K2. 𝕓{I} V2.
  94 #d #e #L1 #L2 * -d -e -L1 -L2
  95 [ #d #e #_ #I #K #V #H destruct
  96 | #L #I #V #H elim (lt_refl_false … H)
  97 | #L1 #L2 #I #V #e #_ #H elim (lt_refl_false … H)
  98 | #X #L2 #Y #Z #V2 #d #e #HL12 #HV12 #_ #I #L1 #V1 #H destruct /2 width=5/
  99 ]
 100 qed.
 101
 102 (* Basic_1: was: ldrop_gen_skip_l *)
 103 lemma ldrop_inv_skip1: ∀d,e,I,K1,V1,L2. ↓[d, e] K1. 𝕓{I} V1 ≡ L2 → 0 < d →
 104                        ∃∃K2,V2. ↓[d - 1, e] K1 ≡ K2 &
 105                                 ↑[d - 1, e] V2 ≡ V1 &
 106                                 L2 = K2. 𝕓{I} V2.
 107 /2 width=3/ qed-.
 108
 109 fact ldrop_inv_skip2_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → 0 < d →
 110                           ∀I,K2,V2. L2 = K2. 𝕓{I} V2 →
 111                           ∃∃K1,V1. ↓[d - 1, e] K1 ≡ K2 &
 112                                    ↑[d - 1, e] V2 ≡ V1 &
 113                                    L1 = K1. 𝕓{I} V1.
 114 #d #e #L1 #L2 * -d -e -L1 -L2
 115 [ #d #e #_ #I #K #V #H destruct
 116 | #L #I #V #H elim (lt_refl_false … H)
 117 | #L1 #L2 #I #V #e #_ #H elim (lt_refl_false … H)
 118 | #L1 #X #Y #V1 #Z #d #e #HL12 #HV12 #_ #I #L2 #V2 #H destruct /2 width=5/
 119 ]
 120 qed.
 121
 122 (* Basic_1: was: ldrop_gen_skip_r *)
 123 lemma ldrop_inv_skip2: ∀d,e,I,L1,K2,V2. ↓[d, e] L1 ≡ K2. 𝕓{I} V2 → 0 < d →
 124                        ∃∃K1,V1. ↓[d - 1, e] K1 ≡ K2 & ↑[d - 1, e] V2 ≡ V1 &
 125                                 L1 = K1. 𝕓{I} V1.
 126 /2 width=3/ qed-.
 127
 128 (* Basic properties *********************************************************)
 129
 130 (* Basic_1: was by definition: ldrop_refl *)
 131 lemma ldrop_refl: ∀L. ↓[0, 0] L ≡ L.
 132 #L elim L -L //
 133 qed.
 134
 135 lemma ldrop_ldrop_lt: ∀L1,L2,I,V,e.
 136                       ↓[0, e - 1] L1 ≡ L2 → 0 < e → ↓[0, e] L1. 𝕓{I} V ≡ L2.
 137 #L1 #L2 #I #V #e #HL12 #He >(plus_minus_m_m e 1) // /2 width=1/
 138 qed.
 139
 140 lemma ldrop_lsubs_ldrop1_abbr: ∀L1,L2,d,e. L1 [d, e] ≼ L2 →
 141                                ∀K1,V,i. ↓[0, i] L1 ≡ K1. 𝕓{Abbr} V →
 142                                d ≤ i → i < d + e →
 143                                ∃∃K2. K1 [0, d + e - i - 1] ≼ K2 &
 144                                      ↓[0, i] L2 ≡ K2. 𝕓{Abbr} V.
 145 #L1 #L2 #d #e #H elim H -L1 -L2 -d -e
 146 [ #d #e #K1 #V #i #H
 147   lapply (ldrop_inv_atom1 … H) -H #H destruct
 148 | #L1 #L2 #K1 #V #i #_ #_ #H
 149   elim (lt_zero_false … H)
 150 | #L1 #L2 #V #e #HL12 #IHL12 #K1 #W #i #H #_ #Hie
 151   elim (ldrop_inv_O1 … H) -H * #Hi #HLK1
 152   [ -IHL12 -Hie destruct
 153     <minus_n_O <minus_plus_m_m // /2 width=3/
 154   | -HL12
 155     elim (IHL12 … HLK1 ? ?) -IHL12 -HLK1 // /2 width=1/ -Hie >arith_g1 // /3 width=3/
 156   ]
 157 | #L1 #L2 #I #V1 #V2 #e #_ #IHL12 #K1 #W #i #H #_ #Hie
 158   elim (ldrop_inv_O1 … H) -H * #Hi #HLK1
 159   [ -IHL12 -Hie -Hi destruct
 160   | elim (IHL12 … HLK1 ? ?) -IHL12 -HLK1 // /2 width=1/ -Hie >arith_g1 // /3 width=3/
 161   ]
 162 | #L1 #L2 #I1 #I2 #V1 #V2 #d #e #_ #IHL12 #K1 #V #i #H #Hdi >plus_plus_comm_23 #Hide
 163   lapply (plus_S_le_to_pos … Hdi) #Hi
 164   lapply (ldrop_inv_ldrop1 … H ?) -H // #HLK1
 165   elim (IHL12 … HLK1 ? ?) -IHL12 -HLK1 /2 width=1/ -Hdi -Hide >arith_g1 // /3 width=3/
 166 ]
 167 qed.
 168
 169 (* Basic forvard lemmas *****************************************************)
 170
 171 (* Basic_1: was: ldrop_S *)
 172 lemma ldrop_fwd_ldrop2: ∀L1,I2,K2,V2,e. ↓[O, e] L1 ≡ K2. 𝕓{I2} V2 →
 173                         ↓[O, e + 1] L1 ≡ K2.
 174 #L1 elim L1 -L1
 175 [ #I2 #K2 #V2 #e #H lapply (ldrop_inv_atom1 … H) -H #H destruct
 176 | #K1 #I1 #V1 #IHL1 #I2 #K2 #V2 #e #H
 177   elim (ldrop_inv_O1 … H) -H * #He #H
 178   [ -IHL1 destruct /2 width=1/
 179   | @ldrop_ldrop >(plus_minus_m_m e 1) // /2 width=3/
 180   ]
 181 ]
 182 qed-.
 183
 184 lemma ldrop_fwd_lw: ∀L1,L2,d,e. ↓[d, e] L1 ≡ L2 → #[L2] ≤ #[L1].
 185 #L1 #L2 #d #e #H elim H -L1 -L2 -d -e // normalize
 186 [ /2 width=1/
 187 | #L1 #L2 #I #V1 #V2 #d #e #_ #HV21 #IHL12
 188   >(tw_lift … HV21) -HV21 /2 width=1/
 189 ]
 190 qed-.
 191
 192 lemma ldrop_fwd_ldrop2_length: ∀L1,I2,K2,V2,e.
 193                                ↓[0, e] L1 ≡ K2. 𝕓{I2} V2 → e < |L1|.
 194 #L1 elim L1 -L1
 195 [ #I2 #K2 #V2 #e #H lapply (ldrop_inv_atom1 … H) -H #H destruct
 196 | #K1 #I1 #V1 #IHL1 #I2 #K2 #V2 #e #H
 197   elim (ldrop_inv_O1 … H) -H * #He #H
 198   [ -IHL1 destruct //
 199   | lapply (IHL1 … H) -IHL1 -H #HeK1 whd in ⊢ (? ? %); /2 width=1/
 200   ]
 201 ]
 202 qed-.
 203
 204 lemma ldrop_fwd_O1_length: ∀L1,L2,e. ↓[0, e] L1 ≡ L2 → |L2| = |L1| - e.
 205 #L1 elim L1 -L1
 206 [ #L2 #e #H >(ldrop_inv_atom1 … H) -H //
 207 | #K1 #I1 #V1 #IHL1 #L2 #e #H
 208   elim (ldrop_inv_O1 … H) -H * #He #H
 209   [ -IHL1 destruct //
 210   | lapply (IHL1 … H) -IHL1 -H #H >H -H normalize
 211     >minus_le_minus_minus_comm //
 212   ]
 213 ]
 214 qed-.
 215
 216 (* Basic_1: removed theorems 49:
 217             ldrop_skip_flat
 218             cimp_flat_sx cimp_flat_dx cimp_bind cimp_getl_conf
 219             ldrop_clear ldrop_clear_O ldrop_clear_S
 220             clear_gen_sort clear_gen_bind clear_gen_flat clear_gen_flat_r
 221             clear_gen_all clear_clear clear_mono clear_trans clear_ctail clear_cle
 222             getl_ctail_clen getl_gen_tail clear_getl_trans getl_clear_trans
 223             getl_clear_bind getl_clear_conf getl_dec getl_ldrop getl_ldrop_conf_lt
 224             getl_ldrop_conf_ge getl_conf_ge_ldrop getl_ldrop_conf_rev
 225             ldrop_getl_trans_lt ldrop_getl_trans_le ldrop_getl_trans_ge
 226             getl_ldrop_trans getl_flt getl_gen_all getl_gen_sort getl_gen_O
 227             getl_gen_S getl_gen_2 getl_gen_flat getl_gen_bind getl_conf_le
 228             getl_trans getl_refl getl_head getl_flat getl_ctail getl_mono
 229 *)