matita/matita/contribs/lambda_delta/Ground_2/arith.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "arithmetics/nat.ma".
  16 include "Ground_2/xoa_props.ma".
  17
  18 (* ARITHMETICAL PROPERTIES **************************************************)
  19
  20 lemma plus_S_eq_O_false: ∀n,m. n + S m = 0 → False.
  21 #n #m <plus_n_Sm #H destruct
  22 qed.
  23
  24 lemma plus_S_le_to_pos: ∀n,m,p. n + S m ≤ p → 0 < p.
  25 #n #m #p <plus_n_Sm #H @(lt_to_le_to_lt … H) //
  26 qed.
  27
  28 lemma minus_le: ∀m,n. m - n ≤ m.
  29 /2/ qed.
  30
  31 lemma le_O_to_eq_O: ∀n. n ≤ 0 → n = 0.
  32 /2/ qed.
  33
  34 lemma lt_to_le: ∀a,b. a < b → a ≤ b.
  35 /2/ qed.
  36
  37 lemma lt_refl_false: ∀n. n < n → False.
  38 #n #H elim (lt_to_not_eq … H) -H /2/
  39 qed.
  40
  41 lemma lt_zero_false: ∀n. n < 0 → False.
  42 #n #H elim (lt_to_not_le … H) -H /2/
  43 qed.
  44
  45 lemma lt_or_ge: ∀m,n. m < n ∨ n ≤ m.
  46 #m #n elim (decidable_lt m n) /3/
  47 qed.
  48
  49 lemma lt_or_eq_or_gt: ∀m,n. ∨∨ m < n | n = m | n < m.
  50 #m elim m -m
  51 [ * /2/
  52 | #m #IHm * [ /2/ ]
  53   #n elim (IHm n) -IHm #H
  54   [ @or3_intro0 | @or3_intro1 destruct | @or3_intro2 ] /2/ (**) (* /3/ is slow *)
  55   qed.
  56
  57 lemma le_to_lt_or_eq: ∀m,n. m ≤ n → m < n ∨ m = n.
  58 /2/ qed. (**) (* REMOVE: this is le_to_or_lt_eq *)
  59
  60 lemma plus_le_weak: ∀m,n,p. m + n ≤ p → n ≤ p.
  61 /2/ qed.
  62
  63 lemma plus_lt_false: ∀m,n. m + n < m → False.
  64 #m #n #H1 lapply (le_plus_n_r n m) #H2
  65 lapply (le_to_lt_to_lt … H2 H1) -H2 H1 #H
  66 elim (lt_refl_false … H)
  67 qed.
  68
  69 lemma le_fwd_plus_plus_ge: ∀m1,m2. m2 ≤ m1 → ∀n1,n2. m1 + n1 ≤ m2 + n2 → n1 ≤ n2.
  70 #m1 #m2 #H elim H -H m1
  71 [ /2/
  72 | #m1 #_ #IHm1 #n1 #n2 #H @IHm1 /2/
  73 ]
  74 qed.
  75
  76 lemma monotonic_lt_minus_l: ∀p,q,n. n ≤ q → q < p → q - n < p - n.
  77 #p #q #n #H1 #H2
  78 @lt_plus_to_minus_r <plus_minus_m_m //.
  79 qed.
  80
  81 lemma plus_le_minus: ∀a,b,c. a + b ≤ c → a ≤ c - b.
  82 /2/ qed.
  83
  84 lemma lt_plus_minus: ∀i,u,d. u ≤ i → i < d + u → i - u < d.
  85 /2/ qed.
  86
  87 lemma plus_plus_comm_23: ∀m,n,p. m + n + p = m + p + n.
  88 // qed.
  89
  90 lemma le_plus_minus_comm: ∀n,m,p. p ≤ m → m + n - p = m - p + n.
  91 #n #m #p #lepm @plus_to_minus <associative_plus
  92 >(commutative_plus p) <plus_minus_m_m //
  93 qed.
  94
  95 lemma minus_le_minus_minus_comm: ∀b,c,a. c ≤ b → a - (b - c) = a + c - b.
  96 #b elim b -b
  97 [ #c #a #H >(le_O_to_eq_O … H) -H //
  98 | #b #IHb #c elim c -c //
  99   #c #_ #a #Hcb
 100   lapply (le_S_S_to_le … Hcb) -Hcb #Hcb
 101   <plus_n_Sm normalize /2/
 102 ]
 103 qed.
 104
 105 lemma minus_plus_comm: ∀a,b,c. a - b - c = a - (c + b).
 106 // qed.
 107
 108 lemma minus_minus_comm: ∀a,b,c. a - b - c = a - c - b.
 109 /3/ qed.
 110
 111 lemma le_plus_minus: ∀a,b,c. c ≤ b → a + b - c = a + (b - c).
 112 /2/ qed.
 113
 114 lemma plus_minus_m_m_comm: ∀n,m. m ≤ n → n = m + (n - m).
 115 /2/ qed.
 116
 117 lemma minus_plus_m_m_comm: ∀n,m. n = (m + n) - m.
 118 /2/ qed.
 119
 120 lemma arith_a2: ∀a,c1,c2. c1 + c2 ≤ a → a - c1 - c2 + (c1 + c2) = a.
 121 /2/ qed.
 122
 123 lemma arith_b1: ∀a,b,c1. c1 ≤ b → a - c1 - (b - c1) = a - b.
 124 #a #b #c1 #H >minus_plus @eq_f2 /2/
 125 qed.
 126
 127 lemma arith_b2: ∀a,b,c1,c2. c1 + c2 ≤ b → a - c1 - c2 - (b - c1 - c2) = a - b.
 128 #a #b #c1 #c2 #H >minus_plus >minus_plus >minus_plus /2/
 129 qed.
 130
 131 lemma arith_c1: ∀a,b,c1. a + c1 - (b + c1) = a - b.
 132 // qed.
 133
 134 lemma arith_c1x: ∀x,a,b,c1. x + c1 + a - (b + c1) = x + a - b.
 135 #x #a #b #c1 >plus_plus_comm_23 //
 136 qed.
 137
 138 lemma arith_d1: ∀a,b,c1. c1 ≤ b → a + c1 + (b - c1) = a + b.
 139 /2/ qed.
 140
 141 lemma arith_e2: ∀a,c1,c2. a ≤ c1 → c1 + c2 - (c1 - a + c2) = a.
 142 /3/ qed.
 143
 144 lemma arith_f1: ∀a,b,c1. a + b ≤ c1 → c1 - (c1 - a - b) = a + b.
 145 #a #b #c1 #H >minus_plus <minus_minus //
 146 qed.
 147
 148 lemma arith_g1: ∀a,b,c1. c1 ≤ b → a - (b - c1) - c1 = a - b.
 149 /2/ qed.
 150
 151 lemma arith_h1: ∀a1,a2,b,c1. c1 ≤ a1 → c1 ≤ b →
 152                 a1 - c1 + a2 - (b - c1) = a1 + a2 - b.
 153 #a1 #a2 #b #c1 #H1 #H2 <le_plus_minus_comm /2/
 154 qed.
 155
 156 lemma arith_i2: ∀a,c1,c2. c1 + c2 ≤ a → c1 + c2 + (a - c1 - c2) = a.
 157 /2/ qed.
 158
 159 lemma arith_z1: ∀a,b,c1. a + c1 - b - c1 = a - b.
 160 // qed.
 161
 162 (* unstable *****************************************************************)
 163
 164 lemma arith1: ∀n,h,m,p. n + h + m ≤ p + h → n + m ≤ p.
 165 /2/ qed.
 166
 167 lemma arith2: ∀j,i,e,d. d + e ≤ i → d ≤ i - e + j.
 168 #j #i #e #d #H lapply (plus_le_minus … H) -H /2/
 169 qed.
 170
 171 lemma arith3: ∀a1,a2,b,c1. a1 + a2 ≤ b → a1 + c1 + a2 ≤ b + c1.
 172 /2/ qed.
 173
 174 lemma arith4: ∀h,d,e1,e2. d ≤ e1 + e2 → d + h ≤ e1 + h + e2.
 175 /2/ qed.
 176
 177 lemma arith5: ∀a,b1,b2,c1. c1 ≤ b1 → c1 ≤ a → a < b1 + b2 → a - c1 < b1 - c1 + b2.
 178 #a #b1 #b2 #c1 #H1 #H2 #H3
 179 <le_plus_minus_comm // @monotonic_lt_minus_l //
 180 qed.
 181
 182 lemma arith8: ∀a,b. a < a + b + 1.
 183 // qed.
 184
 185 lemma arith9: ∀a,b,c. c < a + (b + c + 1) + 1.
 186 // qed.
 187
 188 lemma arith10: ∀a,b,c,d,e. a ≤ b → c + (a - d - e) ≤ c + (b - d - e).
 189 #a #b #c #d #e #H
 190 >minus_plus >minus_plus @monotonic_le_plus_r @monotonic_le_minus_l //
 191 qed.