matita/matita/contribs/lambda_delta/basic_2/reducibility/cpr_lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/unfold/tpss_lift.ma".
  16 include "basic_2/reducibility/tpr_lift.ma".
  17 include "basic_2/reducibility/cpr.ma".
  18
  19 (* CONTEXT-SENSITIVE PARALLEL REDUCTION ON TERMS ****************************)
  20
  21 (* Advanced properties ******************************************************)
  22
  23 lemma cpr_cdelta: ∀L,K,V1,W1,W2,i.
  24                   ⇩[0, i] L ≡ K. ⓓV1 → K ⊢ V1 ▶* [0, |L| - i - 1] W1 →
  25                   ⇧[0, i + 1] W1 ≡ W2 → L ⊢ #i ➡ W2.
  26 #L #K #V1 #W1 #W2 #i #HLK #HVW1 #HW12
  27 lapply (ldrop_fwd_ldrop2_length … HLK) #Hi
  28 @ex2_1_intro [2: // | skip | @tpss_subst /width=6/ ] (**) (* /3 width=6/ is too slow *)
  29 qed.
  30
  31 lemma cpr_abst: ∀L,V1,V2. L ⊢ V1 ➡ V2 → ∀V,T1,T2.
  32                 L.ⓛV ⊢ T1 ➡ T2 → L ⊢ ⓛV1. T1 ➡ ⓛV2. T2.
  33 #L #V1 #V2 * #V0 #HV10 #HV02 #V #T1 #T2 * #T0 #HT10 #HT02
  34 lapply (tpss_inv_S2 … HT02 L V ?) -HT02 // #HT02
  35 @(ex2_1_intro … (ⓛV0.T0)) /2 width=1/ -V1 -T1 (**) (* explicit constructors *)
  36 @tpss_bind // -V0
  37 @(tpss_lsubs_trans (L.ⓛV)) // -T0 -T2 /2 width=1/
  38 qed.
  39
  40 (* Advanced inversion lemmas ************************************************)
  41
  42 (* Basic_1: was: pr2_gen_lref *)
  43 lemma cpr_inv_lref1: ∀L,T2,i. L ⊢ #i ➡ T2 →
  44                      T2 = #i ∨
  45                      ∃∃K,V1,T1. ⇩[0, i] L ≡ K. ⓓV1 &
  46                                 K ⊢ V1 ▶* [0, |L| - i - 1] T1 &
  47                                 ⇧[0, i + 1] T1 ≡ T2 &
  48                                 i < |L|.
  49 #L #T2 #i * #X #H
  50 >(tpr_inv_atom1 … H) -H #H
  51 elim (tpss_inv_lref1 … H) -H /2 width=1/
  52 * /3 width=6/
  53 qed-.
  54
  55 (* Basic_1: was: pr2_gen_abst *)
  56 lemma cpr_inv_abst1: ∀L,V1,T1,U2. L ⊢ ⓛV1. T1 ➡ U2 → ∀I,W.
  57                      ∃∃V2,T2. L ⊢ V1 ➡ V2 & L. ⓑ{I} W ⊢ T1 ➡ T2 & U2 = ⓛV2. T2.
  58 #L #V1 #T1 #Y * #X #H1 #H2 #I #W
  59 elim (tpr_inv_abst1 … H1) -H1 #V #T #HV1 #HT1 #H destruct
  60 elim (tpss_inv_bind1 … H2) -H2 #V2 #T2 #HV2 #HT2 #H destruct
  61 lapply (tpss_lsubs_trans … HT2 (L. ⓑ{I} W) ?) -HT2 /2 width=1/ /4 width=5/
  62 qed-.
  63
  64 (* Basic_1: was pr2_gen_appl *)
  65 lemma cpr_inv_appl1: ∀L,V1,U0,U2. L ⊢ ⓐV1. U0 ➡ U2 →
  66                      ∨∨ ∃∃V2,T2.            L ⊢ V1 ➡ V2 & L ⊢ U0 ➡ T2 &
  67                                             U2 = ⓐV2. T2
  68                       | ∃∃V2,W,T1,T2.       L ⊢ V1 ➡ V2 & L. ⓓV2 ⊢ T1 ➡ T2 &
  69                                             U0 = ⓛW. T1 &
  70                                             U2 = ⓓV2. T2
  71                       | ∃∃V2,V,W1,W2,T1,T2. L ⊢ V1 ➡ V2 & L ⊢ W1 ➡ W2 & L. ⓓW2 ⊢ T1 ➡ T2 &
  72                                             ⇧[0,1] V2 ≡ V &
  73                                             U0 = ⓓW1. T1 &
  74                                             U2 = ⓓW2. ⓐV. T2.
  75 #L #V1 #U0 #Y * #X #H1 #H2
  76 elim (tpr_inv_appl1 … H1) -H1 *
  77 [ #V #U #HV1 #HU0 #H destruct
  78   elim (tpss_inv_flat1 … H2) -H2 #V2 #U2 #HV2 #HU2 #H destruct /4 width=5/
  79 | #V #W #T0 #T #HV1 #HT0 #H #H1 destruct
  80   elim (tpss_inv_bind1 … H2) -H2 #V2 #T2 #HV2 #HT2 #H destruct
  81   lapply (tpss_weak … HT2 0 (|L|+1) ? ?) -HT2 // /4 width=8/
  82 | #V0 #V #W #W0 #T #T0 #HV10 #HW0 #HT0 #HV0 #H #H1 destruct
  83   elim (tpss_inv_bind1 … H2) -H2 #W2 #X #HW02 #HX #HY destruct
  84   elim (tpss_inv_flat1 … HX) -HX #V2 #T2 #HV2 #HT2 #H destruct
  85   elim (tpss_inv_lift1_ge … HV2 … HV0 ?) -V // [3: /2 width=1/ |2: skip ] #V <minus_plus_m_m
  86   lapply (tpss_weak … HT2 0 (|L|+1) ? ?) -HT2 // /4 width=12/
  87 ]
  88 qed-.
  89
  90 (* Note: the main property of simple terms *)
  91 lemma cpr_inv_appl1_simple: ∀L,V1,T1,U. L ⊢ ⓐV1. T1 ➡ U → 𝐒⦃T1⦄ →
  92                             ∃∃V2,T2. L ⊢ V1 ➡ V2 & L ⊢ T1 ➡ T2 &
  93                                      U = ⓐV2. T2.
  94 #L #V1 #T1 #U #H #HT1
  95 elim (cpr_inv_appl1 … H) -H *
  96 [ /2 width=5/
  97 | #V2 #W #W1 #W2 #_ #_ #H #_ destruct
  98   elim (simple_inv_bind … HT1)
  99 | #V2 #V #W1 #W2 #U1 #U2 #_ #_ #_ #_ #H #_ destruct
 100   elim (simple_inv_bind … HT1)
 101 ]
 102 qed-.
 103
 104 (* Relocation properties ****************************************************)
 105
 106 (* Basic_1: was: pr2_lift *)
 107 lemma cpr_lift: ∀L,K,d,e. ⇩[d, e] L ≡ K →
 108                 ∀T1,U1. ⇧[d, e] T1 ≡ U1 → ∀T2,U2. ⇧[d, e] T2 ≡ U2 →
 109                 K ⊢ T1 ➡ T2 → L ⊢ U1 ➡ U2.
 110 #L #K #d #e #HLK #T1 #U1 #HTU1 #T2 #U2 #HTU2 * #T #HT1 #HT2
 111 elim (lift_total T d e) #U #HTU
 112 lapply (tpr_lift … HT1 … HTU1 … HTU) -T1 #HU1
 113 elim (lt_or_ge (|K|) d) #HKd
 114 [ lapply (tpss_lift_le … HT2 … HLK HTU … HTU2) -T2 -T -HLK [ /2 width=2/ | /3 width=4/ ]
 115 | lapply (tpss_lift_be … HT2 … HLK HTU … HTU2) -T2 -T -HLK // /3 width=4/
 116 ]
 117 qed.
 118
 119 (* Basic_1: was: pr2_gen_lift *)
 120 lemma cpr_inv_lift: ∀L,K,d,e. ⇩[d, e] L ≡ K →
 121                     ∀T1,U1. ⇧[d, e] T1 ≡ U1 → ∀U2. L ⊢ U1 ➡ U2 →
 122                     ∃∃T2. ⇧[d, e] T2 ≡ U2 & K ⊢ T1 ➡ T2.
 123 #L #K #d #e #HLK #T1 #U1 #HTU1 #U2 * #U #HU1 #HU2
 124 elim (tpr_inv_lift … HU1 … HTU1) -U1 #T #HTU #T1
 125 elim (lt_or_ge (|L|) d) #HLd
 126 [ elim (tpss_inv_lift1_le … HU2 … HLK … HTU ?) -U -HLK [ /5 width=4/ | /2 width=2/ ]
 127 | elim (lt_or_ge (|L|) (d + e)) #HLde
 128   [ elim (tpss_inv_lift1_be_up … HU2 … HLK … HTU ? ?) -U -HLK // [ /5 width=4/ | /2 width=2/ ]
 129   | elim (tpss_inv_lift1_be … HU2 … HLK … HTU ? ?) -U -HLK // /5 width=4/
 130   ]
 131 ]
 132 qed.