matita/matita/contribs/lambda_delta/basic_2/reducibility/ltpr_ldrop.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic_2/reducibility/tpr_lift.ma".
  16 include "Basic_2/reducibility/ltpr.ma".
  17
  18 (* CONTEXT-FREE PARALLEL REDUCTION ON LOCAL ENVIRONMENTS ********************)
  19
  20 (* Basic_1: was: wcpr0_drop *)
  21 lemma ltpr_ldrop_conf: ∀L1,K1,d,e. ⇩[d, e] L1 ≡ K1 → ∀L2. L1 ➡ L2 →
  22                        ∃∃K2. ⇩[d, e] L2 ≡ K2 & K1 ➡ K2.
  23 #L1 #K1 #d #e #H elim H -L1 -K1 -d -e
  24 [ #d #e #X #H >(ltpr_inv_atom1 … H) -H /2 width=3/
  25 | #K1 #I #V1 #X #H
  26   elim (ltpr_inv_pair1 … H) -H #L2 #V2 #HL12 #HV12 #H destruct /3 width=5/
  27 | #L1 #K1 #I #V1 #e #_ #IHLK1 #X #H
  28   elim (ltpr_inv_pair1 … H) -H #L2 #V2 #HL12 #HV12 #H destruct
  29   elim (IHLK1 … HL12) -L1 /3 width=3/
  30 | #L1 #K1 #I #V1 #W1 #d #e #_ #HWV1 #IHLK1 #X #H
  31   elim (ltpr_inv_pair1 … H) -H #L2 #V2 #HL12 #HV12 #H destruct
  32   elim (tpr_inv_lift … HV12 … HWV1) -V1
  33   elim (IHLK1 … HL12) -L1 /3 width=5/
  34 ]
  35 qed.
  36
  37 (* Basic_1: was: wcpr0_drop_back *)
  38 lemma ldrop_ltpr_trans: ∀L1,K1,d,e. ⇩[d, e] L1 ≡ K1 → ∀K2. K1 ➡ K2 →
  39                         ∃∃L2. ⇩[d, e] L2 ≡ K2 & L1 ➡ L2.
  40 #L1 #K1 #d #e #H elim H -L1 -K1 -d -e
  41 [ #d #e #X #H >(ltpr_inv_atom1 … H) -H /2 width=3/
  42 | #K1 #I #V1 #X #H
  43   elim (ltpr_inv_pair1 … H) -H #K2 #V2 #HK12 #HV12 #H destruct /3 width=5/
  44 | #L1 #K1 #I #V1 #e #_ #IHLK1 #K2 #HK12
  45   elim (IHLK1 … HK12) -K1 /3 width=5/
  46 | #L1 #K1 #I #V1 #W1 #d #e #_ #HWV1 #IHLK1 #X #H
  47   elim (ltpr_inv_pair1 … H) -H #K2 #W2 #HK12 #HW12 #H destruct
  48   elim (lift_total W2 d e) #V2 #HWV2
  49   lapply (tpr_lift … HW12 … HWV1 … HWV2) -W1
  50   elim (IHLK1 … HK12) -K1 /3 width=5/
  51 ]
  52 qed.
  53
  54 fact ltpr_ldrop_trans_O1_aux: ∀L2,K2,d,e. ⇩[d, e] L2 ≡ K2 → ∀L1. L1 ➡ L2 →
  55                               d = 0 → ∃∃K1. ⇩[0, e] L1 ≡ K1 & K1 ➡ K2.
  56 #L2 #K2 #d #e #H elim H -L2 -K2 -d -e
  57 [ #d #e #X #H >(ltpr_inv_atom2 … H) -H /2 width=3/
  58 | #K2 #I #V2 #X #H
  59   elim (ltpr_inv_pair2 … H) -H #K1 #V1 #HK12 #HV12 #H destruct /3 width=5/
  60 | #L2 #K2 #I #V2 #e #_ #IHLK2 #X #H #_
  61   elim (ltpr_inv_pair2 … H) -H #L1 #V1 #HL12 #HV12 #H destruct
  62   elim (IHLK2 … HL12 ?) -L2 // /3 width=3/
  63 | #L2 #K2 #I #V2 #W2 #d #e #_ #_ #_ #L1 #_
  64   >commutative_plus normalize #H destruct
  65 ]
  66 qed.
  67
  68 lemma ltpr_ldrop_trans_O1: ∀L1,L2. L1 ➡ L2 → ∀K2,e. ⇩[0, e] L2 ≡ K2 →
  69                            ∃∃K1. ⇩[0, e] L1 ≡ K1 & K1 ➡ K2.
  70 /2 width=5/ qed.