matita/matita/contribs/lambda_delta/Basic_2/substitution/tps.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic_2/grammar/cl_weight.ma".
  16 include "Basic_2/substitution/drop.ma".
  17
  18 (* PARALLEL SUBSTITUTION ON TERMS *******************************************)
  19
  20 inductive tps: nat → nat → lenv → relation term ≝
  21 | tps_atom : ∀L,I,d,e. tps d e L (𝕒{I}) (𝕒{I})
  22 | tps_subst: ∀L,K,V,W,i,d,e. d ≤ i → i < d + e →
  23              ↓[0, i] L ≡ K. 𝕓{Abbr} V → ↑[0, i + 1] V ≡ W → tps d e L (#i) W
  24 | tps_bind : ∀L,I,V1,V2,T1,T2,d,e.
  25              tps d e L V1 V2 → tps (d + 1) e (L. 𝕓{I} V2) T1 T2 →
  26              tps d e L (𝕓{I} V1. T1) (𝕓{I} V2. T2)
  27 | tps_flat : ∀L,I,V1,V2,T1,T2,d,e.
  28              tps d e L V1 V2 → tps d e L T1 T2 →
  29              tps d e L (𝕗{I} V1. T1) (𝕗{I} V2. T2)
  30 .
  31
  32 interpretation "parallel substritution (term)"
  33    'PSubst L T1 d e T2 = (tps d e L T1 T2).
  34
  35 (* Basic properties *********************************************************)
  36
  37 lemma tps_lsubs_conf: ∀L1,T1,T2,d,e. L1 ⊢ T1 [d, e] ≫ T2 →
  38                       ∀L2. L1 [d, e] ≼ L2 → L2 ⊢ T1 [d, e] ≫ T2.
  39 #L1 #T1 #T2 #d #e #H elim H -H L1 T1 T2 d e
  40 [ //
  41 | #L1 #K1 #V #W #i #d #e #Hdi #Hide #HLK1 #HVW #L2 #HL12
  42   elim (drop_lsubs_drop1_abbr … HL12 … HLK1 ? ?) -HL12 HLK1 // /2/
  43 | /4/
  44 | /3/
  45 ]
  46 qed.
  47
  48 lemma tps_refl: ∀T,L,d,e. L ⊢ T [d, e] ≫ T.
  49 #T elim T -T //
  50 #I elim I -I /2/
  51 qed.
  52
  53 lemma tps_weak: ∀L,T1,T2,d1,e1. L ⊢ T1 [d1, e1] ≫ T2 →
  54                 ∀d2,e2. d2 ≤ d1 → d1 + e1 ≤ d2 + e2 →
  55                 L ⊢ T1 [d2, e2] ≫ T2.
  56 #L #T1 #T2 #d1 #e1 #H elim H -H L T1 T2 d1 e1
  57 [ //
  58 | #L #K #V #W #i #d1 #e1 #Hid1 #Hide1 #HLK #HVW #d2 #e2 #Hd12 #Hde12
  59   lapply (transitive_le … Hd12 … Hid1) -Hd12 Hid1 #Hid2
  60   lapply (lt_to_le_to_lt … Hide1 … Hde12) -Hide1 /2/
  61 | /4/
  62 | /4/
  63 ]
  64 qed.
  65
  66 lemma tps_weak_top: ∀L,T1,T2,d,e.
  67                     L ⊢ T1 [d, e] ≫ T2 → L ⊢ T1 [d, |L| - d] ≫ T2.
  68 #L #T1 #T2 #d #e #H elim H -H L T1 T2 d e
  69 [ //
  70 | #L #K #V #W #i #d #e #Hdi #_ #HLK #HVW
  71   lapply (drop_fwd_drop2_length … HLK) #Hi
  72   lapply (le_to_lt_to_lt … Hdi Hi) #Hd
  73   lapply (plus_minus_m_m_comm (|L|) d ?) /2/
  74 | normalize /2/
  75 | /2/
  76 ]
  77 qed.
  78
  79 lemma tps_weak_all: ∀L,T1,T2,d,e.
  80                     L ⊢ T1 [d, e] ≫ T2 → L ⊢ T1 [0, |L|] ≫ T2.
  81 #L #T1 #T2 #d #e #HT12
  82 lapply (tps_weak … HT12 0 (d + e) ? ?) -HT12 // #HT12
  83 lapply (tps_weak_top … HT12) //
  84 qed.
  85
  86 lemma tps_split_up: ∀L,T1,T2,d,e. L ⊢ T1 [d, e] ≫ T2 → ∀i. d ≤ i → i ≤ d + e →
  87                     ∃∃T. L ⊢ T1 [d, i - d] ≫ T & L ⊢ T [i, d + e - i] ≫ T2.
  88 #L #T1 #T2 #d #e #H elim H -H L T1 T2 d e
  89 [ /2/
  90 | #L #K #V #W #i #d #e #Hdi #Hide #HLK #HVW #j #Hdj #Hjde
  91   elim (lt_or_ge i j)
  92   [ -Hide Hjde;
  93     >(plus_minus_m_m_comm j d) in ⊢ (% → ?) // -Hdj /3/
  94   | -Hdi Hdj; #Hid
  95     generalize in match Hide -Hide (**) (* rewriting in the premises, rewrites in the goal too *)
  96     >(plus_minus_m_m_comm … Hjde) in ⊢ (% → ?) -Hjde /4/
  97   ]
  98 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #i #Hdi #Hide
  99   elim (IHV12 i ? ?) -IHV12 // #V #HV1 #HV2
 100   elim (IHT12 (i + 1) ? ?) -IHT12 [2: /2 by arith4/ |3: /2/ ] (* just /2/ is too slow *)
 101   -Hdi Hide >arith_c1 >arith_c1x #T #HT1 #HT2
 102   lapply (tps_lsubs_conf … HT1 (L. 𝕓{I} V) ?) -HT1 /3 width=5/
 103 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #i #Hdi #Hide
 104   elim (IHV12 i ? ?) -IHV12 // elim (IHT12 i ? ?) -IHT12 //
 105   -Hdi Hide /3 width=5/
 106 ]
 107 qed.
 108
 109 (* Basic inversion lemmas ***************************************************)
 110
 111 fact tps_inv_atom1_aux: ∀L,T1,T2,d,e. L ⊢ T1 [d, e] ≫ T2 → ∀I. T1 = 𝕒{I} →
 112                         T2 = 𝕒{I} ∨
 113                         ∃∃K,V,i. d ≤ i & i < d + e &
 114                                  ↓[O, i] L ≡ K. 𝕓{Abbr} V &
 115                                  ↑[O, i + 1] V ≡ T2 &
 116                                  I = LRef i.
 117 #L #T1 #T2 #d #e * -L T1 T2 d e
 118 [ #L #I #d #e #J #H destruct -I /2/
 119 | #L #K #V #T2 #i #d #e #Hdi #Hide #HLK #HVT2 #I #H destruct -I /3 width=8/
 120 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #J #H destruct
 121 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #J #H destruct
 122 ]
 123 qed.
 124
 125 lemma tps_inv_atom1: ∀L,T2,I,d,e. L ⊢ 𝕒{I} [d, e] ≫ T2 →
 126                      T2 = 𝕒{I} ∨
 127                      ∃∃K,V,i. d ≤ i & i < d + e &
 128                               ↓[O, i] L ≡ K. 𝕓{Abbr} V &
 129                               ↑[O, i + 1] V ≡ T2 &
 130                               I = LRef i.
 131 /2/ qed.
 132
 133
 134 (* Basic_1: was: subst1_gen_sort *)
 135 lemma tps_inv_sort1: ∀L,T2,k,d,e. L ⊢ ⋆k [d, e] ≫ T2 → T2 = ⋆k.
 136 #L #T2 #k #d #e #H
 137 elim (tps_inv_atom1 … H) -H //
 138 * #K #V #i #_ #_ #_ #_ #H destruct
 139 qed.
 140
 141 (* Basic_1: was: subst1_gen_lref *)
 142 lemma tps_inv_lref1: ∀L,T2,i,d,e. L ⊢ #i [d, e] ≫ T2 →
 143                      T2 = #i ∨
 144                      ∃∃K,V. d ≤ i & i < d + e &
 145                             ↓[O, i] L ≡ K. 𝕓{Abbr} V &
 146                             ↑[O, i + 1] V ≡ T2.
 147 #L #T2 #i #d #e #H
 148 elim (tps_inv_atom1 … H) -H /2/
 149 * #K #V #j #Hdj #Hjde #HLK #HVT2 #H destruct -i /3/
 150 qed.
 151
 152 fact tps_inv_bind1_aux: ∀d,e,L,U1,U2. L ⊢ U1 [d, e] ≫ U2 →
 153                         ∀I,V1,T1. U1 = 𝕓{I} V1. T1 →
 154                         ∃∃V2,T2. L ⊢ V1 [d, e] ≫ V2 &
 155                                  L. 𝕓{I} V2 ⊢ T1 [d + 1, e] ≫ T2 &
 156                                  U2 =  𝕓{I} V2. T2.
 157 #d #e #L #U1 #U2 * -d e L U1 U2
 158 [ #L #k #d #e #I #V1 #T1 #H destruct
 159 | #L #K #V #W #i #d #e #_ #_ #_ #_ #I #V1 #T1 #H destruct
 160 | #L #J #V1 #V2 #T1 #T2 #d #e #HV12 #HT12 #I #V #T #H destruct /2 width=5/
 161 | #L #J #V1 #V2 #T1 #T2 #d #e #_ #_ #I #V #T #H destruct
 162 ]
 163 qed.
 164
 165 lemma tps_inv_bind1: ∀d,e,L,I,V1,T1,U2. L ⊢ 𝕓{I} V1. T1 [d, e] ≫ U2 →
 166                      ∃∃V2,T2. L ⊢ V1 [d, e] ≫ V2 &
 167                               L. 𝕓{I} V2 ⊢ T1 [d + 1, e] ≫ T2 &
 168                               U2 =  𝕓{I} V2. T2.
 169 /2/ qed.
 170
 171 fact tps_inv_flat1_aux: ∀d,e,L,U1,U2. L ⊢ U1 [d, e] ≫ U2 →
 172                         ∀I,V1,T1. U1 = 𝕗{I} V1. T1 →
 173                         ∃∃V2,T2. L ⊢ V1 [d, e] ≫ V2 & L ⊢ T1 [d, e] ≫ T2 &
 174                                  U2 =  𝕗{I} V2. T2.
 175 #d #e #L #U1 #U2 * -d e L U1 U2
 176 [ #L #k #d #e #I #V1 #T1 #H destruct
 177 | #L #K #V #W #i #d #e #_ #_ #_ #_ #I #V1 #T1 #H destruct
 178 | #L #J #V1 #V2 #T1 #T2 #d #e #_ #_ #I #V #T #H destruct
 179 | #L #J #V1 #V2 #T1 #T2 #d #e #HV12 #HT12 #I #V #T #H destruct /2 width=5/
 180 ]
 181 qed.
 182
 183 lemma tps_inv_flat1: ∀d,e,L,I,V1,T1,U2. L ⊢ 𝕗{I} V1. T1 [d, e] ≫ U2 →
 184                      ∃∃V2,T2. L ⊢ V1 [d, e] ≫ V2 & L ⊢ T1 [d, e] ≫ T2 &
 185                               U2 =  𝕗{I} V2. T2.
 186 /2/ qed.
 187
 188 fact tps_inv_refl_O2_aux: ∀L,T1,T2,d,e. L ⊢ T1 [d, e] ≫ T2 → e = 0 → T1 = T2.
 189 #L #T1 #T2 #d #e #H elim H -H L T1 T2 d e
 190 [ //
 191 | #L #K #V #W #i #d #e #Hdi #Hide #_ #_ #H destruct -e;
 192   lapply (le_to_lt_to_lt … Hdi … Hide) -Hdi Hide <plus_n_O #Hdd
 193   elim (lt_refl_false … Hdd)
 194 | /3/
 195 | /3/
 196 ]
 197 qed.
 198
 199 lemma tps_inv_refl_O2: ∀L,T1,T2,d. L ⊢ T1 [d, 0] ≫ T2 → T1 = T2.
 200 /2 width=6/ qed.
 201
 202 (* Basic forward lemmas *****************************************************)
 203
 204 lemma tps_fwd_tw: ∀L,T1,T2,d,e. L ⊢ T1 [d, e] ≫ T2 → #[T1] ≤ #[T2].
 205 #L #T1 #T2 #d #e #H elim H normalize -H L T1 T2 d e
 206 [ //
 207 | /2/
 208 | /3 by monotonic_le_plus_l, le_plus/ (**) (* just /3/ is too slow *)
 209 | /3 by monotonic_le_plus_l, le_plus/ (**) (* just /3/ is too slow *)
 210 ]
 211 qed.
 212
 213 (* Basic_1: removed theorems 25:
 214             subst0_gen_sort subst0_gen_lref subst0_gen_head subst0_gen_lift_lt
 215             subst0_gen_lift_false subst0_gen_lift_ge subst0_refl subst0_trans
 216             subst0_lift_lt subst0_lift_ge subst0_lift_ge_S subst0_lift_ge_s
 217             subst0_subst0 subst0_subst0_back subst0_weight_le subst0_weight_lt
 218             subst0_confluence_neq subst0_confluence_eq subst0_tlt_head
 219             subst0_confluence_lift subst0_tlt
 220             subst1_head subst1_gen_head subst1_lift_S subst1_confluence_lift
 221 *)