matita/matita/contribs/lambda_delta/Basic_2/substitution/lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic_2/grammar/term_weight.ma".
  16
  17 (* RELOCATION ***************************************************************)
  18
  19 (* Basic_1: includes:
  20             lift_sort lift_lref_lt lift_lref_ge lift_bind lift_flat
  21 *)
  22 inductive lift: nat → nat → relation term ≝
  23 | lift_sort   : ∀k,d,e. lift d e (⋆k) (⋆k)
  24 | lift_lref_lt: ∀i,d,e. i < d → lift d e (#i) (#i)
  25 | lift_lref_ge: ∀i,d,e. d ≤ i → lift d e (#i) (#(i + e))
  26 | lift_gref   : ∀p,d,e. lift d e (§p) (§p)
  27 | lift_bind   : ∀I,V1,V2,T1,T2,d,e.
  28                 lift d e V1 V2 → lift (d + 1) e T1 T2 →
  29                 lift d e (𝕓{I} V1. T1) (𝕓{I} V2. T2)
  30 | lift_flat   : ∀I,V1,V2,T1,T2,d,e.
  31                 lift d e V1 V2 → lift d e T1 T2 →
  32                 lift d e (𝕗{I} V1. T1) (𝕗{I} V2. T2)
  33 .
  34
  35 interpretation "relocation" 'RLift d e T1 T2 = (lift d e T1 T2).
  36
  37 (* Basic inversion lemmas ***************************************************)
  38
  39 fact lift_inv_refl_O2_aux: ∀d,e,T1,T2. ⇑[d, e] T1 ≡ T2 → e = 0 → T1 = T2.
  40 #d #e #T1 #T2 #H elim H -d -e -T1 -T2 // /3 width=1/
  41 qed.
  42
  43 lemma lift_inv_refl_O2: ∀d,T1,T2. ⇑[d, 0] T1 ≡ T2 → T1 = T2.
  44 /2 width=4/ qed-.
  45
  46 fact lift_inv_sort1_aux: ∀d,e,T1,T2. ⇑[d,e] T1 ≡ T2 → ∀k. T1 = ⋆k → T2 = ⋆k.
  47 #d #e #T1 #T2 * -d -e -T1 -T2 //
  48 [ #i #d #e #_ #k #H destruct
  49 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
  50 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
  51 ]
  52 qed.
  53
  54 lemma lift_inv_sort1: ∀d,e,T2,k. ⇑[d,e] ⋆k ≡ T2 → T2 = ⋆k.
  55 /2 width=5/ qed-.
  56
  57 fact lift_inv_lref1_aux: ∀d,e,T1,T2. ⇑[d,e] T1 ≡ T2 → ∀i. T1 = #i →
  58                          (i < d ∧ T2 = #i) ∨ (d ≤ i ∧ T2 = #(i + e)).
  59 #d #e #T1 #T2 * -d -e -T1 -T2
  60 [ #k #d #e #i #H destruct
  61 | #j #d #e #Hj #i #Hi destruct /3 width=1/
  62 | #j #d #e #Hj #i #Hi destruct /3 width=1/
  63 | #p #d #e #i #H destruct
  64 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
  65 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
  66 ]
  67 qed.
  68
  69 lemma lift_inv_lref1: ∀d,e,T2,i. ⇑[d,e] #i ≡ T2 →
  70                       (i < d ∧ T2 = #i) ∨ (d ≤ i ∧ T2 = #(i + e)).
  71 /2 width=3/ qed-.
  72
  73 lemma lift_inv_lref1_lt: ∀d,e,T2,i. ⇑[d,e] #i ≡ T2 → i < d → T2 = #i.
  74 #d #e #T2 #i #H elim (lift_inv_lref1 … H) -H * //
  75 #Hdi #_ #Hid lapply (le_to_lt_to_lt … Hdi Hid) -Hdi -Hid #Hdd
  76 elim (lt_refl_false … Hdd)
  77 qed-.
  78
  79 lemma lift_inv_lref1_ge: ∀d,e,T2,i. ⇑[d,e] #i ≡ T2 → d ≤ i → T2 = #(i + e).
  80 #d #e #T2 #i #H elim (lift_inv_lref1 … H) -H * //
  81 #Hid #_ #Hdi lapply (le_to_lt_to_lt … Hdi Hid) -Hdi -Hid #Hdd
  82 elim (lt_refl_false … Hdd)
  83 qed-.
  84
  85 fact lift_inv_gref1_aux: ∀d,e,T1,T2. ⇑[d,e] T1 ≡ T2 → ∀p. T1 = §p → T2 = §p.
  86 #d #e #T1 #T2 * -d -e -T1 -T2 //
  87 [ #i #d #e #_ #k #H destruct
  88 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
  89 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
  90 ]
  91 qed.
  92
  93 lemma lift_inv_gref1: ∀d,e,T2,p. ⇑[d,e] §p ≡ T2 → T2 = §p.
  94 /2 width=5/ qed-.
  95
  96 fact lift_inv_bind1_aux: ∀d,e,T1,T2. ⇑[d,e] T1 ≡ T2 →
  97                          ∀I,V1,U1. T1 = 𝕓{I} V1.U1 →
  98                          ∃∃V2,U2. ⇑[d,e] V1 ≡ V2 & ⇑[d+1,e] U1 ≡ U2 &
  99                                   T2 = 𝕓{I} V2. U2.
 100 #d #e #T1 #T2 * -d -e -T1 -T2
 101 [ #k #d #e #I #V1 #U1 #H destruct
 102 | #i #d #e #_ #I #V1 #U1 #H destruct
 103 | #i #d #e #_ #I #V1 #U1 #H destruct
 104 | #p #d #e #I #V1 #U1 #H destruct
 105 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct /2 width=5/
 106 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct
 107 ]
 108 qed.
 109
 110 lemma lift_inv_bind1: ∀d,e,T2,I,V1,U1. ⇑[d,e] 𝕓{I} V1. U1 ≡ T2 →
 111                       ∃∃V2,U2. ⇑[d,e] V1 ≡ V2 & ⇑[d+1,e] U1 ≡ U2 &
 112                                T2 = 𝕓{I} V2. U2.
 113 /2 width=3/ qed-.
 114
 115 fact lift_inv_flat1_aux: ∀d,e,T1,T2. ⇑[d,e] T1 ≡ T2 →
 116                          ∀I,V1,U1. T1 = 𝕗{I} V1.U1 →
 117                          ∃∃V2,U2. ⇑[d,e] V1 ≡ V2 & ⇑[d,e] U1 ≡ U2 &
 118                                   T2 = 𝕗{I} V2. U2.
 119 #d #e #T1 #T2 * -d -e -T1 -T2
 120 [ #k #d #e #I #V1 #U1 #H destruct
 121 | #i #d #e #_ #I #V1 #U1 #H destruct
 122 | #i #d #e #_ #I #V1 #U1 #H destruct
 123 | #p #d #e #I #V1 #U1 #H destruct
 124 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct
 125 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct /2 width=5/
 126 ]
 127 qed.
 128
 129 lemma lift_inv_flat1: ∀d,e,T2,I,V1,U1. ⇑[d,e] 𝕗{I} V1. U1 ≡ T2 →
 130                       ∃∃V2,U2. ⇑[d,e] V1 ≡ V2 & ⇑[d,e] U1 ≡ U2 &
 131                                T2 = 𝕗{I} V2. U2.
 132 /2 width=3/ qed-.
 133
 134 fact lift_inv_sort2_aux: ∀d,e,T1,T2. ⇑[d,e] T1 ≡ T2 → ∀k. T2 = ⋆k → T1 = ⋆k.
 135 #d #e #T1 #T2 * -d -e -T1 -T2 //
 136 [ #i #d #e #_ #k #H destruct
 137 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 138 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 139 ]
 140 qed.
 141
 142 (* Basic_1: was: lift_gen_sort *)
 143 lemma lift_inv_sort2: ∀d,e,T1,k. ⇑[d,e] T1 ≡ ⋆k → T1 = ⋆k.
 144 /2 width=5/ qed-.
 145
 146 fact lift_inv_lref2_aux: ∀d,e,T1,T2. ⇑[d,e] T1 ≡ T2 → ∀i. T2 = #i →
 147                          (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
 148 #d #e #T1 #T2 * -d -e -T1 -T2
 149 [ #k #d #e #i #H destruct
 150 | #j #d #e #Hj #i #Hi destruct /3 width=1/
 151 | #j #d #e #Hj #i #Hi destruct <minus_plus_m_m /4 width=1/
 152 | #p #d #e #i #H destruct
 153 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 154 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 155 ]
 156 qed.
 157
 158 (* Basic_1: was: lift_gen_lref *)
 159 lemma lift_inv_lref2: ∀d,e,T1,i. ⇑[d,e] T1 ≡ #i →
 160                       (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
 161 /2 width=3/ qed-.
 162
 163 (* Basic_1: was: lift_gen_lref_lt *)
 164 lemma lift_inv_lref2_lt: ∀d,e,T1,i. ⇑[d,e] T1 ≡ #i → i < d → T1 = #i.
 165 #d #e #T1 #i #H elim (lift_inv_lref2 … H) -H * //
 166 #Hdi #_ #Hid lapply (le_to_lt_to_lt … Hdi Hid) -Hdi -Hid #Hdd
 167 elim (lt_inv_plus_l … Hdd) -Hdd #Hdd
 168 elim (lt_refl_false … Hdd)
 169 qed-.
 170
 171 (* Basic_1: was: lift_gen_lref_false *)
 172 lemma lift_inv_lref2_be: ∀d,e,T1,i. ⇑[d,e] T1 ≡ #i →
 173                          d ≤ i → i < d + e → False.
 174 #d #e #T1 #i #H elim (lift_inv_lref2 … H) -H *
 175 [ #H1 #_ #H2 #_ | #H2 #_ #_ #H1 ]
 176 lapply (le_to_lt_to_lt … H2 H1) -H2 -H1 #H
 177 elim (lt_refl_false … H)
 178 qed-.
 179
 180 (* Basic_1: was: lift_gen_lref_ge *)
 181 lemma lift_inv_lref2_ge: ∀d,e,T1,i. ⇑[d,e] T1 ≡ #i → d + e ≤ i → T1 = #(i - e).
 182 #d #e #T1 #i #H elim (lift_inv_lref2 … H) -H * //
 183 #Hid #_ #Hdi lapply (le_to_lt_to_lt … Hdi Hid) -Hdi -Hid #Hdd
 184 elim (lt_inv_plus_l … Hdd) -Hdd #Hdd
 185 elim (lt_refl_false … Hdd)
 186 qed-.
 187
 188 fact lift_inv_gref2_aux: ∀d,e,T1,T2. ⇑[d,e] T1 ≡ T2 → ∀p. T2 = §p → T1 = §p.
 189 #d #e #T1 #T2 * -d -e -T1 -T2 //
 190 [ #i #d #e #_ #k #H destruct
 191 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 192 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 193 ]
 194 qed.
 195
 196 lemma lift_inv_gref2: ∀d,e,T1,p. ⇑[d,e] T1 ≡ §p → T1 = §p.
 197 /2 width=5/ qed-.
 198
 199 fact lift_inv_bind2_aux: ∀d,e,T1,T2. ⇑[d,e] T1 ≡ T2 →
 200                          ∀I,V2,U2. T2 = 𝕓{I} V2.U2 →
 201                          ∃∃V1,U1. ⇑[d,e] V1 ≡ V2 & ⇑[d+1,e] U1 ≡ U2 &
 202                                   T1 = 𝕓{I} V1. U1.
 203 #d #e #T1 #T2 * -d -e -T1 -T2
 204 [ #k #d #e #I #V2 #U2 #H destruct
 205 | #i #d #e #_ #I #V2 #U2 #H destruct
 206 | #i #d #e #_ #I #V2 #U2 #H destruct
 207 | #p #d #e #I #V2 #U2 #H destruct
 208 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct /2 width=5/
 209 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct
 210 ]
 211 qed.
 212
 213 (* Basic_1: was: lift_gen_bind *)
 214 lemma lift_inv_bind2: ∀d,e,T1,I,V2,U2. ⇑[d,e] T1 ≡  𝕓{I} V2. U2 →
 215                       ∃∃V1,U1. ⇑[d,e] V1 ≡ V2 & ⇑[d+1,e] U1 ≡ U2 &
 216                                T1 = 𝕓{I} V1. U1.
 217 /2 width=3/ qed-.
 218
 219 fact lift_inv_flat2_aux: ∀d,e,T1,T2. ⇑[d,e] T1 ≡ T2 →
 220                          ∀I,V2,U2. T2 = 𝕗{I} V2.U2 →
 221                          ∃∃V1,U1. ⇑[d,e] V1 ≡ V2 & ⇑[d,e] U1 ≡ U2 &
 222                                   T1 = 𝕗{I} V1. U1.
 223 #d #e #T1 #T2 * -d -e -T1 -T2
 224 [ #k #d #e #I #V2 #U2 #H destruct
 225 | #i #d #e #_ #I #V2 #U2 #H destruct
 226 | #i #d #e #_ #I #V2 #U2 #H destruct
 227 | #p #d #e #I #V2 #U2 #H destruct
 228 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct
 229 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct /2 width=5/
 230 ]
 231 qed.
 232
 233 (* Basic_1: was: lift_gen_flat *)
 234 lemma lift_inv_flat2: ∀d,e,T1,I,V2,U2. ⇑[d,e] T1 ≡  𝕗{I} V2. U2 →
 235                       ∃∃V1,U1. ⇑[d,e] V1 ≡ V2 & ⇑[d,e] U1 ≡ U2 &
 236                                T1 = 𝕗{I} V1. U1.
 237 /2 width=3/ qed-.
 238
 239 lemma lift_inv_pair_xy_x: ∀d,e,I,V,T. ⇑[d, e] 𝕔{I} V. T ≡ V → False.
 240 #d #e #J #V elim V -V
 241 [ * #i #T #H
 242   [ lapply (lift_inv_sort2 … H) -H #H destruct
 243   | elim (lift_inv_lref2 … H) -H * #_ #H destruct
 244   | lapply (lift_inv_gref2 … H) -H #H destruct
 245   ]
 246 | * #I #W2 #U2 #IHW2 #_ #T #H
 247   [ elim (lift_inv_bind2 … H) -H #W1 #U1 #HW12 #_ #H destruct /2 width=2/
 248   | elim (lift_inv_flat2 … H) -H #W1 #U1 #HW12 #_ #H destruct /2 width=2/
 249   ]
 250 ]
 251 qed-.
 252
 253 lemma lift_inv_pair_xy_y: ∀I,T,V,d,e. ⇑[d, e] 𝕔{I} V. T ≡ T → False.
 254 #J #T elim T -T
 255 [ * #i #V #d #e #H
 256   [ lapply (lift_inv_sort2 … H) -H #H destruct
 257   | elim (lift_inv_lref2 … H) -H * #_ #H destruct
 258   | lapply (lift_inv_gref2 … H) -H #H destruct
 259   ]
 260 | * #I #W2 #U2 #_ #IHU2 #V #d #e #H
 261   [ elim (lift_inv_bind2 … H) -H #W1 #U1 #_ #HU12 #H destruct /2 width=4/
 262   | elim (lift_inv_flat2 … H) -H #W1 #U1 #_ #HU12 #H destruct /2 width=4/
 263   ]
 264 ]
 265 qed-.
 266
 267 (* Basic forward lemmas *****************************************************)
 268
 269 lemma tw_lift: ∀d,e,T1,T2. ⇑[d, e] T1 ≡ T2 → #[T1] = #[T2].
 270 #d #e #T1 #T2 #H elim H -d -e -T1 -T2 normalize //
 271 qed-.
 272
 273 (* Basic properties *********************************************************)
 274
 275 (* Basic_1: was: lift_lref_gt *)
 276 lemma lift_lref_ge_minus: ∀d,e,i. d + e ≤ i → ⇑[d, e] #(i - e) ≡ #i.
 277 #d #e #i #H >(plus_minus_m_m i e) in ⊢ (? ? ? ? %); /2 width=2/ /3 width=2/
 278 qed.
 279
 280 lemma lift_lref_ge_minus_eq: ∀d,e,i,j. d + e ≤ i → j = i - e → ⇑[d, e] #j ≡ #i.
 281 /2 width=1/ qed-.
 282
 283 (* Basic_1: was: lift_r *)
 284 lemma lift_refl: ∀T,d. ⇑[d, 0] T ≡ T.
 285 #T elim T -T
 286 [ * #i // #d elim (lt_or_ge i d) /2 width=1/
 287 | * /2 width=1/
 288 ]
 289 qed.
 290
 291 lemma lift_total: ∀T1,d,e. ∃T2. ⇑[d,e] T1 ≡ T2.
 292 #T1 elim T1 -T1
 293 [ * #i /2 width=2/ #d #e elim (lt_or_ge i d) /3 width=2/
 294 | * #I #V1 #T1 #IHV1 #IHT1 #d #e
 295   elim (IHV1 d e) -IHV1 #V2 #HV12
 296   [ elim (IHT1 (d+1) e) -IHT1 /3 width=2/
 297   | elim (IHT1 d e) -IHT1 /3 width=2/
 298   ]
 299 ]
 300 qed.
 301
 302 (* Basic_1: was: lift_free (right to left) *)
 303 lemma lift_split: ∀d1,e2,T1,T2. ⇑[d1, e2] T1 ≡ T2 →
 304                   ∀d2,e1. d1 ≤ d2 → d2 ≤ d1 + e1 → e1 ≤ e2 →
 305                   ∃∃T. ⇑[d1, e1] T1 ≡ T & ⇑[d2, e2 - e1] T ≡ T2.
 306 #d1 #e2 #T1 #T2 #H elim H -d1 -e2 -T1 -T2
 307 [ /3 width=3/
 308 | #i #d1 #e2 #Hid1 #d2 #e1 #Hd12 #_ #_
 309   lapply (lt_to_le_to_lt … Hid1 Hd12) -Hd12 #Hid2 /4 width=3/
 310 | #i #d1 #e2 #Hid1 #d2 #e1 #_ #Hd21 #He12
 311   lapply (transitive_le … (i+e1) Hd21 ?) /2 width=1/ -Hd21 #Hd21
 312   >(plus_minus_m_m e2 e1 ?) // /3 width=3/
 313 | /3 width=3/
 314 | #I #V1 #V2 #T1 #T2 #d1 #e2 #_ #_ #IHV #IHT #d2 #e1 #Hd12 #Hd21 #He12
 315   elim (IHV … Hd12 Hd21 He12) -IHV #V0 #HV0a #HV0b
 316   elim (IHT (d2+1) … ? ? He12) /2 width=1/ /3 width=5/
 317 | #I #V1 #V2 #T1 #T2 #d1 #e2 #_ #_ #IHV #IHT #d2 #e1 #Hd12 #Hd21 #He12
 318   elim (IHV … Hd12 Hd21 He12) -IHV #V0 #HV0a #HV0b
 319   elim (IHT d2 … ? ? He12) // /3 width=5/
 320 ]
 321 qed.
 322
 323 (* Basic_1: was only: dnf_dec2 dnf_dec *)
 324 lemma is_lift_dec: ∀T2,d,e. Decidable (∃T1. ⇑[d,e] T1 ≡ T2).
 325 #T1 elim T1 -T1
 326 [ * [1,3: /3 width=2/ ] #i #d #e
 327   elim (lt_dec i d) #Hid
 328   [ /4 width=2/
 329   | lapply (false_lt_to_le … Hid) -Hid #Hid
 330     elim (lt_dec i (d + e)) #Hide
 331     [ @or_intror * #T1 #H
 332       elim (lift_inv_lref2_be … H Hid Hide)
 333     | lapply (false_lt_to_le … Hide) -Hide /4 width=2/
 334     ]
 335   ]
 336 | * #I #V2 #T2 #IHV2 #IHT2 #d #e
 337   [ elim (IHV2 d e) -IHV2
 338     [ * #V1 #HV12 elim (IHT2 (d+1) e) -IHT2
 339       [ * #T1 #HT12 @or_introl /3 width=2/
 340       | -V1 #HT2 @or_intror * #X #H
 341         elim (lift_inv_bind2 … H) -H /3 width=2/
 342       ]
 343     | -IHT2 #HV2 @or_intror * #X #H
 344       elim (lift_inv_bind2 … H) -H /3 width=2/
 345     ]
 346   | elim (IHV2 d e) -IHV2
 347     [ * #V1 #HV12 elim (IHT2 d e) -IHT2
 348       [ * #T1 #HT12 /4 width=2/
 349       | -V1 #HT2 @or_intror * #X #H
 350         elim (lift_inv_flat2 … H) -H /3 width=2/
 351       ]
 352     | -IHT2 #HV2 @or_intror * #X #H
 353       elim (lift_inv_flat2 … H) -H /3 width=2/
 354     ]
 355   ]
 356 ]
 357 qed.
 358
 359 (* Basic_1: removed theorems 7:
 360             lift_head lift_gen_head
 361             lift_weight_map lift_weight lift_weight_add lift_weight_add_O
 362             lift_tlt_dx
 363 *)