matita/matita/contribs/lambda_delta/Basic_2/substitution/tps.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic_2/grammar/cl_weight.ma".
  16 include "Basic_2/substitution/ldrop.ma".
  17
  18 (* PARALLEL SUBSTITUTION ON TERMS *******************************************)
  19
  20 inductive tps: nat → nat → lenv → relation term ≝
  21 | tps_atom : ∀L,I,d,e. tps d e L (𝕒{I}) (𝕒{I})
  22 | tps_subst: ∀L,K,V,W,i,d,e. d ≤ i → i < d + e →
  23              ↓[0, i] L ≡ K. 𝕓{Abbr} V → ↑[0, i + 1] V ≡ W → tps d e L (#i) W
  24 | tps_bind : ∀L,I,V1,V2,T1,T2,d,e.
  25              tps d e L V1 V2 → tps (d + 1) e (L. 𝕓{I} V2) T1 T2 →
  26              tps d e L (𝕓{I} V1. T1) (𝕓{I} V2. T2)
  27 | tps_flat : ∀L,I,V1,V2,T1,T2,d,e.
  28              tps d e L V1 V2 → tps d e L T1 T2 →
  29              tps d e L (𝕗{I} V1. T1) (𝕗{I} V2. T2)
  30 .
  31
  32 interpretation "parallel substritution (term)"
  33    'PSubst L T1 d e T2 = (tps d e L T1 T2).
  34
  35 (* Basic properties *********************************************************)
  36
  37 lemma tps_lsubs_conf: ∀L1,T1,T2,d,e. L1 ⊢ T1 [d, e] ≫ T2 →
  38                       ∀L2. L1 [d, e] ≼ L2 → L2 ⊢ T1 [d, e] ≫ T2.
  39 #L1 #T1 #T2 #d #e #H elim H -H L1 T1 T2 d e
  40 [ //
  41 | #L1 #K1 #V #W #i #d #e #Hdi #Hide #HLK1 #HVW #L2 #HL12
  42   elim (ldrop_lsubs_ldrop1_abbr … HL12 … HLK1 ? ?) -HL12 HLK1 // /2/
  43 | /4/
  44 | /3/
  45 ]
  46 qed.
  47
  48 lemma tps_refl: ∀T,L,d,e. L ⊢ T [d, e] ≫ T.
  49 #T elim T -T //
  50 #I elim I -I /2/
  51 qed.
  52
  53 (* Basic_1: was: subst1_ex *)
  54 lemma tps_full: ∀K,V,T1,L,d. ↓[0, d] L ≡ (K. 𝕓{Abbr} V) →
  55                 ∃∃T2,T. L ⊢ T1 [d, 1] ≫ T2 & ↑[d, 1] T ≡ T2.
  56 #K #V #T1 elim T1 -T1
  57 [ * #i #L #d #HLK /2/
  58   elim (lt_or_eq_or_gt i d) #Hid [ /3/ |3: /3/ ]
  59   destruct -d;
  60   elim (lift_total V 0 (i+1)) #W #HVW
  61   elim (lift_split … HVW i i ? ? ?) // <minus_plus_m_m_comm /3/
  62 | * #I #W1 #U1 #IHW1 #IHU1 #L #d #HLK
  63   elim (IHW1 … HLK) -IHW1 #W2 #W #HW12 #HW2
  64   [ elim (IHU1 (L. 𝕓{I} W2) (d+1) ?) -IHU1 /2/ -HLK /3 width=8/
  65   | elim (IHU1 … HLK) -IHU1 HLK /3 width=8/
  66   ]
  67 ]
  68 qed.
  69
  70 lemma tps_weak: ∀L,T1,T2,d1,e1. L ⊢ T1 [d1, e1] ≫ T2 →
  71                 ∀d2,e2. d2 ≤ d1 → d1 + e1 ≤ d2 + e2 →
  72                 L ⊢ T1 [d2, e2] ≫ T2.
  73 #L #T1 #T2 #d1 #e1 #H elim H -H L T1 T2 d1 e1
  74 [ //
  75 | #L #K #V #W #i #d1 #e1 #Hid1 #Hide1 #HLK #HVW #d2 #e2 #Hd12 #Hde12
  76   lapply (transitive_le … Hd12 … Hid1) -Hd12 Hid1 #Hid2
  77   lapply (lt_to_le_to_lt … Hide1 … Hde12) -Hide1 /2/
  78 | /4/
  79 | /4/
  80 ]
  81 qed.
  82
  83 lemma tps_weak_top: ∀L,T1,T2,d,e.
  84                     L ⊢ T1 [d, e] ≫ T2 → L ⊢ T1 [d, |L| - d] ≫ T2.
  85 #L #T1 #T2 #d #e #H elim H -H L T1 T2 d e
  86 [ //
  87 | #L #K #V #W #i #d #e #Hdi #_ #HLK #HVW
  88   lapply (ldrop_fwd_ldrop2_length … HLK) #Hi
  89   lapply (le_to_lt_to_lt … Hdi Hi) #Hd
  90   lapply (plus_minus_m_m_comm (|L|) d ?) /2/
  91 | normalize /2/
  92 | /2/
  93 ]
  94 qed.
  95
  96 lemma tps_weak_all: ∀L,T1,T2,d,e.
  97                     L ⊢ T1 [d, e] ≫ T2 → L ⊢ T1 [0, |L|] ≫ T2.
  98 #L #T1 #T2 #d #e #HT12
  99 lapply (tps_weak … HT12 0 (d + e) ? ?) -HT12 // #HT12
 100 lapply (tps_weak_top … HT12) //
 101 qed.
 102
 103 lemma tps_split_up: ∀L,T1,T2,d,e. L ⊢ T1 [d, e] ≫ T2 → ∀i. d ≤ i → i ≤ d + e →
 104                     ∃∃T. L ⊢ T1 [d, i - d] ≫ T & L ⊢ T [i, d + e - i] ≫ T2.
 105 #L #T1 #T2 #d #e #H elim H -H L T1 T2 d e
 106 [ /2/
 107 | #L #K #V #W #i #d #e #Hdi #Hide #HLK #HVW #j #Hdj #Hjde
 108   elim (lt_or_ge i j)
 109   [ -Hide Hjde;
 110     >(plus_minus_m_m_comm j d) in ⊢ (% → ?) // -Hdj /3/
 111   | -Hdi Hdj; #Hid
 112     generalize in match Hide -Hide (**) (* rewriting in the premises, rewrites in the goal too *)
 113     >(plus_minus_m_m_comm … Hjde) in ⊢ (% → ?) -Hjde /4/
 114   ]
 115 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #i #Hdi #Hide
 116   elim (IHV12 i ? ?) -IHV12 // #V #HV1 #HV2
 117   elim (IHT12 (i + 1) ? ?) -IHT12 [2: /2 by arith4/ |3: /2/ ] (* just /2/ is too slow *)
 118   -Hdi Hide >arith_c1 >arith_c1x #T #HT1 #HT2
 119   lapply (tps_lsubs_conf … HT1 (L. 𝕓{I} V) ?) -HT1 /3 width=5/
 120 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #i #Hdi #Hide
 121   elim (IHV12 i ? ?) -IHV12 // elim (IHT12 i ? ?) -IHT12 //
 122   -Hdi Hide /3 width=5/
 123 ]
 124 qed.
 125
 126 (* Basic inversion lemmas ***************************************************)
 127
 128 fact tps_inv_atom1_aux: ∀L,T1,T2,d,e. L ⊢ T1 [d, e] ≫ T2 → ∀I. T1 = 𝕒{I} →
 129                         T2 = 𝕒{I} ∨
 130                         ∃∃K,V,i. d ≤ i & i < d + e &
 131                                  ↓[O, i] L ≡ K. 𝕓{Abbr} V &
 132                                  ↑[O, i + 1] V ≡ T2 &
 133                                  I = LRef i.
 134 #L #T1 #T2 #d #e * -L T1 T2 d e
 135 [ #L #I #d #e #J #H destruct -I /2/
 136 | #L #K #V #T2 #i #d #e #Hdi #Hide #HLK #HVT2 #I #H destruct -I /3 width=8/
 137 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #J #H destruct
 138 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #J #H destruct
 139 ]
 140 qed.
 141
 142 lemma tps_inv_atom1: ∀L,T2,I,d,e. L ⊢ 𝕒{I} [d, e] ≫ T2 →
 143                      T2 = 𝕒{I} ∨
 144                      ∃∃K,V,i. d ≤ i & i < d + e &
 145                               ↓[O, i] L ≡ K. 𝕓{Abbr} V &
 146                               ↑[O, i + 1] V ≡ T2 &
 147                               I = LRef i.
 148 /2/ qed-.
 149
 150
 151 (* Basic_1: was: subst1_gen_sort *)
 152 lemma tps_inv_sort1: ∀L,T2,k,d,e. L ⊢ ⋆k [d, e] ≫ T2 → T2 = ⋆k.
 153 #L #T2 #k #d #e #H
 154 elim (tps_inv_atom1 … H) -H //
 155 * #K #V #i #_ #_ #_ #_ #H destruct
 156 qed-.
 157
 158 (* Basic_1: was: subst1_gen_lref *)
 159 lemma tps_inv_lref1: ∀L,T2,i,d,e. L ⊢ #i [d, e] ≫ T2 →
 160                      T2 = #i ∨
 161                      ∃∃K,V. d ≤ i & i < d + e &
 162                             ↓[O, i] L ≡ K. 𝕓{Abbr} V &
 163                             ↑[O, i + 1] V ≡ T2.
 164 #L #T2 #i #d #e #H
 165 elim (tps_inv_atom1 … H) -H /2/
 166 * #K #V #j #Hdj #Hjde #HLK #HVT2 #H destruct -i /3/
 167 qed-.
 168
 169 fact tps_inv_bind1_aux: ∀d,e,L,U1,U2. L ⊢ U1 [d, e] ≫ U2 →
 170                         ∀I,V1,T1. U1 = 𝕓{I} V1. T1 →
 171                         ∃∃V2,T2. L ⊢ V1 [d, e] ≫ V2 &
 172                                  L. 𝕓{I} V2 ⊢ T1 [d + 1, e] ≫ T2 &
 173                                  U2 =  𝕓{I} V2. T2.
 174 #d #e #L #U1 #U2 * -d e L U1 U2
 175 [ #L #k #d #e #I #V1 #T1 #H destruct
 176 | #L #K #V #W #i #d #e #_ #_ #_ #_ #I #V1 #T1 #H destruct
 177 | #L #J #V1 #V2 #T1 #T2 #d #e #HV12 #HT12 #I #V #T #H destruct /2 width=5/
 178 | #L #J #V1 #V2 #T1 #T2 #d #e #_ #_ #I #V #T #H destruct
 179 ]
 180 qed.
 181
 182 lemma tps_inv_bind1: ∀d,e,L,I,V1,T1,U2. L ⊢ 𝕓{I} V1. T1 [d, e] ≫ U2 →
 183                      ∃∃V2,T2. L ⊢ V1 [d, e] ≫ V2 &
 184                               L. 𝕓{I} V2 ⊢ T1 [d + 1, e] ≫ T2 &
 185                               U2 =  𝕓{I} V2. T2.
 186 /2/ qed-.
 187
 188 fact tps_inv_flat1_aux: ∀d,e,L,U1,U2. L ⊢ U1 [d, e] ≫ U2 →
 189                         ∀I,V1,T1. U1 = 𝕗{I} V1. T1 →
 190                         ∃∃V2,T2. L ⊢ V1 [d, e] ≫ V2 & L ⊢ T1 [d, e] ≫ T2 &
 191                                  U2 =  𝕗{I} V2. T2.
 192 #d #e #L #U1 #U2 * -d e L U1 U2
 193 [ #L #k #d #e #I #V1 #T1 #H destruct
 194 | #L #K #V #W #i #d #e #_ #_ #_ #_ #I #V1 #T1 #H destruct
 195 | #L #J #V1 #V2 #T1 #T2 #d #e #_ #_ #I #V #T #H destruct
 196 | #L #J #V1 #V2 #T1 #T2 #d #e #HV12 #HT12 #I #V #T #H destruct /2 width=5/
 197 ]
 198 qed.
 199
 200 lemma tps_inv_flat1: ∀d,e,L,I,V1,T1,U2. L ⊢ 𝕗{I} V1. T1 [d, e] ≫ U2 →
 201                      ∃∃V2,T2. L ⊢ V1 [d, e] ≫ V2 & L ⊢ T1 [d, e] ≫ T2 &
 202                               U2 =  𝕗{I} V2. T2.
 203 /2/ qed-.
 204
 205 fact tps_inv_refl_O2_aux: ∀L,T1,T2,d,e. L ⊢ T1 [d, e] ≫ T2 → e = 0 → T1 = T2.
 206 #L #T1 #T2 #d #e #H elim H -H L T1 T2 d e
 207 [ //
 208 | #L #K #V #W #i #d #e #Hdi #Hide #_ #_ #H destruct -e;
 209   lapply (le_to_lt_to_lt … Hdi … Hide) -Hdi Hide <plus_n_O #Hdd
 210   elim (lt_refl_false … Hdd)
 211 | /3/
 212 | /3/
 213 ]
 214 qed.
 215
 216 lemma tps_inv_refl_O2: ∀L,T1,T2,d. L ⊢ T1 [d, 0] ≫ T2 → T1 = T2.
 217 /2 width=6/ qed-.
 218
 219 (* Basic forward lemmas *****************************************************)
 220
 221 lemma tps_fwd_tw: ∀L,T1,T2,d,e. L ⊢ T1 [d, e] ≫ T2 → #[T1] ≤ #[T2].
 222 #L #T1 #T2 #d #e #H elim H normalize -H L T1 T2 d e
 223 /3 by monotonic_le_plus_l, le_plus/ (**) (* just /3/ is too slow *)
 224 qed-.
 225
 226 (* Basic_1: removed theorems 25:
 227             subst0_gen_sort subst0_gen_lref subst0_gen_head subst0_gen_lift_lt
 228             subst0_gen_lift_false subst0_gen_lift_ge subst0_refl subst0_trans
 229             subst0_lift_lt subst0_lift_ge subst0_lift_ge_S subst0_lift_ge_s
 230             subst0_subst0 subst0_subst0_back subst0_weight_le subst0_weight_lt
 231             subst0_confluence_neq subst0_confluence_eq subst0_tlt_head
 232             subst0_confluence_lift subst0_tlt
 233             subst1_head subst1_gen_head subst1_lift_S subst1_confluence_lift
 234 *)