matita/matita/contribs/lambda_delta/basic_2/unfold/ltpss.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/unfold/tpss.ma".
  16
  17 (* PARALLEL UNFOLD ON LOCAL ENVIRONMENTS ************************************)
  18
  19 (* Basic_1: includes: csubst1_bind *)
  20 inductive ltpss: nat → nat → relation lenv ≝
  21 | ltpss_atom : ∀d,e. ltpss d e (⋆) (⋆)
  22 | ltpss_pair : ∀L,I,V. ltpss 0 0 (L. ⓑ{I} V) (L. ⓑ{I} V)
  23 | ltpss_tpss2: ∀L1,L2,I,V1,V2,e.
  24                ltpss 0 e L1 L2 → L2 ⊢ V1 [0, e] ▶* V2 →
  25                ltpss 0 (e + 1) (L1. ⓑ{I} V1) L2. ⓑ{I} V2
  26 | ltpss_tpss1: ∀L1,L2,I,V1,V2,d,e.
  27                ltpss d e L1 L2 → L2 ⊢ V1 [d, e] ▶* V2 →
  28                ltpss (d + 1) e (L1. ⓑ{I} V1) (L2. ⓑ{I} V2)
  29 .
  30
  31 interpretation "parallel unfold (local environment)"
  32    'PSubstStar L1 d e L2 = (ltpss d e L1 L2).
  33
  34 (* Basic properties *********************************************************)
  35
  36 lemma ltpss_tpss2_lt: ∀L1,L2,I,V1,V2,e.
  37                       L1 [0, e - 1] ▶* L2 → L2 ⊢ V1 [0, e - 1] ▶* V2 →
  38                       0 < e → L1. ⓑ{I} V1 [0, e] ▶* L2. ⓑ{I} V2.
  39 #L1 #L2 #I #V1 #V2 #e #HL12 #HV12 #He
  40 >(plus_minus_m_m e 1) /2 width=1/
  41 qed.
  42
  43 lemma ltpss_tpss1_lt: ∀L1,L2,I,V1,V2,d,e.
  44                       L1 [d - 1, e] ▶* L2 → L2 ⊢ V1 [d - 1, e] ▶* V2 →
  45                       0 < d → L1. ⓑ{I} V1 [d, e] ▶* L2. ⓑ{I} V2.
  46 #L1 #L2 #I #V1 #V2 #d #e #HL12 #HV12 #Hd
  47 >(plus_minus_m_m d 1) /2 width=1/
  48 qed.
  49
  50 (* Basic_1: was by definition: csubst1_refl *)
  51 lemma ltpss_refl: ∀L,d,e. L [d, e] ▶* L.
  52 #L elim L -L //
  53 #L #I #V #IHL * /2 width=1/ * /2 width=1/
  54 qed.
  55
  56 lemma ltpss_weak_all: ∀L1,L2,d,e. L1 [d, e] ▶* L2 → L1 [0, |L2|] ▶* L2.
  57 #L1 #L2 #d #e #H elim H -L1 -L2 -d -e
  58 // /3 width=2/ /3 width=3/
  59 qed.
  60
  61 (* Basic forward lemmas *****************************************************)
  62
  63 lemma ltpss_fwd_length: ∀L1,L2,d,e. L1 [d, e] ▶* L2 → |L1| = |L2|.
  64 #L1 #L2 #d #e #H elim H -L1 -L2 -d -e
  65 normalize //
  66 qed-.
  67
  68 (* Basic inversion lemmas ***************************************************)
  69
  70 fact ltpss_inv_refl_O2_aux: ∀d,e,L1,L2. L1 [d, e] ▶* L2 → e = 0 → L1 = L2.
  71 #d #e #L1 #L2 #H elim H -d -e -L1 -L2 //
  72 [ #L1 #L2 #I #V1 #V2 #e #_ #_ #_ >commutative_plus normalize #H destruct
  73 | #L1 #L2 #I #V1 #V2 #d #e #_ #HV12 #IHL12 #He destruct
  74   >(IHL12 ?) -IHL12 // >(tpss_inv_refl_O2 … HV12) //
  75 ]
  76 qed.
  77
  78 lemma ltpss_inv_refl_O2: ∀d,L1,L2. L1 [d, 0] ▶* L2 → L1 = L2.
  79 /2 width=4/ qed-.
  80
  81 fact ltpss_inv_atom1_aux: ∀d,e,L1,L2.
  82                           L1 [d, e] ▶* L2 → L1 = ⋆ → L2 = ⋆.
  83 #d #e #L1 #L2 * -d -e -L1 -L2
  84 [ //
  85 | #L #I #V #H destruct
  86 | #L1 #L2 #I #V1 #V2 #e #_ #_ #H destruct
  87 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H destruct
  88 ]
  89 qed.
  90
  91 lemma ltpss_inv_atom1: ∀d,e,L2. ⋆ [d, e] ▶* L2 → L2 = ⋆.
  92 /2 width=5/ qed-.
  93
  94 fact ltpss_inv_tpss21_aux: ∀d,e,L1,L2. L1 [d, e] ▶* L2 → d = 0 → 0 < e →
  95                            ∀K1,I,V1. L1 = K1. ⓑ{I} V1 →
  96                            ∃∃K2,V2. K1 [0, e - 1] ▶* K2 &
  97                                     K2 ⊢ V1 [0, e - 1] ▶* V2 &
  98                                     L2 = K2. ⓑ{I} V2.
  99 #d #e #L1 #L2 * -d -e -L1 -L2
 100 [ #d #e #_ #_ #K1 #I #V1 #H destruct
 101 | #L1 #I #V #_ #H elim (lt_refl_false … H)
 102 | #L1 #L2 #I #V1 #V2 #e #HL12 #HV12 #_ #_ #K1 #J #W1 #H destruct /2 width=5/
 103 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ >commutative_plus normalize #H destruct
 104 ]
 105 qed.
 106
 107 lemma ltpss_inv_tpss21: ∀e,K1,I,V1,L2. K1. ⓑ{I} V1 [0, e] ▶* L2 → 0 < e →
 108                         ∃∃K2,V2. K1 [0, e - 1] ▶* K2 & K2 ⊢ V1 [0, e - 1] ▶* V2 &
 109                                  L2 = K2. ⓑ{I} V2.
 110 /2 width=5/ qed-.
 111
 112 fact ltpss_inv_tpss11_aux: ∀d,e,L1,L2. L1 [d, e] ▶* L2 → 0 < d →
 113                            ∀I,K1,V1. L1 = K1. ⓑ{I} V1 →
 114                            ∃∃K2,V2. K1 [d - 1, e] ▶* K2 &
 115                                     K2 ⊢ V1 [d - 1, e] ▶* V2 &
 116                                     L2 = K2. ⓑ{I} V2.
 117 #d #e #L1 #L2 * -d -e -L1 -L2
 118 [ #d #e #_ #I #K1 #V1 #H destruct
 119 | #L #I #V #H elim (lt_refl_false … H)
 120 | #L1 #L2 #I #V1 #V2 #e #_ #_ #H elim (lt_refl_false … H)
 121 | #L1 #L2 #I #V1 #V2 #d #e #HL12 #HV12 #_ #J #K1 #W1 #H destruct /2 width=5/
 122 ]
 123 qed.
 124
 125 lemma ltpss_inv_tpss11: ∀d,e,I,K1,V1,L2. K1. ⓑ{I} V1 [d, e] ▶* L2 → 0 < d →
 126                         ∃∃K2,V2. K1 [d - 1, e] ▶* K2 &
 127                                  K2 ⊢ V1 [d - 1, e] ▶* V2 &
 128                                  L2 = K2. ⓑ{I} V2.
 129 /2 width=3/ qed-.
 130
 131 fact ltpss_inv_atom2_aux: ∀d,e,L1,L2.
 132                           L1 [d, e] ▶* L2 → L2 = ⋆ → L1 = ⋆.
 133 #d #e #L1 #L2 * -d -e -L1 -L2
 134 [ //
 135 | #L #I #V #H destruct
 136 | #L1 #L2 #I #V1 #V2 #e #_ #_ #H destruct
 137 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H destruct
 138 ]
 139 qed.
 140
 141 lemma ltpss_inv_atom2: ∀d,e,L1. L1 [d, e] ▶* ⋆ → L1 = ⋆.
 142 /2 width=5/ qed-.
 143
 144 fact ltpss_inv_tpss22_aux: ∀d,e,L1,L2. L1 [d, e] ▶* L2 → d = 0 → 0 < e →
 145                            ∀K2,I,V2. L2 = K2. ⓑ{I} V2 →
 146                            ∃∃K1,V1. K1 [0, e - 1] ▶* K2 &
 147                                     K2 ⊢ V1 [0, e - 1] ▶* V2 &
 148                                     L1 = K1. ⓑ{I} V1.
 149 #d #e #L1 #L2 * -d -e -L1 -L2
 150 [ #d #e #_ #_ #K1 #I #V1 #H destruct
 151 | #L1 #I #V #_ #H elim (lt_refl_false … H)
 152 | #L1 #L2 #I #V1 #V2 #e #HL12 #HV12 #_ #_ #K2 #J #W2 #H destruct /2 width=5/
 153 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ >commutative_plus normalize #H destruct
 154 ]
 155 qed.
 156
 157 lemma ltpss_inv_tpss22: ∀e,L1,K2,I,V2. L1 [0, e] ▶* K2. ⓑ{I} V2 → 0 < e →
 158                         ∃∃K1,V1. K1 [0, e - 1] ▶* K2 & K2 ⊢ V1 [0, e - 1] ▶* V2 &
 159                                  L1 = K1. ⓑ{I} V1.
 160 /2 width=5/ qed-.
 161
 162 fact ltpss_inv_tpss12_aux: ∀d,e,L1,L2. L1 [d, e] ▶* L2 → 0 < d →
 163                            ∀I,K2,V2. L2 = K2. ⓑ{I} V2 →
 164                            ∃∃K1,V1. K1 [d - 1, e] ▶* K2 &
 165                                     K2 ⊢ V1 [d - 1, e] ▶* V2 &
 166                                   L1 = K1. ⓑ{I} V1.
 167 #d #e #L1 #L2 * -d -e -L1 -L2
 168 [ #d #e #_ #I #K2 #V2 #H destruct
 169 | #L #I #V #H elim (lt_refl_false … H)
 170 | #L1 #L2 #I #V1 #V2 #e #_ #_ #H elim (lt_refl_false … H)
 171 | #L1 #L2 #I #V1 #V2 #d #e #HL12 #HV12 #_ #J #K2 #W2 #H destruct /2 width=5/
 172 ]
 173 qed.
 174
 175 lemma ltpss_inv_tpss12: ∀L1,K2,I,V2,d,e. L1 [d, e] ▶* K2. ⓑ{I} V2 → 0 < d →
 176                         ∃∃K1,V1. K1 [d - 1, e] ▶* K2 &
 177                                  K2 ⊢ V1 [d - 1, e] ▶* V2 &
 178                                  L1 = K1. ⓑ{I} V1.
 179 /2 width=3/ qed-.
 180
 181 (* Basic_1: removed theorems 27:
 182             csubst0_clear_O csubst0_drop_lt csubst0_drop_gt csubst0_drop_eq
 183             csubst0_clear_O_back csubst0_clear_S csubst0_clear_trans
 184             csubst0_drop_gt_back csubst0_drop_eq_back csubst0_drop_lt_back
 185             csubst0_gen_sort csubst0_gen_head csubst0_getl_ge csubst0_getl_lt
 186             csubst0_gen_S_bind_2 csubst0_getl_ge_back csubst0_getl_lt_back
 187             csubst0_snd_bind csubst0_fst_bind csubst0_both_bind
 188             csubst1_head csubst1_flat csubst1_gen_head
 189             csubst1_getl_ge csubst1_getl_lt csubst1_getl_ge_back getl_csubst1
 190
 191 *)