matita/matita/contribs/lambda_delta/basic_2/equivalence/cpcs_ltpss.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/unfold/ltpss_ltpss.ma".
  16 include "basic_2/equivalence/cpcs_cpcs.ma".
  17
  18 (* CONTEXT-SENSITIVE PARALLEL EQUIVALENCE ON TERMS **************************)
  19
  20 (* Properties concerning partial unfold on local environments ***************)
  21
  22 lemma ltpss_cpr_conf: ∀L1,L2,d,e. L1 ▶* [d, e] L2 →
  23                       ∀T1,T2. L1 ⊢ T1 ➡ T2 → L2 ⊢ T1 ⬌* T2.
  24 #L1 #L2 #d #e #HL12 #T1 #T2 *
  25 lapply (ltpss_weak_all … HL12)
  26 >(ltpss_fwd_length … HL12) -HL12 #HL12 #T #HT1 #HT2
  27 elim (ltpss_tpss_conf … HT2 … HL12) -L1 #T0 #HT0 #HT20
  28 @(cprs_div … T0) /3 width=3/ (**) (* /4/ is too slow *)
  29 qed.
  30
  31 lemma ltpss_cprs_conf: ∀L1,L2,d,e. L1 ▶* [d, e] L2 →
  32                        ∀T1,T2. L1 ⊢ T1 ➡* T2 → L2 ⊢ T1 ⬌* T2.
  33 #L1 #L2 #d #e #HL12 #T1 #T2 #H @(cprs_ind … H) -T2 //
  34 #T #T2 #_ #HT2 #IHT1
  35 @(cpcs_trans … IHT1) -T1 /2 width=5/
  36 qed.
  37
  38 lemma ltpss_cpcs_conf: ∀L1,L2,d,e. L1 ▶* [d, e] L2 →
  39                        ∀T1,T2. L1 ⊢ T1 ⬌* T2 → L2 ⊢ T1 ⬌* T2.
  40 #L1 #L2 #d #e #HL12 #T1 #T2 #H
  41 elim (cpcs_inv_cprs … H) -H #T #HT1 #HT2
  42 @(cpcs_canc_dx … T) /2 width=5/
  43 qed.