matita/matita/contribs/lambda_delta/Basic_2/substitution/tps_lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic_2/substitution/drop_drop.ma".
  16 include "Basic_2/substitution/tps.ma".
  17
  18 (* PARTIAL SUBSTITUTION ON TERMS ********************************************)
  19
  20 (* Advanced inversion lemmas ************************************************)
  21
  22 fact tps_inv_refl_SO2_aux: ∀L,T1,T2,d,e. L ⊢ T1 [d, e] ≫ T2 → e = 1 →
  23                            ∀K,V. ↓[0, d] L ≡ K. 𝕓{Abst} V → T1 = T2.
  24 #L #T1 #T2 #d #e #H elim H -H L T1 T2 d e
  25 [ //
  26 | #L #K0 #V0 #W #i #d #e #Hdi #Hide #HLK0 #_ #H destruct -e;
  27   >(le_to_le_to_eq … Hdi ?) /2/ -d #K #V #HLK
  28   lapply (drop_mono … HLK0 … HLK) #H destruct
  29 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #H1 #K #V #HLK
  30   >(IHV12 H1 … HLK) -IHV12 >(IHT12 H1 K V) -IHT12 /2/
  31 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #H1 #K #V #HLK
  32   >(IHV12 H1 … HLK) -IHV12 >(IHT12 H1 … HLK) -IHT12 //
  33 ]
  34 qed.
  35
  36 lemma tps_inv_refl_SO2: ∀L,T1,T2,d. L ⊢ T1 [d, 1] ≫ T2 →
  37                         ∀K,V. ↓[0, d] L ≡ K. 𝕓{Abst} V → T1 = T2.
  38 /2 width=8/ qed.
  39
  40 (* Relocation properties ****************************************************)
  41
  42 (* Basic_1: was: subst1_lift_lt *)
  43 lemma tps_lift_le: ∀K,T1,T2,dt,et. K ⊢ T1 [dt, et] ≫ T2 →
  44                    ∀L,U1,U2,d,e. ↓[d, e] L ≡ K →
  45                    ↑[d, e] T1 ≡ U1 → ↑[d, e] T2 ≡ U2 →
  46                    dt + et ≤ d →
  47                    L ⊢ U1 [dt, et] ≫ U2.
  48 #K #T1 #T2 #dt #et #H elim H -H K T1 T2 dt et
  49 [ #K #I #dt #et #L #U1 #U2 #d #e #_ #H1 #H2 #_
  50   >(lift_mono … H1 … H2) -H1 H2 //
  51 | #K #KV #V #W #i #dt #et #Hdti #Hidet #HKV #HVW #L #U1 #U2 #d #e #HLK #H #HVU2 #Hdetd
  52   lapply (lt_to_le_to_lt … Hidet … Hdetd) -Hdetd #Hid
  53   lapply (lift_inv_lref1_lt … H … Hid) -H #H destruct -U1;
  54   elim (lift_trans_ge … HVW … HVU2 ?) -HVW HVU2 W // <minus_plus #W #HVW #HWU2
  55   elim (drop_trans_le … HLK … HKV ?) -HLK HKV K [2: /2/] #X #HLK #H
  56   elim (drop_inv_skip2 … H ?) -H [2: /2/] -Hid #K #Y #_ #HVY
  57   >(lift_mono … HVY … HVW) -HVY HVW Y #H destruct -X /2/
  58 | #K #I #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #d #e #HLK #H1 #H2 #Hdetd
  59   elim (lift_inv_bind1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  60   elim (lift_inv_bind1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct -U1 U2;
  61   @tps_bind [ /2 width=6/ | @IHT12 [3,4,5: /2/ |1,2: skip | /2/ ] ] (**) (* /3 width=6/ is too slow, arith3 needed to avoid crash *)
  62 | #K #I #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #d #e #HLK #H1 #H2 #Hdetd
  63   elim (lift_inv_flat1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  64   elim (lift_inv_flat1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct -U1 U2;
  65   /3 width=6/
  66 ]
  67 qed.
  68
  69 (* Basic_1: was: subst1_lift_ge *)
  70 lemma tps_lift_ge: ∀K,T1,T2,dt,et. K ⊢ T1 [dt, et] ≫ T2 →
  71                    ∀L,U1,U2,d,e. ↓[d, e] L ≡ K →
  72                    ↑[d, e] T1 ≡ U1 → ↑[d, e] T2 ≡ U2 →
  73                    d ≤ dt →
  74                    L ⊢ U1 [dt + e, et] ≫ U2.
  75 #K #T1 #T2 #dt #et #H elim H -H K T1 T2 dt et
  76 [ #K #I #dt #et #L #U1 #U2 #d #e #_ #H1 #H2 #_
  77   >(lift_mono … H1 … H2) -H1 H2 //
  78 | #K #KV #V #W #i #dt #et #Hdti #Hidet #HKV #HVW #L #U1 #U2 #d #e #HLK #H #HWU2 #Hddt
  79   lapply (transitive_le … Hddt … Hdti) -Hddt #Hid
  80   lapply (lift_inv_lref1_ge … H … Hid) -H #H destruct -U1;
  81   lapply (lift_trans_be … HVW … HWU2 ? ?) -HVW HWU2 W // [ /2/ ] >plus_plus_comm_23 #HVU2
  82   lapply (drop_trans_ge_comm … HLK … HKV ?) -HLK HKV K // -Hid /3/
  83 | #K #I #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #d #e #HLK #H1 #H2 #Hddt
  84   elim (lift_inv_bind1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  85   elim (lift_inv_bind1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct -U1 U2;
  86   @tps_bind [ /2 width=5/ | /3 width=5/ ] (**) (* explicit constructor *)
  87 | #K #I #V1 #V2 #T1 #T2 #dt #et #_ #_ #IHV12 #IHT12 #L #U1 #U2 #d #e #HLK #H1 #H2 #Hddt
  88   elim (lift_inv_flat1 … H1) -H1 #VV1 #TT1 #HVV1 #HTT1 #H1
  89   elim (lift_inv_flat1 … H2) -H2 #VV2 #TT2 #HVV2 #HTT2 #H2 destruct -U1 U2;
  90   /3 width=5/
  91 ]
  92 qed.
  93
  94 (* Basic_1: was: subst1_gen_lift_lt *)
  95 lemma tps_inv_lift1_le: ∀L,U1,U2,dt,et. L ⊢ U1 [dt, et] ≫ U2 →
  96                         ∀K,d,e. ↓[d, e] L ≡ K → ∀T1. ↑[d, e] T1 ≡ U1 →
  97                         dt + et ≤ d →
  98                         ∃∃T2. K ⊢ T1 [dt, et] ≫ T2 & ↑[d, e] T2 ≡ U2.
  99 #L #U1 #U2 #dt #et #H elim H -H L U1 U2 dt et
 100 [ #L * #i #dt #et #K #d #e #_ #T1 #H #_
 101   [ lapply (lift_inv_sort2 … H) -H #H destruct -T1 /2/
 102   | elim (lift_inv_lref2 … H) -H * #Hid #H destruct -T1 /3/
 103   ]
 104 | #L #KV #V #W #i #dt #et #Hdti #Hidet #HLKV #HVW #K #d #e #HLK #T1 #H #Hdetd
 105   lapply (lt_to_le_to_lt … Hidet … Hdetd) -Hdetd #Hid
 106   lapply (lift_inv_lref2_lt … H … Hid) -H #H destruct -T1;
 107   elim (drop_conf_lt … HLK … HLKV ?) -HLK HLKV L // #L #U #HKL #_ #HUV
 108   elim (lift_trans_le … HUV … HVW ?) -HUV HVW V // >arith_a2 // -Hid /3/
 109 | #L #I #V1 #V2 #U1 #U2 #dt #et #_ #_ #IHV12 #IHU12 #K #d #e #HLK #X #H #Hdetd
 110   elim (lift_inv_bind2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct -X;
 111   elim (IHV12 … HLK … HWV1 ?) -IHV12 HWV1 // #W2 #HW12 #HWV2
 112   elim (IHU12 … HTU1 ?) -IHU12 HTU1 [3: /2/ |4: @drop_skip // |2: skip ] -HLK Hdetd (**) (* /3 width=5/ is too slow *)
 113   /3 width=5/
 114 | #L #I #V1 #V2 #U1 #U2 #dt #et #_ #_ #IHV12 #IHU12 #K #d #e #HLK #X #H #Hdetd
 115   elim (lift_inv_flat2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct -X;
 116   elim (IHV12 … HLK … HWV1 ?) -IHV12 HWV1 //
 117   elim (IHU12 … HLK … HTU1 ?) -IHU12 HLK HTU1 // /3 width=5/
 118 ]
 119 qed.
 120
 121 (* Basic_1: was: subst1_gen_lift_ge *)
 122 lemma tps_inv_lift1_ge: ∀L,U1,U2,dt,et. L ⊢ U1 [dt, et] ≫ U2 →
 123                         ∀K,d,e. ↓[d, e] L ≡ K → ∀T1. ↑[d, e] T1 ≡ U1 →
 124                         d + e ≤ dt →
 125                         ∃∃T2. K ⊢ T1 [dt - e, et] ≫ T2 & ↑[d, e] T2 ≡ U2.
 126 #L #U1 #U2 #dt #et #H elim H -H L U1 U2 dt et
 127 [ #L * #i #dt #et #K #d #e #_ #T1 #H #_
 128   [ lapply (lift_inv_sort2 … H) -H #H destruct -T1 /2/
 129   | elim (lift_inv_lref2 … H) -H * #Hid #H destruct -T1 /3/
 130   ]
 131 | #L #KV #V #W #i #dt #et #Hdti #Hidet #HLKV #HVW #K #d #e #HLK #T1 #H #Hdedt
 132   lapply (transitive_le … Hdedt … Hdti) #Hdei
 133   lapply (plus_le_weak … Hdedt) -Hdedt #Hedt
 134   lapply (plus_le_weak … Hdei) #Hei
 135   lapply (lift_inv_lref2_ge … H … Hdei) -H #H destruct -T1;
 136   lapply (drop_conf_ge … HLK … HLKV ?) -HLK HLKV L // #HKV
 137   elim (lift_split … HVW d (i - e + 1) ? ? ?) -HVW; [2,3,4: normalize /2/ ] -Hdei >arith_e2 // #V0 #HV10 #HV02
 138   @ex2_1_intro
 139   [2: @tps_subst [3: /2/ |5,6: // |1,2: skip |4: @arith5 // ]
 140   |1: skip
 141   | //
 142   ] (**) (* explicitc constructors *)
 143 | #L #I #V1 #V2 #U1 #U2 #dt #et #_ #_ #IHV12 #IHU12 #K #d #e #HLK #X #H #Hdetd
 144   elim (lift_inv_bind2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct -X;
 145   lapply (plus_le_weak … Hdetd) #Hedt
 146   elim (IHV12 … HLK … HWV1 ?) -IHV12 HWV1 // #W2 #HW12 #HWV2
 147   elim (IHU12 … HTU1 ?) -IHU12 HTU1 [4: @drop_skip // |2: skip |3: /2/ ]
 148   <plus_minus // /3 width=5/
 149 | #L #I #V1 #V2 #U1 #U2 #dt #et #_ #_ #IHV12 #IHU12 #K #d #e #HLK #X #H #Hdetd
 150   elim (lift_inv_flat2 … H) -H #W1 #T1 #HWV1 #HTU1 #H destruct -X;
 151   elim (IHV12 … HLK … HWV1 ?) -IHV12 HWV1 //
 152   elim (IHU12 … HLK … HTU1 ?) -IHU12 HLK HTU1 // /3 width=5/
 153 ]
 154 qed.
 155
 156 (* Basic_1: was: subst1_gen_lift_eq *)
 157 lemma tps_inv_lift1_eq: ∀L,U1,U2,d,e.
 158                         L ⊢ U1 [d, e] ≫ U2 → ∀T1. ↑[d, e] T1 ≡ U1 → U1 = U2.
 159 #L #U1 #U2 #d #e #H elim H -H L U1 U2 d e
 160 [ //
 161 | #L #K #V #W #i #d #e #Hdi #Hide #_ #_ #T1 #H
 162   elim (lift_inv_lref2 … H) -H * #H
 163   [ lapply (le_to_lt_to_lt … Hdi … H) -Hdi H #H
 164     elim (lt_refl_false … H)
 165   | lapply (lt_to_le_to_lt … Hide … H) -Hide H #H
 166     elim (lt_refl_false … H)
 167   ]
 168 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
 169   elim (lift_inv_bind2 … HX) -HX #V #T #HV1 #HT1 #H destruct -X
 170   >IHV12 // >IHT12 //
 171 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #X #HX
 172   elim (lift_inv_flat2 … HX) -HX #V #T #HV1 #HT1 #H destruct -X
 173   >IHV12 // >IHT12 //
 174 ]
 175 qed.
 176 (*
 177       Theorem subst0_gen_lift_rev_ge: (t1,v,u2:?; i,h,d:?)
 178                                       (subst0 i v t1 (lift h d u2)) ->
 179                                       (le (plus d h) i) ->
 180                                       (EX u1 | (subst0 (minus i h) v u1 u2) &
 181                                                t1 = (lift h d u1)
 182                                       ).
 183
 184
 185       Theorem subst0_gen_lift_rev_lelt: (t1,v,u2:?; i,h,d:?)
 186                                         (subst0 i v t1 (lift h d u2)) ->
 187                                         (le d i) -> (lt i (plus d h)) ->
 188                                         (EX u1 | t1 = (lift (minus (plus d h) (S i)) (S i) u1)).
 189 *)
 190
 191 lemma tps_inv_lift1_up: ∀L,U1,U2,dt,et. L ⊢ U1 [dt, et] ≫ U2 →
 192                         ∀K,d,e. ↓[d, e] L ≡ K → ∀T1. ↑[d, e] T1 ≡ U1 →
 193                         d ≤ dt → dt ≤ d + e → d + e ≤ dt + et →
 194                         ∃∃T2. K ⊢ T1 [d, dt + et - (d + e)] ≫ T2 & ↑[d, e] T2 ≡ U2.
 195 #L #U1 #U2 #dt #et #HU12 #K #d #e #HLK #T1 #HTU1 #Hddt #Hdtde #Hdedet
 196 elim (tps_split_up … HU12 (d + e) ? ?) -HU12 // -Hdedet #U #HU1 #HU2
 197 lapply (tps_weak … HU1 d e ? ?) -HU1 // <plus_minus_m_m_comm // -Hddt Hdtde #HU1
 198 lapply (tps_inv_lift1_eq … HU1 … HTU1) -HU1 #HU1 destruct -U1;
 199 elim (tps_inv_lift1_ge … HU2 … HLK … HTU1 ?) -HU2 HLK HTU1 // <minus_plus_m_m /2/
 200 qed.