matita/matita/contribs/lambda_delta/basic_2/grammar/lenv_append.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/grammar/lenv_length.ma".
  16
  17 (* LOCAL ENVIRONMENTS *******************************************************)
  18
  19 let rec append L K on K ≝ match K with
  20 [ LAtom       ⇒ L
  21 | LPair K I V ⇒ (append L K). ⓑ{I} V
  22 ].
  23
  24 interpretation "append (local environment)" 'Append L1 L2 = (append L1 L2).
  25
  26 (* Basic properties *********************************************************)
  27
  28 lemma append_atom_sn: ∀L. ⋆ @@ L = L.
  29 #L elim L -L normalize //
  30 qed.
  31
  32 lemma append_length: ∀L1,L2. |L1 @@ L2| = |L1| + |L2|.
  33 #L1 #L2 elim L2 -L2 normalize //
  34 qed.
  35
  36 (* Basic inversion lemmas ***************************************************)
  37
  38 lemma append_inj_sn: ∀K1,K2,L1,L2. L1 @@ K1 = L2 @@ K2 → |K1| = |K2| →
  39                      L1 = L2 ∧ K1 = K2.
  40 #K1 elim K1 -K1
  41 [ * normalize /2 width=1/
  42   #K2 #I2 #V2 #L1 #L2 #_ <plus_n_Sm #H destruct
  43 | #K1 #I1 #V1 #IH * normalize
  44   [ #L1 #L2 #_ <plus_n_Sm #H destruct
  45   | #K2 #I2 #V2 #L1 #L2 #H1 #H2 destruct (**) (* destruct does not simplify well *)
  46     elim (IH … e0 ?) -IH -H1 /2 width=1/ -H2 #H1 #H2 destruct /2 width=1/
  47   ]
  48 ]
  49 qed-.
  50
  51 (* Note: lemma 750 *)
  52 lemma append_inj_dx: ∀K1,K2,L1,L2. L1 @@ K1 = L2 @@ K2 → |L1| = |L2| →
  53                      L1 = L2 ∧ K1 = K2.
  54 #K1 elim K1 -K1
  55 [ * normalize /2 width=1/
  56   #K2 #I2 #V2 #L1 #L2 #H1 #H2 destruct
  57   normalize in H2; >append_length in H2; #H
  58   elim (plus_xySz_x_false … H)
  59 | #K1 #I1 #V1 #IH * normalize
  60   [ #L1 #L2 #H1 #H2 destruct
  61     normalize in H2; >append_length in H2; #H
  62     elim (plus_xySz_x_false … (sym_eq … H))
  63   | #K2 #I2 #V2 #L1 #L2 #H1 #H2 destruct (**) (* destruct does not simplify well *)
  64     elim (IH … e0 ?) -IH -H1 /2 width=1/ -H2 #H1 #H2 destruct /2 width=1/
  65   ]
  66 ]
  67 qed-.
  68
  69 lemma length_inv_pos_dx_append: ∀d,L. |L| = d + 1 →
  70                                 ∃∃I,K,V. |K| = d & L = ⋆.ⓑ{I}V @@ K.
  71 #d @(nat_ind_plus … d) -d
  72 [ #L #H
  73   elim (length_inv_pos_dx … H) -H #I #K #V #H
  74   >(length_inv_zero_dx … H) -H #H destruct
  75   @ex2_3_intro [4: /2 width=2/ |5: // |1,2,3: skip ] (* /3/ does not work *)
  76 | #d #IHd #L #H
  77   elim (length_inv_pos_dx … H) -H #I #K #V #H
  78   elim (IHd … H) -IHd -H #I0 #K0 #V0 #H1 #H2 #H3 destruct
  79   @(ex2_3_intro … (K0.ⓑ{I}V)) //
  80 ]
  81 qed-.
  82
  83 (* Basic_eliminators ********************************************************)
  84
  85 fact lenv_ind_dx_aux: ∀R:predicate lenv. R ⋆ →
  86                       (∀I,L,V. R L → R (⋆.ⓑ{I}V @@ L)) →
  87                       ∀d,L. |L| = d → R L.
  88 #R #Hatom #Hpair #d @(nat_ind_plus … d) -d
  89 [ #L #H >(length_inv_zero_dx … H) -H //
  90 | #d #IH #L #H
  91   elim (length_inv_pos_dx_append … H) -H #I #K #V #H1 #H2 destruct /3 width=1/
  92 ]
  93 qed-.
  94
  95 lemma lenv_ind_dx: ∀R:predicate lenv. R ⋆ →
  96                    (∀I,L,V. R L → R (⋆.ⓑ{I}V @@ L)) →
  97                    ∀L. R L.
  98 /3 width=2 by lenv_ind_dx_aux/ qed-.