matita/matita/contribs/lambda_delta/basic_2/computation/xprs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/reducibility/xpr.ma".
  16 (*
  17 include "basic_2/reducibility/cnf.ma".
  18 *)
  19 (* EXTENDED PARALLEL COMPUTATION ON TERMS ***********************************)
  20
  21 definition xprs: ∀h. sd h → lenv → relation term ≝
  22                  λh,g,L. TC … (xpr h g L).
  23
  24 interpretation "extended parallel computation (term)"
  25    'XPRedStar h g L T1 T2 = (xprs h g L T1 T2).
  26
  27 (* Basic eliminators ********************************************************)
  28
  29 lemma xprs_ind: ∀h,g,L,T1. ∀R:predicate term. R T1 →
  30                 (∀T,T2. ⦃h, L⦄ ⊢ T1 •➡*[g] T → ⦃h, L⦄ ⊢ T •➡[g] T2 → R T → R T2) →
  31                 ∀T2. ⦃h, L⦄ ⊢ T1 •➡*[g] T2 → R T2.
  32 #h #g #L #T1 #R #HT1 #IHT1 #T2 #HT12
  33 @(TC_star_ind … HT1 IHT1 … HT12) //
  34 qed-.
  35
  36 lemma xprs_ind_dx: ∀h,g,L,T2. ∀R:predicate term. R T2 →
  37                    (∀T1,T. ⦃h, L⦄ ⊢ T1 •➡[g] T → ⦃h, L⦄ ⊢ T •➡*[g] T2 → R T → R T1) →
  38                    ∀T1. ⦃h, L⦄ ⊢ T1 •➡*[g] T2 → R T1.
  39 #h #g #L #T2 #R #HT2 #IHT2 #T1 #HT12
  40 @(TC_star_ind_dx … HT2 IHT2 … HT12) //
  41 qed-.
  42
  43 (* Basic properties *********************************************************)
  44
  45 lemma xprs_refl: ∀h,g,L. reflexive … (xprs h g L).
  46 /2 width=1/ qed.
  47
  48 lemma xprs_strap1: ∀h,g,L,T1,T,T2.
  49                    ⦃h, L⦄ ⊢ T1 •➡*[g] T → ⦃h, L⦄ ⊢ T •➡[g] T2 → ⦃h, L⦄ ⊢ T1 •➡*[g] T2.
  50 /2 width=3/ qed.
  51
  52 lemma xprs_strap2: ∀h,g,L,T1,T,T2.
  53                    ⦃h, L⦄ ⊢ T1 •➡[g] T → ⦃h, L⦄ ⊢ T •➡*[g] T2 → ⦃h, L⦄ ⊢ T1 •➡*[g] T2.
  54 /2 width=3/ qed.
  55
  56 (* Basic inversion lemmas ***************************************************)
  57 (*
  58 axiom xprs_inv_cnf1: ∀L,T,U. L ⊢ T ➡* U → L ⊢ 𝐍⦃T⦄ → T = U.
  59 #L #T #U #H @(xprs_ind_dx … H) -T //
  60 #T0 #T #H1T0 #_ #IHT #H2T0
  61 lapply (H2T0 … H1T0) -H1T0 #H destruct /2 width=1/
  62 qed-.
  63 *)