matita/matita/contribs/lambda_delta/Basic_2/substitution/lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic_2/grammar/term_weight.ma".
  16
  17 (* RELOCATION ***************************************************************)
  18
  19 (* Basic_1: includes:
  20             lift_sort lift_lref_lt lift_lref_ge lift_bind lift_flat
  21 *)
  22 inductive lift: nat → nat → relation term ≝
  23 | lift_sort   : ∀k,d,e. lift d e (⋆k) (⋆k)
  24 | lift_lref_lt: ∀i,d,e. i < d → lift d e (#i) (#i)
  25 | lift_lref_ge: ∀i,d,e. d ≤ i → lift d e (#i) (#(i + e))
  26 | lift_gref   : ∀p,d,e. lift d e (§p) (§p)
  27 | lift_bind   : ∀I,V1,V2,T1,T2,d,e.
  28                 lift d e V1 V2 → lift (d + 1) e T1 T2 →
  29                 lift d e (𝕓{I} V1. T1) (𝕓{I} V2. T2)
  30 | lift_flat   : ∀I,V1,V2,T1,T2,d,e.
  31                 lift d e V1 V2 → lift d e T1 T2 →
  32                 lift d e (𝕗{I} V1. T1) (𝕗{I} V2. T2)
  33 .
  34
  35 interpretation "relocation" 'RLift d e T1 T2 = (lift d e T1 T2).
  36
  37 (* Basic properties *********************************************************)
  38
  39 (* Basic_1: was: lift_lref_gt *)
  40 lemma lift_lref_ge_minus: ∀d,e,i. d + e ≤ i → ↑[d, e] #(i - e) ≡ #i.
  41 #d #e #i #H >(plus_minus_m_m i e) in ⊢ (? ? ? ? %) /3/
  42 qed.
  43
  44 (* Basic_1: was: lift_r *)
  45 lemma lift_refl: ∀T,d. ↑[d, 0] T ≡ T.
  46 #T elim T -T
  47 [ * #i // #d elim (lt_or_ge i d) /2/
  48 | * /2/
  49 ]
  50 qed.
  51
  52 lemma lift_total: ∀T1,d,e. ∃T2. ↑[d,e] T1 ≡ T2.
  53 #T1 elim T1 -T1
  54 [ * #i /2/ #d #e elim (lt_or_ge i d) /3/
  55 | * #I #V1 #T1 #IHV1 #IHT1 #d #e
  56   elim (IHV1 d e) -IHV1 #V2 #HV12
  57   [ elim (IHT1 (d+1) e) -IHT1 /3/
  58   | elim (IHT1 d e) -IHT1 /3/
  59   ]
  60 ]
  61 qed.
  62
  63 (* Basic_1: was: lift_free (right to left) *)
  64 lemma lift_split: ∀d1,e2,T1,T2. ↑[d1, e2] T1 ≡ T2 → ∀d2,e1.
  65                                 d1 ≤ d2 → d2 ≤ d1 + e1 → e1 ≤ e2 →
  66                                 ∃∃T. ↑[d1, e1] T1 ≡ T & ↑[d2, e2 - e1] T ≡ T2.
  67 #d1 #e2 #T1 #T2 #H elim H -H d1 e2 T1 T2
  68 [ /3/
  69 | #i #d1 #e2 #Hid1 #d2 #e1 #Hd12 #_ #_
  70   lapply (lt_to_le_to_lt … Hid1 Hd12) -Hd12 #Hid2 /4/
  71 | #i #d1 #e2 #Hid1 #d2 #e1 #_ #Hd21 #He12
  72   lapply (transitive_le …(i+e1) Hd21 ?) /2/ -Hd21 #Hd21
  73   <(arith_d1 i e2 e1) // /3/
  74 | /3/
  75 | #I #V1 #V2 #T1 #T2 #d1 #e2 #_ #_ #IHV #IHT #d2 #e1 #Hd12 #Hd21 #He12
  76   elim (IHV … Hd12 Hd21 He12) -IHV #V0 #HV0a #HV0b
  77   elim (IHT (d2+1) … ? ? He12) /3 width = 5/
  78 | #I #V1 #V2 #T1 #T2 #d1 #e2 #_ #_ #IHV #IHT #d2 #e1 #Hd12 #Hd21 #He12
  79   elim (IHV … Hd12 Hd21 He12) -IHV #V0 #HV0a #HV0b
  80   elim (IHT d2 … ? ? He12) /3 width = 5/
  81 ]
  82 qed.
  83
  84 (* Basic forward lemmas *****************************************************)
  85
  86 lemma tw_lift: ∀d,e,T1,T2. ↑[d, e] T1 ≡ T2 → #[T1] = #[T2].
  87 #d #e #T1 #T2 #H elim H -d e T1 T2; normalize //
  88 qed.
  89
  90 (* Basic inversion lemmas ***************************************************)
  91
  92 fact lift_inv_refl_aux: ∀d,e,T1,T2. ↑[d, e] T1 ≡ T2 → e = 0 → T1 = T2.
  93 #d #e #T1 #T2 #H elim H -H d e T1 T2 /3/
  94 qed.
  95
  96 lemma lift_inv_refl: ∀d,T1,T2. ↑[d, 0] T1 ≡ T2 → T1 = T2.
  97 /2/ qed.
  98
  99 fact lift_inv_sort1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀k. T1 = ⋆k → T2 = ⋆k.
 100 #d #e #T1 #T2 * -d e T1 T2 //
 101 [ #i #d #e #_ #k #H destruct
 102 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 103 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 104 ]
 105 qed.
 106
 107 lemma lift_inv_sort1: ∀d,e,T2,k. ↑[d,e] ⋆k ≡ T2 → T2 = ⋆k.
 108 /2 width=5/ qed.
 109
 110 fact lift_inv_lref1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀i. T1 = #i →
 111                          (i < d ∧ T2 = #i) ∨ (d ≤ i ∧ T2 = #(i + e)).
 112 #d #e #T1 #T2 * -d e T1 T2
 113 [ #k #d #e #i #H destruct
 114 | #j #d #e #Hj #i #Hi destruct /3/
 115 | #j #d #e #Hj #i #Hi destruct /3/
 116 | #p #d #e #i #H destruct
 117 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 118 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 119 ]
 120 qed.
 121
 122 lemma lift_inv_lref1: ∀d,e,T2,i. ↑[d,e] #i ≡ T2 →
 123                       (i < d ∧ T2 = #i) ∨ (d ≤ i ∧ T2 = #(i + e)).
 124 /2/ qed.
 125
 126 lemma lift_inv_lref1_lt: ∀d,e,T2,i. ↑[d,e] #i ≡ T2 → i < d → T2 = #i.
 127 #d #e #T2 #i #H elim (lift_inv_lref1 … H) -H * //
 128 #Hdi #_ #Hid lapply (le_to_lt_to_lt … Hdi Hid) -Hdi Hid #Hdd
 129 elim (lt_refl_false … Hdd)
 130 qed.
 131
 132 lemma lift_inv_lref1_ge: ∀d,e,T2,i. ↑[d,e] #i ≡ T2 → d ≤ i → T2 = #(i + e).
 133 #d #e #T2 #i #H elim (lift_inv_lref1 … H) -H * //
 134 #Hid #_ #Hdi lapply (le_to_lt_to_lt … Hdi Hid) -Hdi Hid #Hdd
 135 elim (lt_refl_false … Hdd)
 136 qed.
 137
 138 fact lift_inv_gref1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀p. T1 = §p → T2 = §p.
 139 #d #e #T1 #T2 * -d e T1 T2 //
 140 [ #i #d #e #_ #k #H destruct
 141 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 142 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 143 ]
 144 qed.
 145
 146 lemma lift_inv_gref1: ∀d,e,T2,p. ↑[d,e] §p ≡ T2 → T2 = §p.
 147 /2 width=5/ qed.
 148
 149 fact lift_inv_bind1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 150                          ∀I,V1,U1. T1 = 𝕓{I} V1.U1 →
 151                          ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 152                                   T2 = 𝕓{I} V2. U2.
 153 #d #e #T1 #T2 * -d e T1 T2
 154 [ #k #d #e #I #V1 #U1 #H destruct
 155 | #i #d #e #_ #I #V1 #U1 #H destruct
 156 | #i #d #e #_ #I #V1 #U1 #H destruct
 157 | #p #d #e #I #V1 #U1 #H destruct
 158 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct /2 width=5/
 159 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct
 160 ]
 161 qed.
 162
 163 lemma lift_inv_bind1: ∀d,e,T2,I,V1,U1. ↑[d,e] 𝕓{I} V1. U1 ≡ T2 →
 164                       ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 165                                T2 = 𝕓{I} V2. U2.
 166 /2/ qed.
 167
 168 fact lift_inv_flat1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 169                          ∀I,V1,U1. T1 = 𝕗{I} V1.U1 →
 170                          ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 171                                   T2 = 𝕗{I} V2. U2.
 172 #d #e #T1 #T2 * -d e T1 T2
 173 [ #k #d #e #I #V1 #U1 #H destruct
 174 | #i #d #e #_ #I #V1 #U1 #H destruct
 175 | #i #d #e #_ #I #V1 #U1 #H destruct
 176 | #p #d #e #I #V1 #U1 #H destruct
 177 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct
 178 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct /2 width=5/
 179 ]
 180 qed.
 181
 182 lemma lift_inv_flat1: ∀d,e,T2,I,V1,U1. ↑[d,e] 𝕗{I} V1. U1 ≡ T2 →
 183                       ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 184                                T2 = 𝕗{I} V2. U2.
 185 /2/ qed.
 186
 187 fact lift_inv_sort2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀k. T2 = ⋆k → T1 = ⋆k.
 188 #d #e #T1 #T2 * -d e T1 T2 //
 189 [ #i #d #e #_ #k #H destruct
 190 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 191 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 192 ]
 193 qed.
 194
 195 (* Basic_1: was: lift_gen_sort *)
 196 lemma lift_inv_sort2: ∀d,e,T1,k. ↑[d,e] T1 ≡ ⋆k → T1 = ⋆k.
 197 /2 width=5/ qed.
 198
 199 fact lift_inv_lref2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀i. T2 = #i →
 200                          (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
 201 #d #e #T1 #T2 * -d e T1 T2
 202 [ #k #d #e #i #H destruct
 203 | #j #d #e #Hj #i #Hi destruct /3/
 204 | #j #d #e #Hj #i #Hi destruct <minus_plus_m_m /4/
 205 | #p #d #e #i #H destruct
 206 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 207 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 208 ]
 209 qed.
 210
 211 (* Basic_1: was: lift_gen_lref *)
 212 lemma lift_inv_lref2: ∀d,e,T1,i. ↑[d,e] T1 ≡ #i →
 213                       (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
 214 /2/ qed.
 215
 216 (* Basic_1: was: lift_gen_lref_lt *)
 217 lemma lift_inv_lref2_lt: ∀d,e,T1,i. ↑[d,e] T1 ≡ #i → i < d → T1 = #i.
 218 #d #e #T1 #i #H elim (lift_inv_lref2 … H) -H * //
 219 #Hdi #_ #Hid lapply (le_to_lt_to_lt … Hdi Hid) -Hdi Hid #Hdd
 220 elim (plus_lt_false … Hdd)
 221 qed.
 222
 223 (* Basic_1: was: lift_gen_lref_false *)
 224
 225 (* Basic_1: was: lift_gen_lref_ge *)
 226 lemma lift_inv_lref2_ge: ∀d,e,T1,i. ↑[d,e] T1 ≡ #i → d + e ≤ i → T1 = #(i - e).
 227 #d #e #T1 #i #H elim (lift_inv_lref2 … H) -H * //
 228 #Hid #_ #Hdi lapply (le_to_lt_to_lt … Hdi Hid) -Hdi Hid #Hdd
 229 elim (plus_lt_false … Hdd)
 230 qed.
 231
 232 fact lift_inv_gref2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀p. T2 = §p → T1 = §p.
 233 #d #e #T1 #T2 * -d e T1 T2 //
 234 [ #i #d #e #_ #k #H destruct
 235 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 236 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 237 ]
 238 qed.
 239
 240 lemma lift_inv_gref2: ∀d,e,T1,p. ↑[d,e] T1 ≡ §p → T1 = §p.
 241 /2 width=5/ qed.
 242
 243 fact lift_inv_bind2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 244                          ∀I,V2,U2. T2 = 𝕓{I} V2.U2 →
 245                          ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 246                                   T1 = 𝕓{I} V1. U1.
 247 #d #e #T1 #T2 * -d e T1 T2
 248 [ #k #d #e #I #V2 #U2 #H destruct
 249 | #i #d #e #_ #I #V2 #U2 #H destruct
 250 | #i #d #e #_ #I #V2 #U2 #H destruct
 251 | #p #d #e #I #V2 #U2 #H destruct
 252 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct /2 width=5/
 253 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct
 254 ]
 255 qed.
 256
 257 (* Basic_1: was: lift_gen_bind *)
 258 lemma lift_inv_bind2: ∀d,e,T1,I,V2,U2. ↑[d,e] T1 ≡  𝕓{I} V2. U2 →
 259                       ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 260                                T1 = 𝕓{I} V1. U1.
 261 /2/ qed.
 262
 263 fact lift_inv_flat2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 264                          ∀I,V2,U2. T2 = 𝕗{I} V2.U2 →
 265                          ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 266                                   T1 = 𝕗{I} V1. U1.
 267 #d #e #T1 #T2 * -d e T1 T2
 268 [ #k #d #e #I #V2 #U2 #H destruct
 269 | #i #d #e #_ #I #V2 #U2 #H destruct
 270 | #i #d #e #_ #I #V2 #U2 #H destruct
 271 | #p #d #e #I #V2 #U2 #H destruct
 272 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct
 273 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct /2 width = 5/
 274 ]
 275 qed.
 276
 277 (* Basic_1: was: lift_gen_flat *)
 278 lemma lift_inv_flat2: ∀d,e,T1,I,V2,U2. ↑[d,e] T1 ≡  𝕗{I} V2. U2 →
 279                       ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 280                                T1 = 𝕗{I} V1. U1.
 281 /2/ qed.
 282
 283 (* Basic_1: removed theorems 7:
 284             lift_head lift_gen_head
 285             lift_weight_map lift_weight lift_weight_add lift_weight_add_O
 286             lift_tlt_dx
 287 *)