matita/matita/contribs/lambda_delta/Basic_2/substitution/lift_lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic_2/substitution/lift.ma".
  16
  17 (* RELOCATION ***************************************************************)
  18
  19 (* Main properies ***********************************************************)
  20
  21 (* Basic_1: was: lift_inj *)
  22 theorem lift_inj:  ∀d,e,T1,U. ↑[d,e] T1 ≡ U → ∀T2. ↑[d,e] T2 ≡ U → T1 = T2.
  23 #d #e #T1 #U #H elim H -H d e T1 U
  24 [ #k #d #e #X #HX
  25   lapply (lift_inv_sort2 … HX) -HX //
  26 | #i #d #e #Hid #X #HX
  27   lapply (lift_inv_lref2_lt … HX ?) -HX //
  28 | #i #d #e #Hdi #X #HX
  29   lapply (lift_inv_lref2_ge … HX ?) -HX /2/
  30 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
  31   elim (lift_inv_bind2 … HX) -HX #V #T #HV1 #HT1 #HX destruct -X /3/
  32 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
  33   elim (lift_inv_flat2 … HX) -HX #V #T #HV1 #HT1 #HX destruct -X /3/
  34 ]
  35 qed.
  36
  37 (* Basic_1: was: lift_gen_lift *)
  38 theorem lift_div_le: ∀d1,e1,T1,T. ↑[d1, e1] T1 ≡ T →
  39                      ∀d2,e2,T2. ↑[d2 + e1, e2] T2 ≡ T →
  40                      d1 ≤ d2 →
  41                      ∃∃T0. ↑[d1, e1] T0 ≡ T2 & ↑[d2, e2] T0 ≡ T1.
  42 #d1 #e1 #T1 #T #H elim H -H d1 e1 T1 T
  43 [ #k #d1 #e1 #d2 #e2 #T2 #Hk #Hd12
  44   lapply (lift_inv_sort2 … Hk) -Hk #Hk destruct -T2 /3/
  45 | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #Hi #Hd12
  46   lapply (lt_to_le_to_lt … Hid1 Hd12) -Hd12 #Hid2
  47   lapply (lift_inv_lref2_lt … Hi ?) -Hi /3/
  48 | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #Hi #Hd12
  49   elim (lift_inv_lref2 … Hi) -Hi * #Hid2 #H destruct -T2
  50   [ -Hd12; lapply (lt_plus_to_lt_l … Hid2) -Hid2 #Hid2 /3/
  51   | -Hid1; lapply (arith1 … Hid2) -Hid2 #Hid2
  52     @(ex2_1_intro … #(i - e2))
  53     [ >le_plus_minus_comm [ @lift_lref_ge @(transitive_le … Hd12) -Hd12 /2/ | -Hd12 /2/ ]
  54     | -Hd12 >(plus_minus_m_m i e2) in ⊢ (? ? ? ? %) /3/
  55     ]
  56   ]
  57 | #I #W1 #W #U1 #U #d1 #e1 #_ #_ #IHW #IHU #d2 #e2 #T2 #H #Hd12
  58   lapply (lift_inv_bind2 … H) -H * #W2 #U2 #HW2 #HU2 #H destruct -T2;
  59   elim (IHW … HW2 ?) // -IHW HW2 #W0 #HW2 #HW1
  60   >plus_plus_comm_23 in HU2 #HU2 elim (IHU … HU2 ?) /3 width = 5/
  61 | #I #W1 #W #U1 #U #d1 #e1 #_ #_ #IHW #IHU #d2 #e2 #T2 #H #Hd12
  62   lapply (lift_inv_flat2 … H) -H * #W2 #U2 #HW2 #HU2 #H destruct -T2;
  63   elim (IHW … HW2 ?) // -IHW HW2 #W0 #HW2 #HW1
  64   elim (IHU … HU2 ?) /3 width = 5/
  65 ]
  66 qed.
  67
  68 theorem lift_mono:  ∀d,e,T,U1. ↑[d,e] T ≡ U1 → ∀U2. ↑[d,e] T ≡ U2 → U1 = U2.
  69 #d #e #T #U1 #H elim H -H d e T U1
  70 [ #k #d #e #X #HX
  71   lapply (lift_inv_sort1 … HX) -HX //
  72 | #i #d #e #Hid #X #HX
  73   lapply (lift_inv_lref1_lt … HX ?) -HX //
  74 | #i #d #e #Hdi #X #HX
  75   lapply (lift_inv_lref1_ge … HX ?) -HX //
  76 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
  77   elim (lift_inv_bind1 … HX) -HX #V #T #HV1 #HT1 #HX destruct -X /3/
  78 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
  79   elim (lift_inv_flat1 … HX) -HX #V #T #HV1 #HT1 #HX destruct -X /3/
  80 ]
  81 qed.
  82
  83 (* Basic_1: was: lift_free (left to right) *)
  84 theorem lift_trans_be: ∀d1,e1,T1,T. ↑[d1, e1] T1 ≡ T →
  85                        ∀d2,e2,T2. ↑[d2, e2] T ≡ T2 →
  86                        d1 ≤ d2 → d2 ≤ d1 + e1 → ↑[d1, e1 + e2] T1 ≡ T2.
  87 #d1 #e1 #T1 #T #H elim H -H d1 e1 T1 T
  88 [ #k #d1 #e1 #d2 #e2 #T2 #HT2 #_ #_
  89   >(lift_inv_sort1 … HT2) -HT2 //
  90 | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #HT2 #Hd12 #_
  91   lapply (lt_to_le_to_lt … Hid1 Hd12) -Hd12 #Hid2
  92   lapply (lift_inv_lref1_lt … HT2 Hid2) /2/
  93 | #i #d1 #e1 #Hid1 #d2 #e2 #T2 #HT2 #_ #Hd21
  94   lapply (lift_inv_lref1_ge … HT2 ?) -HT2
  95   [ @(transitive_le … Hd21 ?) -Hd21 /2/
  96   | -Hd21 /2/
  97   ]
  98 | #I #V1 #V2 #T1 #T2 #d1 #e1 #_ #_ #IHV12 #IHT12 #d2 #e2 #X #HX #Hd12 #Hd21
  99   elim (lift_inv_bind1 … HX) -HX #V0 #T0 #HV20 #HT20 #HX destruct -X;
 100   lapply (IHV12 … HV20 ? ?) // -IHV12 HV20 #HV10
 101   lapply (IHT12 … HT20 ? ?) /2/
 102 | #I #V1 #V2 #T1 #T2 #d1 #e1 #_ #_ #IHV12 #IHT12 #d2 #e2 #X #HX #Hd12 #Hd21
 103   elim (lift_inv_flat1 … HX) -HX #V0 #T0 #HV20 #HT20 #HX destruct -X;
 104   lapply (IHV12 … HV20 ? ?) // -IHV12 HV20 #HV10
 105   lapply (IHT12 … HT20 ? ?) /2/
 106 ]
 107 qed.
 108
 109 (* Basic_1: was: lift_d (right to left) *)
 110 theorem lift_trans_le: ∀d1,e1,T1,T. ↑[d1, e1] T1 ≡ T →
 111                        ∀d2,e2,T2. ↑[d2, e2] T ≡ T2 → d2 ≤ d1 →
 112                        ∃∃T0. ↑[d2, e2] T1 ≡ T0 & ↑[d1 + e2, e1] T0 ≡ T2.
 113 #d1 #e1 #T1 #T #H elim H -H d1 e1 T1 T
 114 [ #k #d1 #e1 #d2 #e2 #X #HX #_
 115   >(lift_inv_sort1 … HX) -HX /2/
 116 | #i #d1 #e1 #Hid1 #d2 #e2 #X #HX #_
 117   lapply (lt_to_le_to_lt … (d1+e2) Hid1 ?) // #Hie2
 118   elim (lift_inv_lref1 … HX) -HX * #Hid2 #HX destruct -X /4/
 119 | #i #d1 #e1 #Hid1 #d2 #e2 #X #HX #Hd21
 120   lapply (transitive_le … Hd21 Hid1) -Hd21 #Hid2
 121   lapply (lift_inv_lref1_ge … HX ?) -HX /2/ #HX destruct -X;
 122   >plus_plus_comm_23 /4/
 123 | #I #V1 #V2 #T1 #T2 #d1 #e1 #_ #_ #IHV12 #IHT12 #d2 #e2 #X #HX #Hd21
 124   elim (lift_inv_bind1 … HX) -HX #V0 #T0 #HV20 #HT20 #HX destruct -X;
 125   elim (IHV12 … HV20 ?) -IHV12 HV20 //
 126   elim (IHT12 … HT20 ?) -IHT12 HT20 /3 width=5/
 127 | #I #V1 #V2 #T1 #T2 #d1 #e1 #_ #_ #IHV12 #IHT12 #d2 #e2 #X #HX #Hd21
 128   elim (lift_inv_flat1 … HX) -HX #V0 #T0 #HV20 #HT20 #HX destruct -X;
 129   elim (IHV12 … HV20 ?) -IHV12 HV20 //
 130   elim (IHT12 … HT20 ?) -IHT12 HT20 /3 width=5/
 131 ]
 132 qed.
 133
 134 (* Basic_1: was: lift_d (left to right) *)
 135 theorem lift_trans_ge: ∀d1,e1,T1,T. ↑[d1, e1] T1 ≡ T →
 136                        ∀d2,e2,T2. ↑[d2, e2] T ≡ T2 → d1 + e1 ≤ d2 →
 137                        ∃∃T0. ↑[d2 - e1, e2] T1 ≡ T0 & ↑[d1, e1] T0 ≡ T2.
 138 #d1 #e1 #T1 #T #H elim H -H d1 e1 T1 T
 139 [ #k #d1 #e1 #d2 #e2 #X #HX #_
 140   >(lift_inv_sort1 … HX) -HX /2/
 141 | #i #d1 #e1 #Hid1 #d2 #e2 #X #HX #Hded
 142   lapply (lt_to_le_to_lt … (d1+e1) Hid1 ?) // #Hid1e
 143   lapply (lt_to_le_to_lt … (d2-e1) Hid1 ?) /2/ #Hid2e
 144   lapply (lt_to_le_to_lt … Hid1e Hded) -Hid1e Hded #Hid2
 145   lapply (lift_inv_lref1_lt … HX ?) -HX // #HX destruct -X /3/
 146 | #i #d1 #e1 #Hid1 #d2 #e2 #X #HX #_
 147   elim (lift_inv_lref1 … HX) -HX * #Hied #HX destruct -X;
 148   [2: >plus_plus_comm_23] /4/
 149 | #I #V1 #V2 #T1 #T2 #d1 #e1 #_ #_ #IHV12 #IHT12 #d2 #e2 #X #HX #Hded
 150   elim (lift_inv_bind1 … HX) -HX #V0 #T0 #HV20 #HT20 #HX destruct -X;
 151   elim (IHV12 … HV20 ?) -IHV12 HV20 //
 152   elim (IHT12 … HT20 ?) -IHT12 HT20 /2/ #T
 153   <plus_minus /3 width=5/
 154 | #I #V1 #V2 #T1 #T2 #d1 #e1 #_ #_ #IHV12 #IHT12 #d2 #e2 #X #HX #Hded
 155   elim (lift_inv_flat1 … HX) -HX #V0 #T0 #HV20 #HT20 #HX destruct -X;
 156   elim (IHV12 … HV20 ?) -IHV12 HV20 //
 157   elim (IHT12 … HT20 ?) -IHT12 HT20 /3 width=5/
 158 ]
 159 qed.