matita/matita/contribs/lambda_delta/basic_2/computation/cprs_lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic_2/reducibility/cpr_lift.ma".
  16 include "Basic_2/computation/cprs.ma".
  17
  18 (* CONTEXT-SENSITIVE PARALLEL COMPUTATION ON TERMS **************************)
  19
  20 (* Relocation properties ****************************************************)
  21
  22 (* Basic_1: was: pr3_lift *)
  23 lemma cprs_lift: ∀L,K,d,e. ⇩[d, e] L ≡ K → ∀T1,U1. ⇧[d, e] T1 ≡ U1 →
  24                  ∀T2. K ⊢ T1 ➡* T2 → ∀U2. ⇧[d, e] T2 ≡ U2 →
  25                  L ⊢ U1 ➡* U2.
  26 #L #K #d #e #HLK #T1 #U1 #HTU1 #T2 #HT12 @(cprs_ind … HT12) -T2
  27 [ -HLK #T2 #HT12
  28    <(lift_mono … HTU1 … HT12) -T1 //
  29 | -HTU1 #T #T2 #_ #HT2 #IHT2 #U2 #HTU2
  30   elim (lift_total T d e) #U #HTU
  31   lapply (cpr_lift … HLK … HTU … HTU2 … HT2) -T2 -HLK /3 width=3/
  32 ]
  33 qed.
  34
  35 (* Basic_1: was: pr3_gen_lift *)
  36 lemma cprs_inv_lift: ∀L,K,d,e. ⇩[d, e] L ≡ K →
  37                      ∀T1,U1. ⇧[d, e] T1 ≡ U1 → ∀U2. L ⊢ U1 ➡* U2 →
  38                      ∃∃T2. ⇧[d, e] T2 ≡ U2 & K ⊢ T1 ➡* T2.
  39 #L #K #d #e #HLK #T1 #U1 #HTU1 #U2 #HU12 @(cprs_ind … HU12) -U2 /2 width=3/
  40 -HTU1 #U #U2 #_ #HU2 * #T #HTU #HT1
  41 elim (cpr_inv_lift … HLK … HTU … HU2) -U -HLK /3 width=5/
  42 qed.