matita/matita/contribs/lambda_delta/basic_2/computation/csn_lcpr.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/grammar/tstc_tstc.ma".
  16 include "basic_2/computation/cprs_cprs.ma".
  17 include "basic_2/computation/csn_lift.ma".
  18 include "basic_2/computation/csn_cpr.ma".
  19 include "basic_2/computation/csn_alt.ma".
  20
  21 (* CONTEXT-SENSITIVE STRONGLY NORMALIZING TERMS *****************************)
  22
  23 (* Advanced properties ******************************************************)
  24
  25 lemma csn_lcpr_conf: ∀L1,L2. L1 ⊢ ➡ L2 → ∀T. L1 ⊢ ⬇* T → L2 ⊢ ⬇* T.
  26 #L1 #L2 #HL12 #T #H @(csn_ind_alt … H) -T #T #_ #IHT
  27 @csn_intro #T0 #HLT0 #HT0
  28 @IHT /2 width=2/ -IHT -HT0 /2 width=3/
  29 qed.
  30
  31 lemma csn_abbr: ∀L,V. L ⊢ ⬇* V → ∀T. L. ⓓV ⊢ ⬇* T → L ⊢ ⬇* ⓓV. T.
  32 #L #V #HV elim HV -V #V #_ #IHV #T #HT @(csn_ind_alt … HT) -T #T #HT #IHT
  33 @csn_intro #X #H1 #H2
  34 elim (cpr_inv_abbr1 … H1) -H1 *
  35 [ #V0 #V1 #T1 #HLV0 #HLV01 #HLT1 #H destruct
  36   lapply (cpr_intro … HLV0 HLV01) -HLV01 #HLV1
  37   lapply (ltpr_cpr_trans (L. ⓓV) … HLT1) /2 width=1/ -V0 #HLT1
  38   elim (eq_false_inv_tpair_sn … H2) -H2
  39   [ #HV1 @IHV // /2 width=1/ -HV1
  40     @(csn_lcpr_conf (L. ⓓV)) /2 width=1/ -HLV1 /2 width=3/
  41   | -IHV -HLV1 * #H destruct /3 width=1/
  42   ]
  43 | -IHV -IHT -H2 #T0 #HT0 #HLT0
  44   lapply (csn_inv_lift … HT … HT0) -HT /2 width=3/
  45 ]
  46 qed.
  47
  48 fact csn_appl_beta_aux: ∀L,W. L ⊢ ⬇* W → ∀U. L ⊢ ⬇* U →
  49                         ∀V,T. U = ⓓV. T → L ⊢ ⬇* ⓐV. ⓛW. T.
  50 #L #W #H elim H -W #W #_ #IHW #X #H @(csn_ind_alt … H) -X #X #HVT #IHVT #V #T #H destruct
  51 lapply (csn_fwd_pair_sn … HVT) #HV
  52 lapply (csn_fwd_bind_dx … HVT) #HT -HVT
  53 @csn_intro #X #H #H2
  54 elim (cpr_inv_appl1 … H) -H *
  55 [ #V0 #Y #HLV0 #H #H0 destruct
  56   elim (cpr_inv_abst1 … H Abbr V) -H #W0 #T0 #HLW0 #HLT0 #H destruct
  57   elim (eq_false_inv_beta … H2) -H2
  58   [ -IHVT #HW0 @IHW -IHW [1,5: // |3: skip ] -HLW0 /2 width=1/ -HW0
  59     @csn_abbr /2 width=3/ -HV
  60     @(csn_lcpr_conf (L. ⓓV)) /2 width=1/ -V0 /2 width=3/
  61   | -IHW -HLW0 -HV -HT * #H #HVT0 destruct
  62     @(IHVT … HVT0) -IHVT -HVT0 // /2 width=1/
  63   ]
  64 | -IHW -IHVT -H2 #V0 #W0 #T0 #T1 #HLV0 #HLT01 #H1 #H2 destruct
  65   lapply (lcpr_cpr_trans (L. ⓓV) … HLT01) -HLT01 /2 width=1/ #HLT01
  66   @csn_abbr /2 width=3/ -HV
  67   @(csn_lcpr_conf (L. ⓓV)) /2 width=1/ -V0 /2 width=3/
  68 | -IHW -IHVT -HV -HT -H2 #V0 #V1 #W0 #W1 #T0 #T1 #_ #_ #_ #_ #H destruct
  69 ]
  70 qed.
  71
  72 (* Basic_1: was: sn3_beta *)
  73 lemma csn_appl_beta: ∀L,W. L ⊢ ⬇* W → ∀V,T. L ⊢ ⬇* ⓓV. T →
  74                      L ⊢ ⬇* ⓐV. ⓛW. T.
  75 /2 width=3/ qed.
  76
  77 fact csn_appl_theta_aux: ∀L,U. L ⊢ ⬇* U → ∀V1,V2. ⇧[0, 1] V1 ≡ V2 →
  78                          ∀V,T. U = ⓓV. ⓐV2. T → L ⊢ ⬇* ⓐV1. ⓓV. T.
  79 #L #X #H @(csn_ind_alt … H) -X #X #HVT #IHVT #V1 #V2 #HV12 #V #T #H destruct
  80 lapply (csn_fwd_pair_sn … HVT) #HV
  81 lapply (csn_fwd_bind_dx … HVT) -HVT #HVT
  82 @csn_intro #X #HL #H
  83 elim (cpr_inv_appl1 … HL) -HL *
  84 [ -HV #V0 #Y #HLV10 #HL #H0 destruct
  85   elim (cpr_inv_abbr1 … HL) -HL *
  86   [ #V3 #V4 #T3 #HV3 #HLV34 #HLT3 #H0 destruct
  87     lapply (cpr_intro … HV3 HLV34) -HLV34 #HLV34
  88     elim (lift_total V0 0 1) #V5 #HV05
  89     elim (term_eq_dec (ⓓV.ⓐV2.T) (ⓓV4.ⓐV5.T3))
  90     [ -IHVT #H0 destruct
  91       elim (eq_false_inv_tpair_sn … H) -H
  92       [ -HLV10 -HLV34 -HV3 -HLT3 -HVT
  93         >(lift_inj … HV12 … HV05) -V5
  94         #H elim (H ?) //
  95       | * #_ #H elim (H ?) //
  96       ]
  97     | -H -HVT #H
  98       lapply (cpr_lift (L. ⓓV) … HV12 … HV05 HLV10) -HLV10 -HV12 /2 width=1/ #HV25
  99       lapply (ltpr_cpr_trans (L. ⓓV) … HLT3) /2 width=1/ -HLT3 #HLT3
 100       @(IHVT … H … HV05) -IHVT // -H -HV05 /3 width=1/
 101     ]
 102   | -H -IHVT #T0 #HT0 #HLT0
 103     @(csn_cpr_trans … (ⓐV1.T0)) /2 width=1/ -V0 -Y
 104     @(csn_inv_lift … 0 1 HVT) /2 width=1/
 105   ]
 106 | -HV -HV12 -HVT -IHVT -H #V0 #W0 #T0 #T1 #_ #_ #H destruct
 107 | -IHVT -H #V0 #V3 #W0 #W1 #T0 #T1 #HLV10 #HLW01 #HLT01 #HV03 #H1 #H2 destruct
 108   lapply (cpr_lift (L. ⓓW0) … HV12 … HV03 HLV10) -HLV10 -HV12 -HV03 /2 width=1/ #HLV23
 109   lapply (lcpr_cpr_trans (L. ⓓW0) … HLT01) -HLT01 /2 width=1/ #HLT01
 110   @csn_abbr /2 width=3/ -HV
 111   @(csn_lcpr_conf (L. ⓓW0)) /2 width=1/ -W1
 112   @(csn_cprs_trans … HVT) -HVT /2 width=1/
 113 ]
 114 qed.
 115
 116 lemma csn_appl_theta: ∀V1,V2. ⇧[0, 1] V1 ≡ V2 →
 117                       ∀L,V,T. L ⊢ ⬇* ⓓV. ⓐV2. T → L ⊢ ⬇* ⓐV1. ⓓV. T.
 118 /2 width=5/ qed.
 119
 120 (* Basic_1: was only: sn3_appl_appl *)
 121 lemma csn_appl_simple_tstc: ∀L,V. L ⊢ ⬇* V → ∀T1.
 122                             L ⊢ ⬇* T1 →
 123                             (∀T2. L ⊢ T1 ➡* T2 → (T1 ≃ T2 → False) → L ⊢ ⬇* ⓐV. T2) →
 124                             𝐒[T1] → L ⊢ ⬇* ⓐV. T1.
 125 #L #V #H @(csn_ind … H) -V #V #_ #IHV #T1 #H @(csn_ind … H) -T1 #T1 #H1T1 #IHT1 #H2T1 #H3T1
 126 @csn_intro #X #HL #H
 127 elim (cpr_inv_appl1_simple … HL ?) -HL //
 128 #V0 #T0 #HLV0 #HLT10 #H0 destruct
 129 elim (eq_false_inv_tpair_sn … H) -H
 130 [ -IHT1 #HV0
 131   @(csn_cpr_trans … (ⓐV0.T1)) /2 width=1/ -HLT10
 132   @IHV -IHV // -H1T1 -H3T1 /2 width=1/ -HV0
 133   #T2 #HLT12 #HT12
 134   @(csn_cpr_trans … (ⓐV.T2)) /2 width=1/ -HLV0
 135   @H2T1 -H2T1 // -HLT12 /2 width=1/
 136 | -IHV -H1T1 -HLV0 * #H #H1T10 destruct
 137   elim (tstc_dec T1 T0) #H2T10
 138   [ @IHT1 -IHT1 // /2 width=1/ -H1T10 /2 width=3/ -H3T1
 139     #T2 #HLT02 #HT02
 140     @H2T1 -H2T1 /2 width=3/ -HLT10 -HLT02 /3 width=3/
 141   | -IHT1 -H3T1 -H1T10
 142     @H2T1 -H2T1 /2 width=1/
 143   ]
 144 ]
 145 qed.