matita/matita/contribs/lambda_delta/Basic_2/unfold/lifts_lifts.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic_2/substitution/lift_lift.ma".
  16 include "Basic_2/unfold/lifts.ma".
  17
  18 (* GENERIC RELOCATION *******************************************************)
  19
  20 (* Main properties **********************************************************)
  21
  22 (* Basic_1: was: lift1_xhg *)
  23 lemma lifts_lift_trans_le: ∀T1,T,des. ⇧*[des] T1 ≡ T → ∀T2. ⇧[0, 1] T ≡ T2 →
  24                            ∃∃T0. ⇧[0, 1] T1 ≡ T0 & ⇧*[ss des] T0 ≡ T2.
  25 #T1 #T #des #H elim H -T1 -T -des
  26 [ /2 width=3/
  27 | #T1 #T3 #T #des #d #e #HT13 #_ #IHT13 #T2 #HT2
  28   elim (IHT13 … HT2) -T #T #HT3 #HT2
  29   elim (lift_trans_le … HT13 … HT3 ?) -T3 // /3 width=5/
  30 ]
  31 qed-.
  32
  33 (* Basic_1: was: lift1_lift1 *)
  34 theorem lifts_trans: ∀T1,T,des1. ⇧*[des1] T1 ≡ T → ∀T2:term. ∀des2. ⇧*[des2] T ≡ T2 →
  35                      ⇧*[des1 @ des2] T1 ≡ T2.
  36 #T1 #T #des1 #H elim H -T1 -T -des1 // /3 width=3/
  37 qed.