matita/matita/contribs/lambda_delta/Basic_2/substitution/ltps.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic_2/substitution/tps.ma".
  16
  17 (* PARALLEL SUBSTITUTION ON LOCAL ENVIRONMENTS ******************************)
  18
  19 (* Basic_1: includes: csubst1_bind *)
  20 inductive ltps: nat → nat → relation lenv ≝
  21 | ltps_atom: ∀d,e. ltps d e (⋆) (⋆)
  22 | ltps_pair: ∀L,I,V. ltps 0 0 (L. 𝕓{I} V) (L. 𝕓{I} V)
  23 | ltps_tps2: ∀L1,L2,I,V1,V2,e.
  24              ltps 0 e L1 L2 → L2 ⊢ V1 [0, e] ≫ V2 →
  25              ltps 0 (e + 1) (L1. 𝕓{I} V1) L2. 𝕓{I} V2
  26 | ltps_tps1: ∀L1,L2,I,V1,V2,d,e.
  27              ltps d e L1 L2 → L2 ⊢ V1 [d, e] ≫ V2 →
  28              ltps (d + 1) e (L1. 𝕓{I} V1) (L2. 𝕓{I} V2)
  29 .
  30
  31 interpretation "parallel substritution (local environment)"
  32    'PSubst L1 d e L2 = (ltps d e L1 L2).
  33
  34 (* Basic properties *********************************************************)
  35
  36 lemma ltps_tps2_lt: ∀L1,L2,I,V1,V2,e.
  37                     L1 [0, e - 1] ≫ L2 → L2 ⊢ V1 [0, e - 1] ≫ V2 →
  38                     0 < e → L1. 𝕓{I} V1 [0, e] ≫ L2. 𝕓{I} V2.
  39 #L1 #L2 #I #V1 #V2 #e #HL12 #HV12 #He
  40 >(plus_minus_m_m e 1) /2/
  41 qed.
  42
  43 lemma ltps_tps1_lt: ∀L1,L2,I,V1,V2,d,e.
  44                     L1 [d - 1, e] ≫ L2 → L2 ⊢ V1 [d - 1, e] ≫ V2 →
  45                     0 < d → L1. 𝕓{I} V1 [d, e] ≫ L2. 𝕓{I} V2.
  46 #L1 #L2 #I #V1 #V2 #d #e #HL12 #HV12 #Hd
  47 >(plus_minus_m_m d 1) /2/
  48 qed.
  49
  50 (* Basic_1: was by definition: csubst1_refl *)
  51 lemma ltps_refl: ∀L,d,e. L [d, e] ≫ L.
  52 #L elim L -L //
  53 #L #I #V #IHL * /2/ * /2/
  54 qed.
  55
  56 (* Basic inversion lemmas ***************************************************)
  57
  58 fact ltps_inv_refl_O2_aux: ∀d,e,L1,L2. L1 [d, e] ≫ L2 → e = 0 → L1 = L2.
  59 #d #e #L1 #L2 #H elim H -H d e L1 L2 //
  60 [ #L1 #L2 #I #V1 #V2 #e #_ #_ #_ #H
  61   elim (plus_S_eq_O_false … H)
  62 | #L1 #L2 #I #V1 #V2 #d #e #_ #HV12 #IHL12 #He destruct -e
  63   >(IHL12 ?) -IHL12 // >(tps_inv_refl_O2 … HV12) //
  64 ]
  65 qed.
  66
  67 lemma ltps_inv_refl_O2: ∀d,L1,L2. L1 [d, 0] ≫ L2 → L1 = L2.
  68 /2/ qed.
  69
  70 fact ltps_inv_atom1_aux: ∀d,e,L1,L2.
  71                          L1 [d, e] ≫ L2 → L1 = ⋆ → L2 = ⋆.
  72 #d #e #L1 #L2 * -d e L1 L2
  73 [ //
  74 | #L #I #V #H destruct
  75 | #L1 #L2 #I #V1 #V2 #e #_ #_ #H destruct
  76 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H destruct
  77 ]
  78 qed.
  79
  80 lemma ltps_inv_atom1: ∀d,e,L2. ⋆ [d, e] ≫ L2 → L2 = ⋆.
  81 /2 width=5/ qed.
  82
  83 fact ltps_inv_tps21_aux: ∀d,e,L1,L2. L1 [d, e] ≫ L2 → d = 0 → 0 < e →
  84                          ∀K1,I,V1. L1 = K1. 𝕓{I} V1 →
  85                          ∃∃K2,V2. K1 [0, e - 1] ≫ K2 &
  86                                   K2 ⊢ V1 [0, e - 1] ≫ V2 &
  87                                   L2 = K2. 𝕓{I} V2.
  88 #d #e #L1 #L2 * -d e L1 L2
  89 [ #d #e #_ #_ #K1 #I #V1 #H destruct
  90 | #L1 #I #V #_ #H elim (lt_refl_false … H)
  91 | #L1 #L2 #I #V1 #V2 #e #HL12 #HV12 #_ #_ #K1 #J #W1 #H destruct -L1 I V1 /2 width=5/
  92 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H elim (plus_S_eq_O_false … H)
  93 ]
  94 qed.
  95
  96 lemma ltps_inv_tps21: ∀e,K1,I,V1,L2. K1. 𝕓{I} V1 [0, e] ≫ L2 → 0 < e →
  97                       ∃∃K2,V2. K1 [0, e - 1] ≫ K2 & K2 ⊢ V1 [0, e - 1] ≫ V2 &
  98                                L2 = K2. 𝕓{I} V2.
  99 /2 width=5/ qed.
 100
 101 fact ltps_inv_tps11_aux: ∀d,e,L1,L2. L1 [d, e] ≫ L2 → 0 < d →
 102                          ∀I,K1,V1. L1 = K1. 𝕓{I} V1 →
 103                          ∃∃K2,V2. K1 [d - 1, e] ≫ K2 &
 104                                   K2 ⊢ V1 [d - 1, e] ≫ V2 &
 105                                   L2 = K2. 𝕓{I} V2.
 106 #d #e #L1 #L2 * -d e L1 L2
 107 [ #d #e #_ #I #K1 #V1 #H destruct
 108 | #L #I #V #H elim (lt_refl_false … H)
 109 | #L1 #L2 #I #V1 #V2 #e #_ #_ #H elim (lt_refl_false … H)
 110 | #L1 #L2 #I #V1 #V2 #d #e #HL12 #HV12 #_ #J #K1 #W1 #H destruct -L1 I V1
 111   /2 width=5/
 112 ]
 113 qed.
 114
 115 lemma ltps_inv_tps11: ∀d,e,I,K1,V1,L2. K1. 𝕓{I} V1 [d, e] ≫ L2 → 0 < d →
 116                       ∃∃K2,V2. K1 [d - 1, e] ≫ K2 &
 117                                   K2 ⊢ V1 [d - 1, e] ≫ V2 &
 118                                   L2 = K2. 𝕓{I} V2.
 119 /2/ qed.
 120
 121 fact ltps_inv_atom2_aux: ∀d,e,L1,L2.
 122                          L1 [d, e] ≫ L2 → L2 = ⋆ → L1 = ⋆.
 123 #d #e #L1 #L2 * -d e L1 L2
 124 [ //
 125 | #L #I #V #H destruct
 126 | #L1 #L2 #I #V1 #V2 #e #_ #_ #H destruct
 127 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H destruct
 128 ]
 129 qed.
 130
 131 lemma ltps_inv_atom2: ∀d,e,L1. L1 [d, e] ≫ ⋆ → L1 = ⋆.
 132 /2 width=5/ qed.
 133
 134 fact ltps_inv_tps22_aux: ∀d,e,L1,L2. L1 [d, e] ≫ L2 → d = 0 → 0 < e →
 135                          ∀K2,I,V2. L2 = K2. 𝕓{I} V2 →
 136                          ∃∃K1,V1. K1 [0, e - 1] ≫ K2 &
 137                                   K2 ⊢ V1 [0, e - 1] ≫ V2 &
 138                                   L1 = K1. 𝕓{I} V1.
 139 #d #e #L1 #L2 * -d e L1 L2
 140 [ #d #e #_ #_ #K1 #I #V1 #H destruct
 141 | #L1 #I #V #_ #H elim (lt_refl_false … H)
 142 | #L1 #L2 #I #V1 #V2 #e #HL12 #HV12 #_ #_ #K2 #J #W2 #H destruct -L2 I V2 /2 width=5/
 143 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H elim (plus_S_eq_O_false … H)
 144 ]
 145 qed.
 146
 147 lemma ltps_inv_tps22: ∀e,L1,K2,I,V2. L1 [0, e] ≫ K2. 𝕓{I} V2 → 0 < e →
 148                       ∃∃K1,V1. K1 [0, e - 1] ≫ K2 & K2 ⊢ V1 [0, e - 1] ≫ V2 &
 149                                L1 = K1. 𝕓{I} V1.
 150 /2 width=5/ qed.
 151
 152 fact ltps_inv_tps12_aux: ∀d,e,L1,L2. L1 [d, e] ≫ L2 → 0 < d →
 153                          ∀I,K2,V2. L2 = K2. 𝕓{I} V2 →
 154                          ∃∃K1,V1. K1 [d - 1, e] ≫ K2 &
 155                                   K2 ⊢ V1 [d - 1, e] ≫ V2 &
 156                                   L1 = K1. 𝕓{I} V1.
 157 #d #e #L1 #L2 * -d e L1 L2
 158 [ #d #e #_ #I #K2 #V2 #H destruct
 159 | #L #I #V #H elim (lt_refl_false … H)
 160 | #L1 #L2 #I #V1 #V2 #e #_ #_ #H elim (lt_refl_false … H)
 161 | #L1 #L2 #I #V1 #V2 #d #e #HL12 #HV12 #_ #J #K2 #W2 #H destruct -L2 I V2
 162   /2 width=5/
 163 ]
 164 qed.
 165
 166 lemma ltps_inv_tps12: ∀L1,K2,I,V2,d,e. L1 [d, e] ≫ K2. 𝕓{I} V2 → 0 < d →
 167                       ∃∃K1,V1. K1 [d - 1, e] ≫ K2 &
 168                                   K2 ⊢ V1 [d - 1, e] ≫ V2 &
 169                                   L1 = K1. 𝕓{I} V1.
 170 /2/ qed.
 171
 172 (* Basic_1: removed theorems 27:
 173             csubst0_clear_O csubst0_drop_lt csubst0_drop_gt csubst0_drop_eq
 174             csubst0_clear_O_back csubst0_clear_S csubst0_clear_trans
 175             csubst0_drop_gt_back csubst0_drop_eq_back csubst0_drop_lt_back
 176             csubst0_gen_sort csubst0_gen_head csubst0_getl_ge csubst0_getl_lt
 177             csubst0_gen_S_bind_2 csubst0_getl_ge_back csubst0_getl_lt_back
 178             csubst0_snd_bind csubst0_fst_bind csubst0_both_bind
 179             csubst1_head csubst1_flat csubst1_gen_head
 180             csubst1_getl_ge csubst1_getl_lt csubst1_getl_ge_back getl_csubst1
 181
 182 *)