matita/matita/contribs/lambda_delta/Basic_2/substitution/lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic_2/grammar/term_weight.ma".
  16
  17 (* RELOCATION ***************************************************************)
  18
  19 (* Basic_1: includes:
  20             lift_sort lift_lref_lt lift_lref_ge lift_bind lift_flat
  21 *)
  22 inductive lift: nat → nat → relation term ≝
  23 | lift_sort   : ∀k,d,e. lift d e (⋆k) (⋆k)
  24 | lift_lref_lt: ∀i,d,e. i < d → lift d e (#i) (#i)
  25 | lift_lref_ge: ∀i,d,e. d ≤ i → lift d e (#i) (#(i + e))
  26 | lift_bind   : ∀I,V1,V2,T1,T2,d,e.
  27                 lift d e V1 V2 → lift (d + 1) e T1 T2 →
  28                 lift d e (𝕓{I} V1. T1) (𝕓{I} V2. T2)
  29 | lift_flat   : ∀I,V1,V2,T1,T2,d,e.
  30                 lift d e V1 V2 → lift d e T1 T2 →
  31                 lift d e (𝕗{I} V1. T1) (𝕗{I} V2. T2)
  32 .
  33
  34 interpretation "relocation" 'RLift d e T1 T2 = (lift d e T1 T2).
  35
  36 (* Basic properties *********************************************************)
  37
  38 (* Basic_1: was: lift_lref_gt *)
  39 lemma lift_lref_ge_minus: ∀d,e,i. d + e ≤ i → ↑[d, e] #(i - e) ≡ #i.
  40 #d #e #i #H >(plus_minus_m_m i e) in ⊢ (? ? ? ? %) /3/
  41 qed.
  42
  43 (* Basic_1: was: lift_r *)
  44 lemma lift_refl: ∀T,d. ↑[d, 0] T ≡ T.
  45 #T elim T -T
  46 [ * #i // #d elim (lt_or_ge i d) /2/
  47 | * /2/
  48 ]
  49 qed.
  50
  51 lemma lift_total: ∀T1,d,e. ∃T2. ↑[d,e] T1 ≡ T2.
  52 #T1 elim T1 -T1
  53 [ * #i /2/ #d #e elim (lt_or_ge i d) /3/
  54 | * #I #V1 #T1 #IHV1 #IHT1 #d #e
  55   elim (IHV1 d e) -IHV1 #V2 #HV12
  56   [ elim (IHT1 (d+1) e) -IHT1 /3/
  57   | elim (IHT1 d e) -IHT1 /3/
  58   ]
  59 ]
  60 qed.
  61
  62 (* Basic_1: was: lift_free (right to left) *)
  63 lemma lift_split: ∀d1,e2,T1,T2. ↑[d1, e2] T1 ≡ T2 → ∀d2,e1.
  64                                 d1 ≤ d2 → d2 ≤ d1 + e1 → e1 ≤ e2 →
  65                                 ∃∃T. ↑[d1, e1] T1 ≡ T & ↑[d2, e2 - e1] T ≡ T2.
  66 #d1 #e2 #T1 #T2 #H elim H -H d1 e2 T1 T2
  67 [ /3/
  68 | #i #d1 #e2 #Hid1 #d2 #e1 #Hd12 #_ #_
  69   lapply (lt_to_le_to_lt … Hid1 Hd12) -Hd12 #Hid2 /4/
  70 | #i #d1 #e2 #Hid1 #d2 #e1 #_ #Hd21 #He12
  71   lapply (transitive_le …(i+e1) Hd21 ?) /2/ -Hd21 #Hd21
  72   <(arith_d1 i e2 e1) // /3/
  73 | #I #V1 #V2 #T1 #T2 #d1 #e2 #_ #_ #IHV #IHT #d2 #e1 #Hd12 #Hd21 #He12
  74   elim (IHV … Hd12 Hd21 He12) -IHV #V0 #HV0a #HV0b
  75   elim (IHT (d2+1) … ? ? He12) /3 width = 5/
  76 | #I #V1 #V2 #T1 #T2 #d1 #e2 #_ #_ #IHV #IHT #d2 #e1 #Hd12 #Hd21 #He12
  77   elim (IHV … Hd12 Hd21 He12) -IHV #V0 #HV0a #HV0b
  78   elim (IHT d2 … ? ? He12) /3 width = 5/
  79 ]
  80 qed.
  81
  82 (* Basic forward lemmas *****************************************************)
  83
  84 lemma tw_lift: ∀d,e,T1,T2. ↑[d, e] T1 ≡ T2 → #[T1] = #[T2].
  85 #d #e #T1 #T2 #H elim H -d e T1 T2; normalize //
  86 qed.
  87
  88 (* Basic inversion lemmas ***************************************************)
  89
  90 fact lift_inv_refl_aux: ∀d,e,T1,T2. ↑[d, e] T1 ≡ T2 → e = 0 → T1 = T2.
  91 #d #e #T1 #T2 #H elim H -H d e T1 T2 /3/
  92 qed.
  93
  94 lemma lift_inv_refl: ∀d,T1,T2. ↑[d, 0] T1 ≡ T2 → T1 = T2.
  95 /2/ qed.
  96
  97 fact lift_inv_sort1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀k. T1 = ⋆k → T2 = ⋆k.
  98 #d #e #T1 #T2 * -d e T1 T2 //
  99 [ #i #d #e #_ #k #H destruct
 100 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 101 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 102 ]
 103 qed.
 104
 105 lemma lift_inv_sort1: ∀d,e,T2,k. ↑[d,e] ⋆k ≡ T2 → T2 = ⋆k.
 106 /2 width=5/ qed.
 107
 108 fact lift_inv_lref1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀i. T1 = #i →
 109                          (i < d ∧ T2 = #i) ∨ (d ≤ i ∧ T2 = #(i + e)).
 110 #d #e #T1 #T2 * -d e T1 T2
 111 [ #k #d #e #i #H destruct
 112 | #j #d #e #Hj #i #Hi destruct /3/
 113 | #j #d #e #Hj #i #Hi destruct /3/
 114 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 115 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 116 ]
 117 qed.
 118
 119 lemma lift_inv_lref1: ∀d,e,T2,i. ↑[d,e] #i ≡ T2 →
 120                       (i < d ∧ T2 = #i) ∨ (d ≤ i ∧ T2 = #(i + e)).
 121 /2/ qed.
 122
 123 lemma lift_inv_lref1_lt: ∀d,e,T2,i. ↑[d,e] #i ≡ T2 → i < d → T2 = #i.
 124 #d #e #T2 #i #H elim (lift_inv_lref1 … H) -H * //
 125 #Hdi #_ #Hid lapply (le_to_lt_to_lt … Hdi Hid) -Hdi Hid #Hdd
 126 elim (lt_refl_false … Hdd)
 127 qed.
 128
 129 lemma lift_inv_lref1_ge: ∀d,e,T2,i. ↑[d,e] #i ≡ T2 → d ≤ i → T2 = #(i + e).
 130 #d #e #T2 #i #H elim (lift_inv_lref1 … H) -H * //
 131 #Hid #_ #Hdi lapply (le_to_lt_to_lt … Hdi Hid) -Hdi Hid #Hdd
 132 elim (lt_refl_false … Hdd)
 133 qed.
 134
 135 fact lift_inv_bind1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 136                          ∀I,V1,U1. T1 = 𝕓{I} V1.U1 →
 137                          ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 138                                   T2 = 𝕓{I} V2. U2.
 139 #d #e #T1 #T2 * -d e T1 T2
 140 [ #k #d #e #I #V1 #U1 #H destruct
 141 | #i #d #e #_ #I #V1 #U1 #H destruct
 142 | #i #d #e #_ #I #V1 #U1 #H destruct
 143 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct /2 width=5/
 144 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct
 145 ]
 146 qed.
 147
 148 lemma lift_inv_bind1: ∀d,e,T2,I,V1,U1. ↑[d,e] 𝕓{I} V1. U1 ≡ T2 →
 149                       ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 150                                T2 = 𝕓{I} V2. U2.
 151 /2/ qed.
 152
 153 fact lift_inv_flat1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 154                          ∀I,V1,U1. T1 = 𝕗{I} V1.U1 →
 155                          ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 156                                   T2 = 𝕗{I} V2. U2.
 157 #d #e #T1 #T2 * -d e T1 T2
 158 [ #k #d #e #I #V1 #U1 #H destruct
 159 | #i #d #e #_ #I #V1 #U1 #H destruct
 160 | #i #d #e #_ #I #V1 #U1 #H destruct
 161 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct
 162 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct /2 width=5/
 163 ]
 164 qed.
 165
 166 lemma lift_inv_flat1: ∀d,e,T2,I,V1,U1. ↑[d,e] 𝕗{I} V1. U1 ≡ T2 →
 167                       ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 168                                T2 = 𝕗{I} V2. U2.
 169 /2/ qed.
 170
 171 fact lift_inv_sort2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀k. T2 = ⋆k → T1 = ⋆k.
 172 #d #e #T1 #T2 * -d e T1 T2 //
 173 [ #i #d #e #_ #k #H destruct
 174 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 175 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 176 ]
 177 qed.
 178
 179 (* Basic_1: was: lift_gen_sort *)
 180 lemma lift_inv_sort2: ∀d,e,T1,k. ↑[d,e] T1 ≡ ⋆k → T1 = ⋆k.
 181 /2 width=5/ qed.
 182
 183 fact lift_inv_lref2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀i. T2 = #i →
 184                          (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
 185 #d #e #T1 #T2 * -d e T1 T2
 186 [ #k #d #e #i #H destruct
 187 | #j #d #e #Hj #i #Hi destruct /3/
 188 | #j #d #e #Hj #i #Hi destruct <minus_plus_m_m /4/
 189 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 190 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 191 ]
 192 qed.
 193
 194 (* Basic_1: was: lift_gen_lref *)
 195 lemma lift_inv_lref2: ∀d,e,T1,i. ↑[d,e] T1 ≡ #i →
 196                       (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
 197 /2/ qed.
 198
 199 (* Basic_1: was: lift_gen_lref_lt *)
 200 lemma lift_inv_lref2_lt: ∀d,e,T1,i. ↑[d,e] T1 ≡ #i → i < d → T1 = #i.
 201 #d #e #T1 #i #H elim (lift_inv_lref2 … H) -H * //
 202 #Hdi #_ #Hid lapply (le_to_lt_to_lt … Hdi Hid) -Hdi Hid #Hdd
 203 elim (plus_lt_false … Hdd)
 204 qed.
 205
 206 (* Basic_1: was: lift_gen_lref_false *)
 207
 208 (* Basic_1: was: lift_gen_lref_ge *)
 209 lemma lift_inv_lref2_ge: ∀d,e,T1,i. ↑[d,e] T1 ≡ #i → d + e ≤ i → T1 = #(i - e).
 210 #d #e #T1 #i #H elim (lift_inv_lref2 … H) -H * //
 211 #Hid #_ #Hdi lapply (le_to_lt_to_lt … Hdi Hid) -Hdi Hid #Hdd
 212 elim (plus_lt_false … Hdd)
 213 qed.
 214
 215 fact lift_inv_bind2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 216                          ∀I,V2,U2. T2 = 𝕓{I} V2.U2 →
 217                          ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 218                                   T1 = 𝕓{I} V1. U1.
 219 #d #e #T1 #T2 * -d e T1 T2
 220 [ #k #d #e #I #V2 #U2 #H destruct
 221 | #i #d #e #_ #I #V2 #U2 #H destruct
 222 | #i #d #e #_ #I #V2 #U2 #H destruct
 223 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct /2 width=5/
 224 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct
 225 ]
 226 qed.
 227
 228 (* Basic_1: was: lift_gen_bind *)
 229 lemma lift_inv_bind2: ∀d,e,T1,I,V2,U2. ↑[d,e] T1 ≡  𝕓{I} V2. U2 →
 230                       ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 231                                T1 = 𝕓{I} V1. U1.
 232 /2/ qed.
 233
 234 fact lift_inv_flat2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 235                          ∀I,V2,U2. T2 = 𝕗{I} V2.U2 →
 236                          ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 237                                   T1 = 𝕗{I} V1. U1.
 238 #d #e #T1 #T2 * -d e T1 T2
 239 [ #k #d #e #I #V2 #U2 #H destruct
 240 | #i #d #e #_ #I #V2 #U2 #H destruct
 241 | #i #d #e #_ #I #V2 #U2 #H destruct
 242 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct
 243 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct /2 width = 5/
 244 ]
 245 qed.
 246
 247 (* Basic_1: was: lift_gen_flat *)
 248 lemma lift_inv_flat2: ∀d,e,T1,I,V2,U2. ↑[d,e] T1 ≡  𝕗{I} V2. U2 →
 249                       ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 250                                T1 = 𝕗{I} V1. U1.
 251 /2/ qed.
 252
 253 (* Basic_1: removed theorems 7:
 254             lift_head lift_gen_head
 255             lift_weight_map lift_weight lift_weight_add lift_weight_add_O
 256             lift_tlt_dx
 257 *)