matita/matita/contribs/lambda_delta/basic_2/grammar/lenv_append.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/grammar/lenv_length.ma".
  16
  17 (* LOCAL ENVIRONMENTS *******************************************************)
  18
  19 let rec append L K on K ≝ match K with
  20 [ LAtom       ⇒ L
  21 | LPair K I V ⇒ (append L K). ⓑ{I} V
  22 ].
  23
  24 interpretation "append (local environment)" 'Append L1 L2 = (append L1 L2).
  25
  26 (* Basic properties *********************************************************)
  27
  28 lemma append_atom_sn: ∀L. ⋆ @@ L = L.
  29 #L elim L -L normalize //
  30 qed.
  31
  32 lemma append_assoc: associative … append.
  33 #L1 #L2 #L3 elim L3 -L3 normalize //
  34 qed.
  35
  36 lemma append_length: ∀L1,L2. |L1 @@ L2| = |L1| + |L2|.
  37 #L1 #L2 elim L2 -L2 normalize //
  38 qed.
  39
  40 (* Basic inversion lemmas ***************************************************)
  41
  42 lemma append_inj_sn: ∀K1,K2,L1,L2. L1 @@ K1 = L2 @@ K2 → |K1| = |K2| →
  43                      L1 = L2 ∧ K1 = K2.
  44 #K1 elim K1 -K1
  45 [ * normalize /2 width=1/
  46   #K2 #I2 #V2 #L1 #L2 #_ <plus_n_Sm #H destruct
  47 | #K1 #I1 #V1 #IH * normalize
  48   [ #L1 #L2 #_ <plus_n_Sm #H destruct
  49   | #K2 #I2 #V2 #L1 #L2 #H1 #H2 destruct (**) (* destruct does not simplify well *)
  50     elim (IH … e0 ?) -IH -H1 /2 width=1/ -H2 #H1 #H2 destruct /2 width=1/
  51   ]
  52 ]
  53 qed-.
  54
  55 (* Note: lemma 750 *)
  56 lemma append_inj_dx: ∀K1,K2,L1,L2. L1 @@ K1 = L2 @@ K2 → |L1| = |L2| →
  57                      L1 = L2 ∧ K1 = K2.
  58 #K1 elim K1 -K1
  59 [ * normalize /2 width=1/
  60   #K2 #I2 #V2 #L1 #L2 #H1 #H2 destruct
  61   normalize in H2; >append_length in H2; #H
  62   elim (plus_xySz_x_false … H)
  63 | #K1 #I1 #V1 #IH * normalize
  64   [ #L1 #L2 #H1 #H2 destruct
  65     normalize in H2; >append_length in H2; #H
  66     elim (plus_xySz_x_false … (sym_eq … H))
  67   | #K2 #I2 #V2 #L1 #L2 #H1 #H2 destruct (**) (* destruct does not simplify well *)
  68     elim (IH … e0 ?) -IH -H1 /2 width=1/ -H2 #H1 #H2 destruct /2 width=1/
  69   ]
  70 ]
  71 qed-.
  72
  73 lemma length_inv_pos_dx_append: ∀d,L. |L| = d + 1 →
  74                                 ∃∃I,K,V. |K| = d & L = ⋆.ⓑ{I}V @@ K.
  75 #d @(nat_ind_plus … d) -d
  76 [ #L #H
  77   elim (length_inv_pos_dx … H) -H #I #K #V #H
  78   >(length_inv_zero_dx … H) -H #H destruct
  79   @ex2_3_intro [4: /2 width=2/ |5: // |1,2,3: skip ] (* /3/ does not work *)
  80 | #d #IHd #L #H
  81   elim (length_inv_pos_dx … H) -H #I #K #V #H
  82   elim (IHd … H) -IHd -H #I0 #K0 #V0 #H1 #H2 #H3 destruct
  83   @(ex2_3_intro … (K0.ⓑ{I}V)) //
  84 ]
  85 qed-.
  86
  87 (* Basic_eliminators ********************************************************)
  88
  89 fact lenv_ind_dx_aux: ∀R:predicate lenv. R ⋆ →
  90                       (∀I,L,V. R L → R (⋆.ⓑ{I}V @@ L)) →
  91                       ∀d,L. |L| = d → R L.
  92 #R #Hatom #Hpair #d @(nat_ind_plus … d) -d
  93 [ #L #H >(length_inv_zero_dx … H) -H //
  94 | #d #IH #L #H
  95   elim (length_inv_pos_dx_append … H) -H #I #K #V #H1 #H2 destruct /3 width=1/
  96 ]
  97 qed-.
  98
  99 lemma lenv_ind_dx: ∀R:predicate lenv. R ⋆ →
 100                    (∀I,L,V. R L → R (⋆.ⓑ{I}V @@ L)) →
 101                    ∀L. R L.
 102 /3 width=2 by lenv_ind_dx_aux/ qed-.