matita/matita/contribs/lambda_delta/Basic_2/unfold/ldrops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic_2/substitution/ldrop.ma".
  16 include "Basic_2/unfold/lifts.ma".
  17
  18 (* GENERIC LOCAL ENVIRONMENT SLICING ****************************************)
  19
  20 inductive ldrops: list2 nat nat → relation lenv ≝
  21 | ldrops_nil : ∀L. ldrops ⟠ L L
  22 | ldrops_cons: ∀L1,L,L2,des,d,e.
  23                ldrops des L1 L → ⇩[d,e] L ≡ L2 → ldrops ({d, e} :: des) L1 L2
  24 .
  25
  26 interpretation "generic local environment slicing"
  27    'RDropStar des T1 T2 = (ldrops des T1 T2).
  28
  29 (* Basic inversion lemmas ***************************************************)
  30
  31 fact ldrops_inv_nil_aux: ∀L1,L2,des. ⇩*[des] L1 ≡ L2 → des = ⟠ → L1 = L2.
  32 #L1 #L2 #des * -L1 -L2 -des //
  33 #L1 #L #L2 #d #e #des #_ #_ #H destruct
  34 qed.
  35
  36 lemma ldrops_inv_nil: ∀L1,L2. ⇩*[⟠] L1 ≡ L2 → L1 = L2.
  37 /2 width=3/ qed-.
  38
  39 fact ldrops_inv_cons_aux: ∀L1,L2,des. ⇩*[des] L1 ≡ L2 →
  40                           ∀d,e,tl. des = {d, e} :: tl →
  41                           ∃∃L. ⇩*[tl] L1 ≡ L & ⇩[d, e] L ≡ L2.
  42 #L1 #L2 #des * -L1 -L2 -des
  43 [ #L #d #e #tl #H destruct
  44 | #L1 #L #L2 #des #d #e #HT1 #HT2 #hd #he #tl #H destruct
  45   /2 width=3/
  46 qed.
  47
  48 lemma ldrops_inv_cons: ∀L1,L2,d,e,des. ⇩*[{d, e} :: des] L1 ≡ L2 →
  49                        ∃∃L. ⇩*[des] L1 ≡ L & ⇩[d, e] L ≡ L2.
  50 /2 width=3/ qed-.
  51
  52 lemma ldrops_inv_skip2: ∀I,des,i,des2. des ▭ i ≡ des2 →
  53                         ∀L1,K2,V2. ⇩*[des2] L1 ≡ K2. 𝕓{I} V2 →
  54                         ∃∃K1,V1,des1. des + 1 ▭ i + 1 ≡ des1 + 1 &
  55                                       ⇩*[des1] K1 ≡ K2 &
  56                                       ⇧*[des1] V2 ≡ V1 &
  57                                       L1 = K1. 𝕓{I} V1.
  58 #I #des #i #des2 #H elim H -des -i -des2
  59 [ #i #L1 #K2 #V2 #H
  60   >(ldrops_inv_nil … H) -L1 /2 width=7/
  61 | #des #des2 #d #e #i #Hid #_ #IHdes2 #L1 #K2 #V2 #H
  62   elim (ldrops_inv_cons … H) -H #L #HL1 #H
  63   elim (ldrop_inv_skip2 … H ?) -H /2 width=1/ #K #V >minus_plus #HK2 #HV2 #H destruct
  64   elim (IHdes2 … HL1) -IHdes2 -HL1 #K1 #V1 #des1 #Hdes1 #HK1 #HV1 #X destruct
  65   @(ex4_3_intro … K1 V1 … ) // [3,4: /2 width=7/ | skip ]
  66   normalize >plus_minus // @minuss_lt // /2 width=1/ (**) (* explicit constructors, /3 width=1/ is a bit slow *)
  67 | #des #des2 #d #e #i #Hid #_ #IHdes2 #L1 #K2 #V2 #H
  68   elim (IHdes2 … H) -IHdes2 -H #K1 #V1 #des1 #Hdes1 #HK1 #HV1 #X destruct
  69   /4 width=7/
  70 ]
  71 qed-.
  72
  73 (* Basic properties *********************************************************)
  74
  75 lemma ldrops_skip: ∀L1,L2,des. ⇩*[des] L1 ≡ L2 → ∀V1,V2. ⇧*[des] V2 ≡ V1 →
  76                    ∀I. ⇩*[des + 1] L1. 𝕓{I} V1 ≡ L2. 𝕓{I} V2.
  77 #L1 #L2 #des #H elim H -L1 -L2 -des
  78 [ #L #V1 #V2 #HV12 #I
  79   >(lifts_inv_nil … HV12) -HV12 //
  80 | #L1 #L #L2 #des #d #e #_ #HL2 #IHL #V1 #V2 #H #I
  81   elim (lifts_inv_cons … H) -H /3 width=5/
  82 ].
  83 qed.
  84
  85 (* Basic_1: removed theorems 1: drop1_getl_trans
  86 *)