matita/matita/contribs/lambda_delta/basic_2/computation/csn_cprs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/computation/cprs.ma".
  16 include "basic_2/computation/csn.ma".
  17
  18 (* CONTEXT-SENSITIVE STRONGLY NORMALIZING TERMS *****************************)
  19
  20 (* Properties concerning context-sensitive computation on terms *************)
  21
  22 definition csns: lenv → predicate term ≝ λL. SN … (cprs L) (eq …).
  23
  24 interpretation
  25    "context-sensitive strong normalization (term)"
  26    'SNStar L T = (csns L T).
  27
  28 (* Basic eliminators ********************************************************)
  29
  30 lemma csns_ind: ∀L. ∀R:predicate term.
  31                 (∀T1. L ⊢ ⬇** T1 →
  32                       (∀T2. L ⊢ T1 ➡* T2 → (T1 = T2 → False) → R T2) → R T1
  33                 ) →
  34                 ∀T. L ⊢ ⬇** T → R T.
  35 #L #R #H0 #T1 #H elim H -T1 #T1 #HT1 #IHT1
  36 @H0 -H0 /3 width=1/ -IHT1 /4 width=1/
  37 qed-.
  38
  39 (* Basic properties *********************************************************)
  40
  41 (* Basic_1: was: sn3_intro *)
  42 lemma csns_intro: ∀L,T1.
  43                   (∀T2. L ⊢ T1 ➡* T2 → (T1 = T2 → False) → L ⊢ ⬇** T2) → L ⊢ ⬇** T1.
  44 #L #T1 #H
  45 @(SN_intro … H)
  46 qed.
  47
  48 fact csns_intro_aux: ∀L,T1.
  49                      (∀T,T2. L ⊢ T ➡* T2 → T1 = T → (T1 = T2 → False) → L ⊢ ⬇** T2) → L ⊢ ⬇** T1.
  50 /4 width=3/ qed-.
  51
  52 (* Basic_1: was: sn3_pr3_trans (old version) *)
  53 lemma csns_cprs_trans: ∀L,T1. L ⊢ ⬇** T1 → ∀T2. L ⊢ T1 ➡* T2 → L ⊢ ⬇** T2.
  54 #L #T1 #H elim H -T1 #T1 #HT1 #IHT1 #T2 #HLT12
  55 @csns_intro #T #HLT2 #HT2
  56 elim (term_eq_dec T1 T2) #HT12
  57 [ -IHT1 -HLT12 destruct /3 width=1/
  58 | -HT1 -HT2 /3 width=4/
  59 qed.
  60
  61 (* Basic_1: was: sn3_pr2_intro (old version) *)
  62 lemma csns_intro_cpr: ∀L,T1.
  63                       (∀T2. L ⊢ T1 ➡ T2 → (T1 = T2 → False) → L ⊢ ⬇** T2) →
  64                       L ⊢ ⬇** T1.
  65 #L #T1 #H
  66 @csns_intro_aux #T #T2 #H @(cprs_ind_dx … H) -T
  67 [ -H #H destruct #H
  68   elim (H ?) //
  69 | #T0 #T #HLT1 #HLT2 #IHT #HT10 #HT12 destruct
  70   elim (term_eq_dec T0 T) #HT0
  71   [ -HLT1 -HLT2 -H /3 width=1/
  72   | -IHT -HT12 /4 width=3/
  73   ]
  74 ]
  75 qed.
  76
  77 (* Main properties **********************************************************)
  78
  79 theorem csn_csns: ∀L,T. L ⊢ ⬇* T → L ⊢ ⬇** T.
  80 #L #T #H @(csn_ind … H) -T /4 width=1/
  81 qed.
  82
  83 theorem csns_csn: ∀L,T. L ⊢ ⬇** T → L ⊢ ⬇* T.
  84 #L #T #H @(csns_ind … H) -T /4 width=1/
  85 qed.
  86
  87 (* Basic_1: was: sn3_pr3_trans *)
  88 lemma csn_cprs_trans: ∀L,T1. L ⊢ ⬇* T1 → ∀T2. L ⊢ T1 ➡* T2 → L ⊢ ⬇* T2.
  89 /4 width=3/ qed.
  90
  91 (* Main eliminators *********************************************************)
  92
  93 lemma csn_ind_cprs: ∀L. ∀R:predicate term.
  94                     (∀T1. L ⊢ ⬇* T1 →
  95                           (∀T2. L ⊢ T1 ➡* T2 → (T1 = T2 → False) → R T2) → R T1
  96                     ) →
  97                     ∀T. L ⊢ ⬇* T → R T.
  98 #L #R #H0 #T1 #H @(csns_ind … (csn_csns … H)) -T1 #T1 #HT1 #IHT1
  99 @H0 -H0 /2 width=1/ -HT1 /3 width=1/
 100 qed-.