matita/matita/contribs/lambda_delta/basic_2/substitution/tps.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/grammar/lenv_top.ma".
  16 include "basic_2/substitution/ldrop.ma".
  17
  18 (* PARALLEL SUBSTITUTION ON TERMS *******************************************)
  19
  20 inductive tps: nat → nat → lenv → relation term ≝
  21 | tps_atom : ∀L,I,d,e. tps d e L (⓪{I}) (⓪{I})
  22 | tps_subst: ∀L,K,V,W,i,d,e. d ≤ i → i < d + e →
  23              ⇩[0, i] L ≡ K. ⓓV → ⇧[0, i + 1] V ≡ W → tps d e L (#i) W
  24 | tps_bind : ∀L,a,I,V1,V2,T1,T2,d,e.
  25              tps d e L V1 V2 → tps (d + 1) e (L. ⓑ{I} V2) T1 T2 →
  26              tps d e L (ⓑ{a,I} V1. T1) (ⓑ{a,I} V2. T2)
  27 | tps_flat : ∀L,I,V1,V2,T1,T2,d,e.
  28              tps d e L V1 V2 → tps d e L T1 T2 →
  29              tps d e L (ⓕ{I} V1. T1) (ⓕ{I} V2. T2)
  30 .
  31
  32 interpretation "parallel substritution (term)"
  33    'PSubst L T1 d e T2 = (tps d e L T1 T2).
  34
  35 (* Basic properties *********************************************************)
  36
  37 lemma tps_lsubs_trans: ∀L1,T1,T2,d,e. L1 ⊢ T1 ▶ [d, e] T2 →
  38                        ∀L2. L2 ≼ [d, e] L1 → L2 ⊢ T1 ▶ [d, e] T2.
  39 #L1 #T1 #T2 #d #e #H elim H -L1 -T1 -T2 -d -e
  40 [ //
  41 | #L1 #K1 #V #W #i #d #e #Hdi #Hide #HLK1 #HVW #L2 #HL12
  42   elim (ldrop_lsubs_ldrop2_abbr … HL12 … HLK1 ? ?) -HL12 -HLK1 // /2 width=4/
  43 | /4 width=1/
  44 | /3 width=1/
  45 ]
  46 qed.
  47
  48 lemma tps_refl: ∀T,L,d,e. L ⊢ T ▶ [d, e] T.
  49 #T elim T -T //
  50 #I elim I -I /2 width=1/
  51 qed.
  52
  53 (* Basic_1: was: subst1_ex *)
  54 lemma tps_full: ∀K,V,T1,L,d. ⇩[0, d] L ≡ (K. ⓓV) →
  55                 ∃∃T2,T. L ⊢ T1 ▶ [d, 1] T2 & ⇧[d, 1] T ≡ T2.
  56 #K #V #T1 elim T1 -T1
  57 [ * #i #L #d #HLK /2 width=4/
  58   elim (lt_or_eq_or_gt i d) #Hid /3 width=4/
  59   destruct
  60   elim (lift_total V 0 (i+1)) #W #HVW
  61   elim (lift_split … HVW i i ? ? ?) // /3 width=4/
  62 | * [ #a ] #I #W1 #U1 #IHW1 #IHU1 #L #d #HLK
  63   elim (IHW1 … HLK) -IHW1 #W2 #W #HW12 #HW2
  64   [ elim (IHU1 (L. ⓑ{I} W2) (d+1) ?) -IHU1 /2 width=1/ -HLK /3 width=9/
  65   | elim (IHU1 … HLK) -IHU1 -HLK /3 width=8/
  66   ]
  67 ]
  68 qed.
  69
  70 lemma tps_weak: ∀L,T1,T2,d1,e1. L ⊢ T1 ▶ [d1, e1] T2 →
  71                 ∀d2,e2. d2 ≤ d1 → d1 + e1 ≤ d2 + e2 →
  72                 L ⊢ T1 ▶ [d2, e2] T2.
  73 #L #T1 #T2 #d1 #e1 #H elim H -L -T1 -T2 -d1 -e1
  74 [ //
  75 | #L #K #V #W #i #d1 #e1 #Hid1 #Hide1 #HLK #HVW #d2 #e2 #Hd12 #Hde12
  76   lapply (transitive_le … Hd12 … Hid1) -Hd12 -Hid1 #Hid2
  77   lapply (lt_to_le_to_lt … Hide1 … Hde12) -Hide1 /2 width=4/
  78 | /4 width=3/
  79 | /4 width=1/
  80 ]
  81 qed.
  82
  83 lemma tps_weak_top: ∀L,T1,T2,d,e.
  84                     L ⊢ T1 ▶ [d, e] T2 → L ⊢ T1 ▶ [d, |L| - d] T2.
  85 #L #T1 #T2 #d #e #H elim H -L -T1 -T2 -d -e
  86 [ //
  87 | #L #K #V #W #i #d #e #Hdi #_ #HLK #HVW
  88   lapply (ldrop_fwd_ldrop2_length … HLK) #Hi
  89   lapply (le_to_lt_to_lt … Hdi Hi) /3 width=4/
  90 | normalize /2 width=1/
  91 | /2 width=1/
  92 ]
  93 qed.
  94
  95 lemma tps_weak_all: ∀L,T1,T2,d,e.
  96                     L ⊢ T1 ▶ [d, e] T2 → L ⊢ T1 ▶ [0, |L|] T2.
  97 #L #T1 #T2 #d #e #HT12
  98 lapply (tps_weak … HT12 0 (d + e) ? ?) -HT12 // #HT12
  99 lapply (tps_weak_top … HT12) //
 100 qed.
 101
 102 lemma tps_split_up: ∀L,T1,T2,d,e. L ⊢ T1 ▶ [d, e] T2 → ∀i. d ≤ i → i ≤ d + e →
 103                     ∃∃T. L ⊢ T1 ▶ [d, i - d] T & L ⊢ T ▶ [i, d + e - i] T2.
 104 #L #T1 #T2 #d #e #H elim H -L -T1 -T2 -d -e
 105 [ /2 width=3/
 106 | #L #K #V #W #i #d #e #Hdi #Hide #HLK #HVW #j #Hdj #Hjde
 107   elim (lt_or_ge i j)
 108   [ -Hide -Hjde
 109     >(plus_minus_m_m j d) in ⊢ (% → ?); // -Hdj /3 width=4/
 110   | -Hdi -Hdj #Hid
 111     generalize in match Hide; -Hide (**) (* rewriting in the premises, rewrites in the goal too *)
 112     >(plus_minus_m_m … Hjde) in ⊢ (% → ?); -Hjde /4 width=4/
 113   ]
 114 | #L #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #i #Hdi #Hide
 115   elim (IHV12 i ? ?) -IHV12 // #V #HV1 #HV2
 116   elim (IHT12 (i + 1) ? ?) -IHT12 /2 width=1/
 117   -Hdi -Hide >arith_c1x #T #HT1 #HT2
 118   lapply (tps_lsubs_trans … HT1 (L. ⓑ{I} V) ?) -HT1 /3 width=5/
 119 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #i #Hdi #Hide
 120   elim (IHV12 i ? ?) -IHV12 // elim (IHT12 i ? ?) -IHT12 //
 121   -Hdi -Hide /3 width=5/
 122 ]
 123 qed.
 124
 125 lemma tps_split_down: ∀L,T1,T2,d,e. L ⊢ T1 ▶ [d, e] T2 →
 126                       ∀i. d ≤ i → i ≤ d + e →
 127                       ∃∃T. L ⊢ T1 ▶ [i, d + e - i] T &
 128                            L ⊢ T ▶ [d, i - d] T2.
 129 #L #T1 #T2 #d #e #H elim H -L -T1 -T2 -d -e
 130 [ /2 width=3/
 131 | #L #K #V #W #i #d #e #Hdi #Hide #HLK #HVW #j #Hdj #Hjde
 132   elim (lt_or_ge i j)
 133   [ -Hide -Hjde >(plus_minus_m_m j d) in ⊢ (% → ?); // -Hdj /4 width=4/
 134   | -Hdi -Hdj
 135     >(plus_minus_m_m (d+e) j) in Hide; // -Hjde /3 width=4/
 136   ]
 137 | #L #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #i #Hdi #Hide
 138   elim (IHV12 i ? ?) -IHV12 // #V #HV1 #HV2
 139   elim (IHT12 (i + 1) ? ?) -IHT12 /2 width=1/
 140   -Hdi -Hide >arith_c1x #T #HT1 #HT2
 141   lapply (tps_lsubs_trans … HT1 (L. ⓑ{I} V) ?) -HT1 /3 width=5/
 142 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #IHV12 #IHT12 #i #Hdi #Hide
 143   elim (IHV12 i ? ?) -IHV12 // elim (IHT12 i ? ?) -IHT12 //
 144   -Hdi -Hide /3 width=5/
 145 ]
 146 qed.
 147
 148 (* Basic inversion lemmas ***************************************************)
 149
 150 fact tps_inv_atom1_aux: ∀L,T1,T2,d,e. L ⊢ T1 ▶ [d, e] T2 → ∀I. T1 = ⓪{I} →
 151                         T2 = ⓪{I} ∨
 152                         ∃∃K,V,i. d ≤ i & i < d + e &
 153                                  ⇩[O, i] L ≡ K. ⓓV &
 154                                  ⇧[O, i + 1] V ≡ T2 &
 155                                  I = LRef i.
 156 #L #T1 #T2 #d #e * -L -T1 -T2 -d -e
 157 [ #L #I #d #e #J #H destruct /2 width=1/
 158 | #L #K #V #T2 #i #d #e #Hdi #Hide #HLK #HVT2 #I #H destruct /3 width=8/
 159 | #L #a #I #V1 #V2 #T1 #T2 #d #e #_ #_ #J #H destruct
 160 | #L #I #V1 #V2 #T1 #T2 #d #e #_ #_ #J #H destruct
 161 ]
 162 qed.
 163
 164 lemma tps_inv_atom1: ∀L,T2,I,d,e. L ⊢ ⓪{I} ▶ [d, e] T2 →
 165                      T2 = ⓪{I} ∨
 166                      ∃∃K,V,i. d ≤ i & i < d + e &
 167                               ⇩[O, i] L ≡ K. ⓓV &
 168                               ⇧[O, i + 1] V ≡ T2 &
 169                               I = LRef i.
 170 /2 width=3/ qed-.
 171
 172
 173 (* Basic_1: was: subst1_gen_sort *)
 174 lemma tps_inv_sort1: ∀L,T2,k,d,e. L ⊢ ⋆k ▶ [d, e] T2 → T2 = ⋆k.
 175 #L #T2 #k #d #e #H
 176 elim (tps_inv_atom1 … H) -H //
 177 * #K #V #i #_ #_ #_ #_ #H destruct
 178 qed-.
 179
 180 (* Basic_1: was: subst1_gen_lref *)
 181 lemma tps_inv_lref1: ∀L,T2,i,d,e. L ⊢ #i ▶ [d, e] T2 →
 182                      T2 = #i ∨
 183                      ∃∃K,V. d ≤ i & i < d + e &
 184                             ⇩[O, i] L ≡ K. ⓓV &
 185                             ⇧[O, i + 1] V ≡ T2.
 186 #L #T2 #i #d #e #H
 187 elim (tps_inv_atom1 … H) -H /2 width=1/
 188 * #K #V #j #Hdj #Hjde #HLK #HVT2 #H destruct /3 width=4/
 189 qed-.
 190
 191 lemma tps_inv_gref1: ∀L,T2,p,d,e. L ⊢ §p ▶ [d, e] T2 → T2 = §p.
 192 #L #T2 #p #d #e #H
 193 elim (tps_inv_atom1 … H) -H //
 194 * #K #V #i #_ #_ #_ #_ #H destruct
 195 qed-.
 196
 197 fact tps_inv_bind1_aux: ∀d,e,L,U1,U2. L ⊢ U1 ▶ [d, e] U2 →
 198                         ∀a,I,V1,T1. U1 = ⓑ{a,I} V1. T1 →
 199                         ∃∃V2,T2. L ⊢ V1 ▶ [d, e] V2 &
 200                                  L. ⓑ{I} V2 ⊢ T1 ▶ [d + 1, e] T2 &
 201                                  U2 = ⓑ{a,I} V2. T2.
 202 #d #e #L #U1 #U2 * -d -e -L -U1 -U2
 203 [ #L #k #d #e #a #I #V1 #T1 #H destruct
 204 | #L #K #V #W #i #d #e #_ #_ #_ #_ #a #I #V1 #T1 #H destruct
 205 | #L #b #J #V1 #V2 #T1 #T2 #d #e #HV12 #HT12 #a #I #V #T #H destruct /2 width=5/
 206 | #L #J #V1 #V2 #T1 #T2 #d #e #_ #_ #a #I #V #T #H destruct
 207 ]
 208 qed.
 209
 210 lemma tps_inv_bind1: ∀d,e,L,a,I,V1,T1,U2. L ⊢ ⓑ{a,I} V1. T1 ▶ [d, e] U2 →
 211                      ∃∃V2,T2. L ⊢ V1 ▶ [d, e] V2 &
 212                               L. ⓑ{I} V2 ⊢ T1 ▶ [d + 1, e] T2 &
 213                               U2 = ⓑ{a,I} V2. T2.
 214 /2 width=3/ qed-.
 215
 216 fact tps_inv_flat1_aux: ∀d,e,L,U1,U2. L ⊢ U1 ▶ [d, e] U2 →
 217                         ∀I,V1,T1. U1 = ⓕ{I} V1. T1 →
 218                         ∃∃V2,T2. L ⊢ V1 ▶ [d, e] V2 & L ⊢ T1 ▶ [d, e] T2 &
 219                                  U2 =  ⓕ{I} V2. T2.
 220 #d #e #L #U1 #U2 * -d -e -L -U1 -U2
 221 [ #L #k #d #e #I #V1 #T1 #H destruct
 222 | #L #K #V #W #i #d #e #_ #_ #_ #_ #I #V1 #T1 #H destruct
 223 | #L #a #J #V1 #V2 #T1 #T2 #d #e #_ #_ #I #V #T #H destruct
 224 | #L #J #V1 #V2 #T1 #T2 #d #e #HV12 #HT12 #I #V #T #H destruct /2 width=5/
 225 ]
 226 qed.
 227
 228 lemma tps_inv_flat1: ∀d,e,L,I,V1,T1,U2. L ⊢ ⓕ{I} V1. T1 ▶ [d, e] U2 →
 229                      ∃∃V2,T2. L ⊢ V1 ▶ [d, e] V2 & L ⊢ T1 ▶ [d, e] T2 &
 230                               U2 =  ⓕ{I} V2. T2.
 231 /2 width=3/ qed-.
 232
 233 fact tps_inv_refl_O2_aux: ∀L,T1,T2,d,e. L ⊢ T1 ▶ [d, e] T2 → e = 0 → T1 = T2.
 234 #L #T1 #T2 #d #e #H elim H -L -T1 -T2 -d -e
 235 [ //
 236 | #L #K #V #W #i #d #e #Hdi #Hide #_ #_ #H destruct
 237   lapply (le_to_lt_to_lt … Hdi … Hide) -Hdi -Hide <plus_n_O #Hdd
 238   elim (lt_refl_false … Hdd)
 239 | /3 width=1/
 240 | /3 width=1/
 241 ]
 242 qed.
 243
 244 lemma tps_inv_refl_O2: ∀L,T1,T2,d. L ⊢ T1 ▶ [d, 0] T2 → T1 = T2.
 245 /2 width=6/ qed-.
 246
 247 (* Basic forward lemmas *****************************************************)
 248
 249 lemma tps_fwd_tw: ∀L,T1,T2,d,e. L ⊢ T1 ▶ [d, e] T2 → #{T1} ≤ #{T2}.
 250 #L #T1 #T2 #d #e #H elim H -L -T1 -T2 -d -e normalize
 251 /3 by monotonic_le_plus_l, le_plus/ (**) (* just /3 width=1/ is too slow *)
 252 qed-.
 253
 254 lemma tps_fwd_shift1: ∀L1,L,T1,T,d,e. L ⊢ L1 @@ T1 ▶ [d, e] T →
 255                       ∃∃L2,T2. L1 𝟙 L2 & T = L2 @@ T2.
 256 #L1 @(lenv_ind_dx … L1) -L1
 257 [ #L #T1 #T #d #e #_ @ex2_2_intro [3: // |4: // |1,2: skip ] (**) (* /2 width=4/ does not work *)
 258 | #I #L1 #V1 #IH #L #T1 #T #d #e >shift_append_assoc #H
 259   elim (tps_inv_bind1 … H) -H #V2 #T2 #_ #HT12 #H destruct
 260   elim (IH … HT12) -IH -L -T1 -d -e #L2 #T #HL12 #H destruct
 261   @(ex2_2_intro … (⋆.ⓑ{I}V2@@L2)) /2 width=4/ /3 width=2/
 262 ]
 263 qed-.
 264
 265 (* Basic_1: removed theorems 25:
 266             subst0_gen_sort subst0_gen_lref subst0_gen_head subst0_gen_lift_lt
 267             subst0_gen_lift_false subst0_gen_lift_ge subst0_refl subst0_trans
 268             subst0_lift_lt subst0_lift_ge subst0_lift_ge_S subst0_lift_ge_s
 269             subst0_subst0 subst0_subst0_back subst0_weight_le subst0_weight_lt
 270             subst0_confluence_neq subst0_confluence_eq subst0_tlt_head
 271             subst0_confluence_lift subst0_tlt
 272             subst1_head subst1_gen_head subst1_lift_S subst1_confluence_lift
 273 *)