matita/matita/contribs/lambda_delta/basic_2/unfold/delift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic_2/unfold/tpss.ma".
  16
  17 (* DELIFT ON TERMS **********************************************************)
  18
  19 definition delift: nat → nat → lenv → relation term ≝
  20                    λd,e,L,T1,T2. ∃∃T. L ⊢ T1 [d, e] ▶* T & ⇧[d, e] T2 ≡ T.
  21
  22 interpretation "delift (term)"
  23    'TSubst L T1 d e T2 = (delift d e L T1 T2).
  24
  25 (* Basic properties *********************************************************)
  26
  27 lemma delift_lsubs_conf: ∀L1,T1,T2,d,e. L1 ⊢ T1 [d, e] ≡ T2 →
  28                          ∀L2. L1 [d, e] ≼ L2 → L2 ⊢ T1 [d, e] ≡ T2.
  29 #L1 #T1 #T2 #d #e * /3 width=3/
  30 qed.
  31
  32 lemma delift_bind: ∀I,L,V1,V2,T1,T2,d,e.
  33                    L ⊢ V1 [d, e] ≡ V2 → L. ⓑ{I} V2 ⊢ T1 [d+1, e] ≡ T2 →
  34                    L ⊢ ⓑ{I} V1. T1 [d, e] ≡ ⓑ{I} V2. T2.
  35 #I #L #V1 #V2 #T1 #T2 #d #e * #V #HV1 #HV2 * #T #HT1 #HT2
  36 lapply (tpss_lsubs_conf … HT1 (L. ⓑ{I} V) ?) -HT1 /2 width=1/ /3 width=5/
  37 qed.
  38
  39 lemma delift_flat: ∀I,L,V1,V2,T1,T2,d,e.
  40                    L ⊢ V1 [d, e] ≡ V2 → L ⊢ T1 [d, e] ≡ T2 →
  41                    L ⊢ ⓕ{I} V1. T1 [d, e] ≡ ⓕ{I} V2. T2.
  42 #I #L #V1 #V2 #T1 #T2 #d #e * #V #HV1 #HV2 * /3 width=5/
  43 qed.
  44
  45 (* Basic forward lemmas *****************************************************)
  46
  47 lemma delift_fwd_sort1: ∀L,U2,d,e,k. L ⊢ ⋆k [d, e] ≡ U2 → U2 = ⋆k.
  48 #L #U2 #d #e #k * #U #HU
  49 >(tpss_inv_sort1 … HU) -HU #HU2
  50 >(lift_inv_sort2 … HU2) -HU2 //
  51 qed-.
  52
  53 lemma delift_fwd_gref1: ∀L,U2,d,e,p. L ⊢ §p [d, e] ≡ U2 → U2 = §p.
  54 #L #U #d #e #p * #U #HU
  55 >(tpss_inv_gref1 … HU) -HU #HU2
  56 >(lift_inv_gref2 … HU2) -HU2 //
  57 qed-.
  58
  59 lemma delift_fwd_bind1: ∀I,L,V1,T1,U2,d,e. L ⊢ ⓑ{I} V1. T1 [d, e] ≡ U2 →
  60                         ∃∃V2,T2. L ⊢ V1 [d, e] ≡ V2 &
  61                                  L. ⓑ{I} V2 ⊢ T1 [d+1, e] ≡ T2 &
  62                                  U2 = ⓑ{I} V2. T2.
  63 #I #L #V1 #T1 #U2 #d #e * #U #HU #HU2
  64 elim (tpss_inv_bind1 … HU) -HU #V #T #HV1 #HT1 #X destruct
  65 elim (lift_inv_bind2 … HU2) -HU2 #V2 #T2 #HV2 #HT2
  66 lapply (tpss_lsubs_conf … HT1 (L. ⓑ{I} V2) ?) -HT1 /2 width=1/ /3 width=5/
  67 qed-.
  68
  69 lemma delift_fwd_flat1: ∀I,L,V1,T1,U2,d,e. L ⊢ ⓕ{I} V1. T1 [d, e] ≡ U2 →
  70                         ∃∃V2,T2. L ⊢ V1 [d, e] ≡ V2 &
  71                                  L ⊢ T1 [d, e] ≡ T2 &
  72                                  U2 = ⓕ{I} V2. T2.
  73 #I #L #V1 #T1 #U2 #d #e * #U #HU #HU2
  74 elim (tpss_inv_flat1 … HU) -HU #V #T #HV1 #HT1 #X destruct
  75 elim (lift_inv_flat2 … HU2) -HU2 /3 width=5/
  76 qed-.
  77
  78 (* Basic Inversion lemmas ***************************************************)
  79
  80 lemma delift_inv_refl_O2: ∀L,T1,T2,d. L ⊢ T1 [d, 0] ≡ T2 → T1 = T2.
  81 #L #T1 #T2 #d * #T #HT1
  82 >(tpss_inv_refl_O2 … HT1) -HT1 #HT2
  83 >(lift_inv_refl_O2 … HT2) -HT2 //
  84 qed-.