matita/matita/contribs/lambda_delta/basic_2/unfold/delift_ltpss.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/unfold/ltpss_ltpss.ma".
  16 include "basic_2/unfold/delift.ma".
  17
  18 (* INVERSE BASIC TERM RELOCATION  *******************************************)
  19
  20 (* Properties on partial unfold on local environments ***********************)
  21
  22 lemma delift_ltpss_conf_eq: ∀L,T1,T2,d,e. L ⊢ T1 [d, e] ≡ T2 →
  23                             ∀K. L ▶* [d, e] K → K ⊢ T1 [d, e] ≡ T2.
  24 #L #T1 #T2 #d #e * #T #HT1 #HT2 #K #HLK
  25 elim (ltpss_tpss_conf … HT1 … HLK) -L #T0 #HT10 #HT0
  26 lapply (tpss_inv_lift1_eq … HT0 … HT2) -HT0 #H destruct /2 width=3/
  27 qed.
  28
  29 lemma ltpss_delift_trans_eq: ∀L,K,d,e. L ▶* [d, e] K →
  30                              ∀T1,T2. K ⊢ T1 [d, e] ≡ T2 → L ⊢ T1 [d, e] ≡ T2.
  31 #L #K #d #e #HLK #T1 #T2 * #T #HT1 #HT2
  32 lapply (ltpss_tpss_trans_eq … HT1 … HLK) -K /2 width=3/
  33 qed.