matita/matita/contribs/lambda_delta/basic_2/unfold/delift_lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/unfold/tpss_lift.ma".
  16 include "basic_2/unfold/delift.ma".
  17
  18 (* DELIFT ON TERMS **********************************************************)
  19
  20 (* Advanced properties ******************************************************)
  21
  22 lemma delift_lref_be: ∀L,K,V1,V2,U2,i,d,e. d ≤ i → i < d + e →
  23                       ⇩[0, i] L ≡ K. ⓓV1 → K ⊢ V1 [0, d + e - i - 1] ≡ V2 →
  24                       ⇧[0, d] V2 ≡ U2 → L ⊢ #i [d, e] ≡ U2.
  25 #L #K #V1 #V2 #U2 #i #d #e #Hdi #Hide #HLK * #V #HV1 #HV2 #HVU2
  26 elim (lift_total V 0 (i+1)) #U #HVU
  27 lapply (lift_trans_be … HV2 … HVU ? ?) -HV2 // >minus_plus <plus_minus_m_m
  28 /2 width=1/ /3 width=6/
  29 qed.
  30
  31 (* Advanced forward lemmas **************************************************)
  32
  33 lemma delift_inv_lref1_lt: ∀L,U2,i,d,e. L ⊢ #i [d, e] ≡ U2 → i < d → U2 = #i.
  34 #L #U2 #i #d #e * #U #HU #HU2 #Hid
  35 elim (tpss_inv_lref1 … HU) -HU
  36 [ #H destruct >(lift_inv_lref2_lt … HU2) //
  37 | * #K #V1 #V2 #Hdi
  38   lapply (lt_to_le_to_lt … Hid Hdi) -Hid -Hdi #Hi
  39   elim (lt_refl_false … Hi)
  40 ]
  41 qed-.
  42
  43 lemma delift_inv_lref1_be: ∀L,U2,d,e,i. L ⊢ #i [d, e] ≡ U2 →
  44                            d ≤ i → i < d + e →
  45                            ∃∃K,V1,V2. ⇩[0, i] L ≡ K. ⓓV1 &
  46                                       K ⊢ V1 [0, d + e - i - 1] ≡ V2 &
  47                                       ⇧[0, d] V2 ≡ U2.
  48 #L #U2 #d #e #i * #U #HU #HU2 #Hdi #Hide
  49 elim (tpss_inv_lref1 … HU) -HU
  50 [ #H destruct elim (lift_inv_lref2_be … HU2 ? ?) //
  51 | * #K #V1 #V #_ #_ #HLK #HV1 #HVU
  52   elim (lift_div_be … HVU … HU2 ? ?) -U // /2 width=1/ /3 width=6/
  53 ]
  54 qed-.
  55
  56 lemma delift_inv_lref1_ge: ∀L,U2,i,d,e. L ⊢ #i [d, e] ≡ U2 →
  57                            d + e ≤ i → U2 = #(i - e).
  58 #L #U2 #i #d #e * #U #HU #HU2 #Hdei
  59 elim (tpss_inv_lref1 … HU) -HU
  60 [ #H destruct >(lift_inv_lref2_ge … HU2) //
  61 | * #K #V1 #V2 #_ #Hide
  62   lapply (lt_to_le_to_lt … Hide Hdei) -Hide -Hdei #Hi
  63   elim (lt_refl_false … Hi)
  64 ]
  65 qed-.
  66
  67 lemma delift_inv_lref1: ∀L,U2,i,d,e. L ⊢ #i [d, e] ≡ U2 →
  68                         ∨∨ (i < d ∧ U2 = #i)
  69                         |  (∃∃K,V1,V2. d ≤ i & i < d + e &
  70                                        ⇩[0, i] L ≡ K. ⓓV1 &
  71                                        K ⊢ V1 [0, d + e - i - 1] ≡ V2 &
  72                                        ⇧[0, d] V2 ≡ U2
  73                            )
  74                         |  (d + e ≤ i ∧ U2 = #(i - e)).
  75 #L #U2 #i #d #e #H
  76 elim (lt_or_ge i d) #Hdi
  77 [ elim (delift_inv_lref1_lt … H Hdi) -H /3 width=1/
  78 | elim (lt_or_ge i (d+e)) #Hide
  79   [ elim (delift_inv_lref1_be … H Hdi Hide) -H /3 width=6/
  80   | elim (delift_inv_lref1_ge … H Hide) -H /3 width=1/
  81   ]
  82 ]
  83 qed-.