matita/matita/contribs/lambda_delta/Basic_2/unfold/ldrops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic_2/substitution/ldrop.ma".
  16 include "Basic_2/unfold/gr2_minus.ma".
  17 include "Basic_2/unfold/lifts.ma".
  18
  19 (* GENERIC LOCAL ENVIRONMENT SLICING ****************************************)
  20
  21 inductive ldrops: list2 nat nat → relation lenv ≝
  22 | ldrops_nil : ∀L. ldrops ⟠ L L
  23 | ldrops_cons: ∀L1,L,L2,des,d,e.
  24                ldrops des L1 L → ⇩[d,e] L ≡ L2 → ldrops ({d, e} :: des) L1 L2
  25 .
  26
  27 interpretation "generic local environment slicing"
  28    'RDropStar des T1 T2 = (ldrops des T1 T2).
  29
  30 (* Basic inversion lemmas ***************************************************)
  31
  32 fact ldrops_inv_nil_aux: ∀L1,L2,des. ⇩*[des] L1 ≡ L2 → des = ⟠ → L1 = L2.
  33 #L1 #L2 #des * -L1 -L2 -des //
  34 #L1 #L #L2 #d #e #des #_ #_ #H destruct
  35 qed.
  36
  37 lemma ldrops_inv_nil: ∀L1,L2. ⇩*[⟠] L1 ≡ L2 → L1 = L2.
  38 /2 width=3/ qed-.
  39
  40 fact ldrops_inv_cons_aux: ∀L1,L2,des. ⇩*[des] L1 ≡ L2 →
  41                           ∀d,e,tl. des = {d, e} :: tl →
  42                           ∃∃L. ⇩*[tl] L1 ≡ L & ⇩[d, e] L ≡ L2.
  43 #L1 #L2 #des * -L1 -L2 -des
  44 [ #L #d #e #tl #H destruct
  45 | #L1 #L #L2 #des #d #e #HT1 #HT2 #hd #he #tl #H destruct
  46   /2 width=3/
  47 qed.
  48
  49 lemma ldrops_inv_cons: ∀L1,L2,d,e,des. ⇩*[{d, e} :: des] L1 ≡ L2 →
  50                        ∃∃L. ⇩*[des] L1 ≡ L & ⇩[d, e] L ≡ L2.
  51 /2 width=3/ qed-.
  52
  53 lemma ldrops_inv_skip2: ∀I,des,i,des2. des ▭ i ≡ des2 →
  54                         ∀L1,K2,V2. ⇩*[des2] L1 ≡ K2. ⓑ{I} V2 →
  55                         ∃∃K1,V1,des1. des + 1 ▭ i + 1 ≡ des1 + 1 &
  56                                       ⇩*[des1] K1 ≡ K2 &
  57                                       ⇧*[des1] V2 ≡ V1 &
  58                                       L1 = K1. ⓑ{I} V1.
  59 #I #des #i #des2 #H elim H -des -i -des2
  60 [ #i #L1 #K2 #V2 #H
  61   >(ldrops_inv_nil … H) -L1 /2 width=7/
  62 | #des #des2 #d #e #i #Hid #_ #IHdes2 #L1 #K2 #V2 #H
  63   elim (ldrops_inv_cons … H) -H #L #HL1 #H
  64   elim (ldrop_inv_skip2 … H ?) -H /2 width=1/ #K #V >minus_plus #HK2 #HV2 #H destruct
  65   elim (IHdes2 … HL1) -IHdes2 -HL1 #K1 #V1 #des1 #Hdes1 #HK1 #HV1 #X destruct
  66   @(ex4_3_intro … K1 V1 … ) // [3,4: /2 width=7/ | skip ]
  67   normalize >plus_minus // @minuss_lt // /2 width=1/ (**) (* explicit constructors, /3 width=1/ is a bit slow *)
  68 | #des #des2 #d #e #i #Hid #_ #IHdes2 #L1 #K2 #V2 #H
  69   elim (IHdes2 … H) -IHdes2 -H #K1 #V1 #des1 #Hdes1 #HK1 #HV1 #X destruct
  70   /4 width=7/
  71 ]
  72 qed-.
  73
  74 (* Basic properties *********************************************************)
  75
  76 lemma ldrops_skip: ∀L1,L2,des. ⇩*[des] L1 ≡ L2 → ∀V1,V2. ⇧*[des] V2 ≡ V1 →
  77                    ∀I. ⇩*[des + 1] L1. ⓑ{I} V1 ≡ L2. ⓑ{I} V2.
  78 #L1 #L2 #des #H elim H -L1 -L2 -des
  79 [ #L #V1 #V2 #HV12 #I
  80   >(lifts_inv_nil … HV12) -HV12 //
  81 | #L1 #L #L2 #des #d #e #_ #HL2 #IHL #V1 #V2 #H #I
  82   elim (lifts_inv_cons … H) -H /3 width=5/
  83 ].
  84 qed.
  85
  86 (* Basic_1: removed theorems 1: drop1_getl_trans
  87 *)