matita/matita/contribs/lambda_delta/Basic_2/substitution/ldrop_ldrop.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic_2/substitution/lift_lift.ma".
  16 include "Basic_2/substitution/ldrop.ma".
  17
  18 (* DROPPING *****************************************************************)
  19
  20 (* Main properties **********************************************************)
  21
  22 (* Basic_1: was: ldrop_mono *)
  23 theorem ldrop_mono: ∀d,e,L,L1. ⇓[d, e] L ≡ L1 →
  24                     ∀L2. ⇓[d, e] L ≡ L2 → L1 = L2.
  25 #d #e #L #L1 #H elim H -d -e -L -L1
  26 [ #d #e #L2 #H
  27   >(ldrop_inv_atom1 … H) -L2 //
  28 | #K #I #V #L2 #HL12
  29    <(ldrop_inv_refl … HL12) -L2 //
  30 | #L #K #I #V #e #_ #IHLK #L2 #H
  31   lapply (ldrop_inv_ldrop1 … H ?) -H // /2 width=1/
  32 | #L #K1 #I #T #V1 #d #e #_ #HVT1 #IHLK1 #X #H
  33   elim (ldrop_inv_skip1 … H ?) -H // <minus_plus_m_m #K2 #V2 #HLK2 #HVT2 #H destruct
  34   >(lift_inj … HVT1 … HVT2) -HVT1 -HVT2
  35   >(IHLK1 … HLK2) -IHLK1 -HLK2 //
  36 ]
  37 qed-.
  38
  39 (* Basic_1: was: ldrop_conf_ge *)
  40 theorem ldrop_conf_ge: ∀d1,e1,L,L1. ⇓[d1, e1] L ≡ L1 →
  41                        ∀e2,L2. ⇓[0, e2] L ≡ L2 → d1 + e1 ≤ e2 →
  42                        ⇓[0, e2 - e1] L1 ≡ L2.
  43 #d1 #e1 #L #L1 #H elim H -d1 -e1 -L -L1
  44 [ #d #e #e2 #L2 #H
  45   >(ldrop_inv_atom1 … H) -L2 //
  46 | //
  47 | #L #K #I #V #e #_ #IHLK #e2 #L2 #H #He2
  48   lapply (ldrop_inv_ldrop1 … H ?) -H /2 width=2/ #HL2
  49   <minus_plus >minus_minus_comm /3 width=1/
  50 | #L #K #I #V1 #V2 #d #e #_ #_ #IHLK #e2 #L2 #H #Hdee2
  51   lapply (transitive_le 1 … Hdee2) // #He2
  52   lapply (ldrop_inv_ldrop1 … H ?) -H // -He2 #HL2
  53   lapply (transitive_le (1 + e) … Hdee2) // #Hee2
  54   @ldrop_ldrop_lt >minus_minus_comm /3 width=1/ (**) (* explicit constructor *)
  55 ]
  56 qed.
  57
  58 (* Basic_1: was: ldrop_conf_lt *)
  59 theorem ldrop_conf_lt: ∀d1,e1,L,L1. ⇓[d1, e1] L ≡ L1 →
  60                        ∀e2,K2,I,V2. ⇓[0, e2] L ≡ K2. 𝕓{I} V2 →
  61                        e2 < d1 → let d ≝ d1 - e2 - 1 in
  62                        ∃∃K1,V1. ⇓[0, e2] L1 ≡ K1. 𝕓{I} V1 &
  63                                 ⇓[d, e1] K2 ≡ K1 & ⇑[d, e1] V1 ≡ V2.
  64 #d1 #e1 #L #L1 #H elim H -d1 -e1 -L -L1
  65 [ #d #e #e2 #K2 #I #V2 #H
  66   lapply (ldrop_inv_atom1 … H) -H #H destruct
  67 | #L #I #V #e2 #K2 #J #V2 #_ #H
  68   elim (lt_zero_false … H)
  69 | #L1 #L2 #I #V #e #_ #_ #e2 #K2 #J #V2 #_ #H
  70   elim (lt_zero_false … H)
  71 | #L1 #L2 #I #V1 #V2 #d #e #HL12 #HV12 #IHL12 #e2 #K2 #J #V #H #He2d
  72   elim (ldrop_inv_O1 … H) -H *
  73   [ -IHL12 -He2d #H1 #H2 destruct /2 width=5/
  74   | -HL12 -HV12 #He #HLK
  75     elim (IHL12 … HLK ?) -IHL12 -HLK [ <minus_minus /3 width=5/ | /2 width=1/ ] (**) (* a bit slow *)
  76   ]
  77 ]
  78 qed.
  79
  80 (* Basic_1: was: ldrop_trans_le *)
  81 theorem ldrop_trans_le: ∀d1,e1,L1,L. ⇓[d1, e1] L1 ≡ L →
  82                         ∀e2,L2. ⇓[0, e2] L ≡ L2 → e2 ≤ d1 →
  83                         ∃∃L0. ⇓[0, e2] L1 ≡ L0 & ⇓[d1 - e2, e1] L0 ≡ L2.
  84 #d1 #e1 #L1 #L #H elim H -d1 -e1 -L1 -L
  85 [ #d #e #e2 #L2 #H
  86   >(ldrop_inv_atom1 … H) -L2 /2 width=3/
  87 | #K #I #V #e2 #L2 #HL2 #H
  88   lapply (le_n_O_to_eq … H) -H #H destruct /2 width=3/
  89 | #L1 #L2 #I #V #e #_ #IHL12 #e2 #L #HL2 #H
  90   lapply (le_n_O_to_eq … H) -H #H destruct
  91   elim (IHL12 … HL2 ?) -IHL12 -HL2 // #L0 #H #HL0
  92   lapply (ldrop_inv_refl … H) -H #H destruct /3 width=5/
  93 | #L1 #L2 #I #V1 #V2 #d #e #HL12 #HV12 #IHL12 #e2 #L #H #He2d
  94   elim (ldrop_inv_O1 … H) -H *
  95   [ -He2d -IHL12 #H1 #H2 destruct /3 width=5/
  96   | -HL12 -HV12 #He2 #HL2
  97     elim (IHL12 … HL2 ?) -L2 [ >minus_le_minus_minus_comm // /3 width=3/ | /2 width=1/ ]
  98   ]
  99 ]
 100 qed.
 101
 102 (* Basic_1: was: ldrop_trans_ge *)
 103 theorem ldrop_trans_ge: ∀d1,e1,L1,L. ⇓[d1, e1] L1 ≡ L →
 104                         ∀e2,L2. ⇓[0, e2] L ≡ L2 → d1 ≤ e2 → ⇓[0, e1 + e2] L1 ≡ L2.
 105 #d1 #e1 #L1 #L #H elim H -d1 -e1 -L1 -L
 106 [ #d #e #e2 #L2 #H
 107   >(ldrop_inv_atom1 … H) -H -L2 //
 108 | //
 109 | /3 width=1/
 110 | #L1 #L2 #I #V1 #V2 #d #e #H_ #_ #IHL12 #e2 #L #H #Hde2
 111   lapply (lt_to_le_to_lt 0 … Hde2) // #He2
 112   lapply (lt_to_le_to_lt … (e + e2) He2 ?) // #Hee2
 113   lapply (ldrop_inv_ldrop1 … H ?) -H // #HL2
 114   @ldrop_ldrop_lt // >le_plus_minus // @IHL12 /2 width=1/ (**) (* explicit constructor *)
 115 ]
 116 qed.
 117
 118 theorem ldrop_trans_ge_comm: ∀d1,e1,e2,L1,L2,L.
 119                              ⇓[d1, e1] L1 ≡ L → ⇓[0, e2] L ≡ L2 → d1 ≤ e2 →
 120                              ⇓[0, e2 + e1] L1 ≡ L2.
 121 #e1 #e1 #e2 >commutative_plus /2 width=5/
 122 qed.
 123
 124 (* Basic_1: was: ldrop_conf_rev *)
 125 axiom ldrop_div: ∀e1,L1,L. ⇓[0, e1] L1 ≡ L → ∀e2,L2. ⇓[0, e2] L2 ≡ L →
 126                  ∃∃L0. ⇓[0, e1] L0 ≡ L2 & ⇓[e1, e2] L0 ≡ L1.