matita/matita/contribs/lambda_delta/basic_2/unfold/ltpss.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/unfold/tpss.ma".
  16
  17 (* PARALLEL UNFOLD ON LOCAL ENVIRONMENTS ************************************)
  18
  19 (* Basic_1: includes: csubst1_bind *)
  20 inductive ltpss: nat → nat → relation lenv ≝
  21 | ltpss_atom : ∀d,e. ltpss d e (⋆) (⋆)
  22 | ltpss_pair : ∀L,I,V. ltpss 0 0 (L. ⓑ{I} V) (L. ⓑ{I} V)
  23 | ltpss_tpss2: ∀L1,L2,I,V1,V2,e.
  24                ltpss 0 e L1 L2 → L2 ⊢ V1 ▶* [0, e] V2 →
  25                ltpss 0 (e + 1) (L1. ⓑ{I} V1) (L2. ⓑ{I} V2)
  26 | ltpss_tpss1: ∀L1,L2,I,V1,V2,d,e.
  27                ltpss d e L1 L2 → L2 ⊢ V1 ▶* [d, e] V2 →
  28                ltpss (d + 1) e (L1. ⓑ{I} V1) (L2. ⓑ{I} V2)
  29 .
  30
  31 interpretation "parallel unfold (local environment)"
  32    'PSubstStar L1 d e L2 = (ltpss d e L1 L2).
  33
  34 (* Basic properties *********************************************************)
  35
  36 lemma ltpss_tps2: ∀L1,L2,I,V1,V2,e.
  37                   L1 ▶* [0, e] L2 → L2 ⊢ V1 ▶ [0, e] V2 →
  38                   L1. ⓑ{I} V1 ▶* [0, e + 1] L2. ⓑ{I} V2.
  39 /3 width=1/ qed.
  40
  41 lemma ltpss_tps1: ∀L1,L2,I,V1,V2,d,e.
  42                   L1 ▶* [d, e] L2 → L2 ⊢ V1 ▶ [d, e] V2 →
  43                   L1. ⓑ{I} V1 ▶* [d + 1, e] L2. ⓑ{I} V2.
  44 /3 width=1/ qed.
  45
  46 lemma ltpss_tpss2_lt: ∀L1,L2,I,V1,V2,e.
  47                       L1 ▶* [0, e - 1] L2 → L2 ⊢ V1 ▶* [0, e - 1] V2 →
  48                       0 < e → L1. ⓑ{I} V1 ▶* [0, e] L2. ⓑ{I} V2.
  49 #L1 #L2 #I #V1 #V2 #e #HL12 #HV12 #He
  50 >(plus_minus_m_m e 1) /2 width=1/
  51 qed.
  52
  53 lemma ltpss_tpss1_lt: ∀L1,L2,I,V1,V2,d,e.
  54                       L1 ▶* [d - 1, e] L2 → L2 ⊢ V1 ▶* [d - 1, e] V2 →
  55                       0 < d → L1. ⓑ{I} V1 ▶* [d, e] L2. ⓑ{I} V2.
  56 #L1 #L2 #I #V1 #V2 #d #e #HL12 #HV12 #Hd
  57 >(plus_minus_m_m d 1) /2 width=1/
  58 qed.
  59
  60 lemma ltpss_tps2_lt: ∀L1,L2,I,V1,V2,e.
  61                      L1 ▶* [0, e - 1] L2 → L2 ⊢ V1 ▶ [0, e - 1] V2 →
  62                      0 < e → L1. ⓑ{I} V1 ▶* [0, e] L2. ⓑ{I} V2.
  63 /3 width=1/ qed.
  64
  65 lemma ltpss_tps1_lt: ∀L1,L2,I,V1,V2,d,e.
  66                      L1 ▶* [d - 1, e] L2 → L2 ⊢ V1 ▶ [d - 1, e] V2 →
  67                      0 < d → L1. ⓑ{I} V1 ▶* [d, e] L2. ⓑ{I} V2.
  68 /3 width=1/ qed.
  69
  70 (* Basic_1: was by definition: csubst1_refl *)
  71 lemma ltpss_refl: ∀L,d,e. L ▶* [d, e] L.
  72 #L elim L -L //
  73 #L #I #V #IHL * /2 width=1/ * /2 width=1/
  74 qed.
  75
  76 lemma ltpss_weak: ∀L1,L2,d1,e1. L1 ▶* [d1, e1] L2 →
  77                   ∀d2,e2. d2 ≤ d1 → d1 + e1 ≤ d2 + e2 → L1 ▶* [d2, e2] L2.
  78 #L1 #L2 #d1 #e1 #H elim H -L1 -L2 -d1 -e1 //
  79 [ #L1 #L2 #I #V1 #V2 #e1 #_ #HV12 #IHL12 #d2 #e2 #Hd2 #Hde2
  80   lapply (le_n_O_to_eq … Hd2) #H destruct normalize in Hde2;
  81   lapply (lt_to_le_to_lt 0 … Hde2) // #He2
  82   lapply (le_plus_to_minus_r … Hde2) -Hde2 /3 width=5/
  83 | #L1 #L2 #I #V1 #V2 #d1 #e1 #_ #HV12 #IHL12 #d2 #e2 #Hd21 #Hde12
  84   >plus_plus_comm_23 in Hde12; #Hde12
  85   elim (le_to_or_lt_eq 0 d2 ?) // #H destruct
  86   [ lapply (le_plus_to_minus_r … Hde12) -Hde12 <plus_minus // #Hde12
  87     lapply (le_plus_to_minus … Hd21) -Hd21 #Hd21 /3 width=5/
  88   | -Hd21 normalize in Hde12;
  89     lapply (lt_to_le_to_lt 0 … Hde12) // #He2
  90     lapply (le_plus_to_minus_r … Hde12) -Hde12 /3 width=5/
  91   ]
  92 ]
  93 qed.
  94
  95 lemma ltpss_weak_all: ∀L1,L2,d,e. L1 ▶* [d, e] L2 → L1 ▶* [0, |L2|] L2.
  96 #L1 #L2 #d #e #H elim H -L1 -L2 -d -e
  97 // /3 width=2/ /3 width=3/
  98 qed.
  99
 100 (* Basic forward lemmas *****************************************************)
 101
 102 lemma ltpss_fwd_length: ∀L1,L2,d,e. L1 ▶* [d, e] L2 → |L1| = |L2|.
 103 #L1 #L2 #d #e #H elim H -L1 -L2 -d -e
 104 normalize //
 105 qed-.
 106
 107 (* Basic inversion lemmas ***************************************************)
 108
 109 fact ltpss_inv_refl_O2_aux: ∀d,e,L1,L2. L1 ▶* [d, e] L2 → e = 0 → L1 = L2.
 110 #d #e #L1 #L2 #H elim H -d -e -L1 -L2 //
 111 [ #L1 #L2 #I #V1 #V2 #e #_ #_ #_ >commutative_plus normalize #H destruct
 112 | #L1 #L2 #I #V1 #V2 #d #e #_ #HV12 #IHL12 #He destruct
 113   >(IHL12 ?) -IHL12 // >(tpss_inv_refl_O2 … HV12) //
 114 ]
 115 qed.
 116
 117 lemma ltpss_inv_refl_O2: ∀d,L1,L2. L1 ▶* [d, 0] L2 → L1 = L2.
 118 /2 width=4/ qed-.
 119
 120 fact ltpss_inv_atom1_aux: ∀d,e,L1,L2.
 121                           L1 ▶* [d, e] L2 → L1 = ⋆ → L2 = ⋆.
 122 #d #e #L1 #L2 * -d -e -L1 -L2
 123 [ //
 124 | #L #I #V #H destruct
 125 | #L1 #L2 #I #V1 #V2 #e #_ #_ #H destruct
 126 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H destruct
 127 ]
 128 qed.
 129
 130 lemma ltpss_inv_atom1: ∀d,e,L2. ⋆ ▶* [d, e] L2 → L2 = ⋆.
 131 /2 width=5/ qed-.
 132
 133 fact ltpss_inv_tpss21_aux: ∀d,e,L1,L2. L1 ▶* [d, e] L2 → d = 0 → 0 < e →
 134                            ∀K1,I,V1. L1 = K1. ⓑ{I} V1 →
 135                            ∃∃K2,V2. K1 ▶* [0, e - 1] K2 &
 136                                     K2 ⊢ V1 ▶* [0, e - 1] V2 &
 137                                     L2 = K2. ⓑ{I} V2.
 138 #d #e #L1 #L2 * -d -e -L1 -L2
 139 [ #d #e #_ #_ #K1 #I #V1 #H destruct
 140 | #L1 #I #V #_ #H elim (lt_refl_false … H)
 141 | #L1 #L2 #I #V1 #V2 #e #HL12 #HV12 #_ #_ #K1 #J #W1 #H destruct /2 width=5/
 142 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ >commutative_plus normalize #H destruct
 143 ]
 144 qed.
 145
 146 lemma ltpss_inv_tpss21: ∀e,K1,I,V1,L2. K1. ⓑ{I} V1 ▶* [0, e] L2 → 0 < e →
 147                         ∃∃K2,V2. K1 ▶* [0, e - 1] K2 &
 148                                  K2 ⊢ V1 ▶* [0, e - 1] V2 &
 149                                  L2 = K2. ⓑ{I} V2.
 150 /2 width=5/ qed-.
 151
 152 fact ltpss_inv_tpss11_aux: ∀d,e,L1,L2. L1 ▶* [d, e] L2 → 0 < d →
 153                            ∀I,K1,V1. L1 = K1. ⓑ{I} V1 →
 154                            ∃∃K2,V2. K1 ▶* [d - 1, e] K2 &
 155                                     K2 ⊢ V1 ▶* [d - 1, e] V2 &
 156                                     L2 = K2. ⓑ{I} V2.
 157 #d #e #L1 #L2 * -d -e -L1 -L2
 158 [ #d #e #_ #I #K1 #V1 #H destruct
 159 | #L #I #V #H elim (lt_refl_false … H)
 160 | #L1 #L2 #I #V1 #V2 #e #_ #_ #H elim (lt_refl_false … H)
 161 | #L1 #L2 #I #V1 #V2 #d #e #HL12 #HV12 #_ #J #K1 #W1 #H destruct /2 width=5/
 162 ]
 163 qed.
 164
 165 lemma ltpss_inv_tpss11: ∀d,e,I,K1,V1,L2. K1. ⓑ{I} V1 ▶* [d, e] L2 → 0 < d →
 166                         ∃∃K2,V2. K1 ▶* [d - 1, e] K2 &
 167                                  K2 ⊢ V1 ▶* [d - 1, e] V2 &
 168                                  L2 = K2. ⓑ{I} V2.
 169 /2 width=3/ qed-.
 170
 171 fact ltpss_inv_atom2_aux: ∀d,e,L1,L2.
 172                           L1 ▶* [d, e] L2 → L2 = ⋆ → L1 = ⋆.
 173 #d #e #L1 #L2 * -d -e -L1 -L2
 174 [ //
 175 | #L #I #V #H destruct
 176 | #L1 #L2 #I #V1 #V2 #e #_ #_ #H destruct
 177 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H destruct
 178 ]
 179 qed.
 180
 181 lemma ltpss_inv_atom2: ∀d,e,L1. L1 ▶* [d, e] ⋆ → L1 = ⋆.
 182 /2 width=5/ qed-.
 183
 184 fact ltpss_inv_tpss22_aux: ∀d,e,L1,L2. L1 ▶* [d, e] L2 → d = 0 → 0 < e →
 185                            ∀K2,I,V2. L2 = K2. ⓑ{I} V2 →
 186                            ∃∃K1,V1. K1 ▶* [0, e - 1] K2 &
 187                                     K2 ⊢ V1 ▶* [0, e - 1] V2 &
 188                                     L1 = K1. ⓑ{I} V1.
 189 #d #e #L1 #L2 * -d -e -L1 -L2
 190 [ #d #e #_ #_ #K1 #I #V1 #H destruct
 191 | #L1 #I #V #_ #H elim (lt_refl_false … H)
 192 | #L1 #L2 #I #V1 #V2 #e #HL12 #HV12 #_ #_ #K2 #J #W2 #H destruct /2 width=5/
 193 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ >commutative_plus normalize #H destruct
 194 ]
 195 qed.
 196
 197 lemma ltpss_inv_tpss22: ∀e,L1,K2,I,V2. L1 ▶* [0, e] K2. ⓑ{I} V2 → 0 < e →
 198                         ∃∃K1,V1. K1 ▶* [0, e - 1] K2 &
 199                                  K2 ⊢ V1 ▶* [0, e - 1] V2 &
 200                                  L1 = K1. ⓑ{I} V1.
 201 /2 width=5/ qed-.
 202
 203 fact ltpss_inv_tpss12_aux: ∀d,e,L1,L2. L1 ▶* [d, e] L2 → 0 < d →
 204                            ∀I,K2,V2. L2 = K2. ⓑ{I} V2 →
 205                            ∃∃K1,V1. K1 ▶* [d - 1, e] K2 &
 206                                     K2 ⊢ V1 ▶* [d - 1, e] V2 &
 207                                     L1 = K1. ⓑ{I} V1.
 208 #d #e #L1 #L2 * -d -e -L1 -L2
 209 [ #d #e #_ #I #K2 #V2 #H destruct
 210 | #L #I #V #H elim (lt_refl_false … H)
 211 | #L1 #L2 #I #V1 #V2 #e #_ #_ #H elim (lt_refl_false … H)
 212 | #L1 #L2 #I #V1 #V2 #d #e #HL12 #HV12 #_ #J #K2 #W2 #H destruct /2 width=5/
 213 ]
 214 qed.
 215
 216 lemma ltpss_inv_tpss12: ∀L1,K2,I,V2,d,e. L1 ▶* [d, e] K2. ⓑ{I} V2 → 0 < d →
 217                         ∃∃K1,V1. K1 ▶* [d - 1, e] K2 &
 218                                  K2 ⊢ V1 ▶* [d - 1, e] V2 &
 219                                  L1 = K1. ⓑ{I} V1.
 220 /2 width=3/ qed-.
 221
 222 (* Basic_1: removed theorems 28:
 223             csubst0_clear_O csubst0_drop_lt csubst0_drop_gt csubst0_drop_eq
 224             csubst0_clear_O_back csubst0_clear_S csubst0_clear_trans
 225             csubst0_drop_gt_back csubst0_drop_eq_back csubst0_drop_lt_back
 226             csubst0_gen_sort csubst0_gen_head csubst0_getl_ge csubst0_getl_lt
 227             csubst0_gen_S_bind_2 csubst0_getl_ge_back csubst0_getl_lt_back
 228             csubst0_snd_bind csubst0_fst_bind csubst0_both_bind
 229             csubst1_head csubst1_flat csubst1_gen_head
 230             csubst1_getl_ge csubst1_getl_lt csubst1_getl_ge_back getl_csubst1
 231             fsubst0_gen_base
 232 *)