matita/matita/contribs/lambda_delta/basic_2/computation/csn.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/reducibility/cpr.ma".
  16 include "basic_2/reducibility/cnf.ma".
  17
  18 (* CONTEXT-SENSITIVE STRONGLY NORMALIZING TERMS *****************************)
  19
  20 definition csn: lenv → predicate term ≝ λL. SN … (cpr L) (eq …).
  21
  22 interpretation
  23    "context-sensitive strong normalization (term)"
  24    'SN L T = (csn L T).
  25
  26 (* Basic eliminators ********************************************************)
  27
  28 lemma csn_ind: ∀L. ∀R:predicate term.
  29                (∀T1. L ⊢ ⬇* T1 →
  30                      (∀T2. L ⊢ T1 ➡ T2 → (T1 = T2 → False) → R T2) →
  31                      R T1
  32                ) →
  33                ∀T. L ⊢ ⬇* T → R T.
  34 #L #R #H0 #T1 #H elim H -T1 #T1 #HT1 #IHT1
  35 @H0 -H0 /3 width=1/ -IHT1 /4 width=1/
  36 qed-.
  37
  38 (* Basic properties *********************************************************)
  39
  40 (* Basic_1: was: sn3_pr2_intro *)
  41 lemma csn_intro: ∀L,T1.
  42                  (∀T2. L ⊢ T1 ➡ T2 → (T1 = T2 → False) → L ⊢ ⬇* T2) → L ⊢ ⬇* T1.
  43 #L #T1 #H
  44 @(SN_intro … H)
  45 qed.
  46
  47 (* Basic_1: was: sn3_nf2 *)
  48 lemma csn_cnf: ∀L,T. L ⊢ 𝐍[T] → L ⊢ ⬇* T.
  49 /2 width=1/ qed.
  50
  51 lemma csn_cpr_trans: ∀L,T1. L ⊢ ⬇* T1 → ∀T2. L ⊢ T1 ➡ T2 → L ⊢ ⬇* T2.
  52 #L #T1 #H elim H -T1 #T1 #HT1 #IHT1 #T2 #HLT12
  53 @csn_intro #T #HLT2 #HT2
  54 elim (term_eq_dec T1 T2) #HT12
  55 [ -IHT1 -HLT12 destruct /3 width=1/
  56 | -HT1 -HT2 /3 width=4/
  57 qed.
  58
  59 (* Basic_1: was: sn3_cast *)
  60 lemma csn_cast: ∀L,W. L ⊢ ⬇* W → ∀T. L ⊢ ⬇* T → L ⊢ ⬇* ⓣW. T.
  61 #L #W #HW elim HW -W #W #_ #IHW #T #HT @(csn_ind … HT) -T #T #HT #IHT
  62 @csn_intro #X #H1 #H2
  63 elim (cpr_inv_cast1 … H1) -H1
  64 [ * #W0 #T0 #HLW0 #HLT0 #H destruct
  65   elim (eq_false_inv_tpair_sn … H2) -H2
  66   [ /3 width=3/
  67   | -HLW0 * #H destruct /3 width=1/
  68   ]
  69 | /3 width=3/
  70 ]
  71 qed.
  72
  73 (* Basic forward lemmas *****************************************************)
  74
  75 fact csn_fwd_flat_dx_aux: ∀L,U. L ⊢ ⬇* U → ∀I,V,T. U = ⓕ{I} V. T → L ⊢ ⬇* T.
  76 #L #U #H elim H -H #U0 #_ #IH #I #V #T #H destruct
  77 @csn_intro #T2 #HLT2 #HT2
  78 @(IH (ⓕ{I} V. T2)) -IH // /2 width=1/ -HLT2 #H destruct /2 width=1/
  79 qed.
  80
  81 (* Basic_1: was: sn3_gen_flat *)
  82 lemma csn_fwd_flat_dx: ∀I,L,V,T. L ⊢ ⬇* ⓕ{I} V. T → L ⊢ ⬇* T.
  83 /2 width=5/ qed-.
  84
  85 (* Basic_1: removed theorems 10:
  86             sn3_gen_cflat sn3_cflat
  87             sn3_appl_cast sn3_appl_beta sn3_appl_lref sn3_appl_abbr
  88             sn3_appl_appls sn3_bind sn3_appl_bind sn3_appls_bind
  89 *)