matita/matita/contribs/lambda_delta/basic_2/computation/csn_alt.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/computation/cprs.ma".
  16 include "basic_2/computation/csn.ma".
  17
  18 (* CONTEXT-SENSITIVE STRONGLY NORMALIZING TERMS *****************************)
  19
  20 (* alternative definition of csn *)
  21 definition csna: lenv → predicate term ≝ λL. SN … (cprs L) (eq …).
  22
  23 interpretation
  24    "context-sensitive strong normalization (term) alternative"
  25    'SNAlt L T = (csna L T).
  26
  27 (* Basic eliminators ********************************************************)
  28
  29 lemma csna_ind: ∀L. ∀R:predicate term.
  30                 (∀T1. L ⊢ ⬇⬇* T1 →
  31                       (∀T2. L ⊢ T1 ➡* T2 → (T1 = T2 → False) → R T2) → R T1
  32                 ) →
  33                 ∀T. L ⊢ ⬇⬇* T → R T.
  34 #L #R #H0 #T1 #H elim H -T1 #T1 #HT1 #IHT1
  35 @H0 -H0 /3 width=1/ -IHT1 /4 width=1/
  36 qed-.
  37
  38 (* Basic properties *********************************************************)
  39
  40 (* Basic_1: was: sn3_intro *)
  41 lemma csna_intro: ∀L,T1.
  42                   (∀T2. L ⊢ T1 ➡* T2 → (T1 = T2 → False) → L ⊢ ⬇⬇* T2) → L ⊢ ⬇⬇* T1.
  43 #L #T1 #H
  44 @(SN_intro … H)
  45 qed.
  46
  47 fact csna_intro_aux: ∀L,T1.
  48                      (∀T,T2. L ⊢ T ➡* T2 → T1 = T → (T1 = T2 → False) → L ⊢ ⬇⬇* T2) → L ⊢ ⬇⬇* T1.
  49 /4 width=3/ qed-.
  50
  51 (* Basic_1: was: sn3_pr3_trans (old version) *)
  52 lemma csna_cprs_trans: ∀L,T1. L ⊢ ⬇⬇* T1 → ∀T2. L ⊢ T1 ➡* T2 → L ⊢ ⬇⬇* T2.
  53 #L #T1 #H elim H -T1 #T1 #HT1 #IHT1 #T2 #HLT12
  54 @csna_intro #T #HLT2 #HT2
  55 elim (term_eq_dec T1 T2) #HT12
  56 [ -IHT1 -HLT12 destruct /3 width=1/
  57 | -HT1 -HT2 /3 width=4/
  58 qed.
  59
  60 (* Basic_1: was: sn3_pr2_intro (old version) *)
  61 lemma csna_intro_cpr: ∀L,T1.
  62                       (∀T2. L ⊢ T1 ➡ T2 → (T1 = T2 → False) → L ⊢ ⬇⬇* T2) →
  63                       L ⊢ ⬇⬇* T1.
  64 #L #T1 #H
  65 @csna_intro_aux #T #T2 #H @(cprs_ind_dx … H) -T
  66 [ -H #H destruct #H
  67   elim (H ?) //
  68 | #T0 #T #HLT1 #HLT2 #IHT #HT10 #HT12 destruct
  69   elim (term_eq_dec T0 T) #HT0
  70   [ -HLT1 -HLT2 -H /3 width=1/
  71   | -IHT -HT12 /4 width=3/
  72   ]
  73 ]
  74 qed.
  75
  76 (* Main properties **********************************************************)
  77
  78 theorem csn_csna: ∀L,T. L ⊢ ⬇* T → L ⊢ ⬇⬇* T.
  79 #L #T #H @(csn_ind … H) -T /4 width=1/
  80 qed.
  81
  82 theorem csna_csn: ∀L,T. L ⊢ ⬇⬇* T → L ⊢ ⬇* T.
  83 #L #T #H @(csna_ind … H) -T /4 width=1/
  84 qed.
  85
  86 (* Basic_1: was: sn3_pr3_trans *)
  87 lemma csn_cprs_trans: ∀L,T1. L ⊢ ⬇* T1 → ∀T2. L ⊢ T1 ➡* T2 → L ⊢ ⬇* T2.
  88 /4 width=3/ qed.
  89
  90 (* Main eliminators *********************************************************)
  91
  92 lemma csn_ind_alt: ∀L. ∀R:predicate term.
  93                    (∀T1. L ⊢ ⬇* T1 →
  94                          (∀T2. L ⊢ T1 ➡* T2 → (T1 = T2 → False) → R T2) → R T1
  95                    ) →
  96                    ∀T. L ⊢ ⬇* T → R T.
  97 #L #R #H0 #T1 #H @(csna_ind … (csn_csna … H)) -T1 #T1 #HT1 #IHT1
  98 @H0 -H0 /2 width=1/ -HT1 /3 width=1/
  99 qed-.