matita/matita/contribs/lambda_delta/basic_2/unfold/tpss_tpss.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/substitution/tps_tps.ma".
  16 include "basic_2/unfold/tpss_lift.ma".
  17
  18 (* PARTIAL UNFOLD ON TERMS **************************************************)
  19
  20 (* Advanced properties ******************************************************)
  21
  22 lemma tpss_tps: ∀L,T1,T2,d. L ⊢ T1 ▶* [d, 1] T2 → L ⊢ T1 ▶ [d, 1] T2.
  23 #L #T1 #T2 #d #H @(tpss_ind … H) -T2 //
  24 #T #T2 #_ #HT2 #IHT1
  25 lapply (tps_trans_ge … IHT1 … HT2 ?) //
  26 qed.
  27
  28 lemma tpss_strip_eq: ∀L,T0,T1,d1,e1. L ⊢ T0 ▶* [d1, e1] T1 →
  29                      ∀T2,d2,e2. L ⊢ T0 ▶ [d2, e2] T2 →
  30                      ∃∃T. L ⊢ T1 ▶ [d2, e2] T & L ⊢ T2 ▶* [d1, e1] T.
  31 /3 width=3/ qed.
  32
  33 lemma tpss_strip_neq: ∀L1,T0,T1,d1,e1. L1 ⊢ T0 ▶* [d1, e1] T1 →
  34                       ∀L2,T2,d2,e2. L2 ⊢ T0 ▶ [d2, e2] T2 →
  35                       (d1 + e1 ≤ d2 ∨ d2 + e2 ≤ d1) →
  36                       ∃∃T. L2 ⊢ T1 ▶ [d2, e2] T & L1 ⊢ T2 ▶* [d1, e1] T.
  37 /3 width=3/ qed.
  38
  39 lemma tpss_strap1_down: ∀L,T1,T0,d1,e1. L ⊢ T1 ▶* [d1, e1] T0 →
  40                         ∀T2,d2,e2. L ⊢ T0 ▶ [d2, e2] T2 → d2 + e2 ≤ d1 →
  41                         ∃∃T. L ⊢ T1 ▶ [d2, e2] T & L ⊢ T ▶* [d1, e1] T2.
  42 /3 width=3/ qed.
  43
  44 lemma tpss_strap2_down: ∀L,T1,T0,d1,e1. L ⊢ T1 ▶ [d1, e1] T0 →
  45                         ∀T2,d2,e2. L ⊢ T0 ▶* [d2, e2] T2 → d2 + e2 ≤ d1 →
  46                         ∃∃T. L ⊢ T1 ▶* [d2, e2] T & L ⊢ T ▶ [d1, e1] T2.
  47 /3 width=3/ qed.
  48
  49 lemma tpss_split_up: ∀L,T1,T2,d,e. L ⊢ T1 ▶* [d, e] T2 →
  50                      ∀i. d ≤ i → i ≤ d + e →
  51                      ∃∃T. L ⊢ T1 ▶* [d, i - d] T & L ⊢ T ▶* [i, d + e - i] T2.
  52 #L #T1 #T2 #d #e #H #i #Hdi #Hide @(tpss_ind … H) -T2
  53 [ /2 width=3/
  54 | #T #T2 #_ #HT12 * #T3 #HT13 #HT3
  55   elim (tps_split_up … HT12 … Hdi Hide) -HT12 -Hide #T0 #HT0 #HT02
  56   elim (tpss_strap1_down … HT3 … HT0 ?) -T [2: >commutative_plus /2 width=1/ ]
  57   /3 width=7 by ex2_1_intro, step/ (**) (* just /3 width=7/ is too slow *)
  58 ]
  59 qed.
  60
  61 lemma tpss_inv_lift1_up: ∀L,U1,U2,dt,et. L ⊢ U1 ▶* [dt, et] U2 →
  62                          ∀K,d,e. ⇩[d, e] L ≡ K → ∀T1. ⇧[d, e] T1 ≡ U1 →
  63                          d ≤ dt → dt ≤ d + e → d + e ≤ dt + et →
  64                          ∃∃T2. K ⊢ T1 ▶* [d, dt + et - (d + e)] T2 &
  65                                ⇧[d, e] T2 ≡ U2.
  66 #L #U1 #U2 #dt #et #HU12 #K #d #e #HLK #T1 #HTU1 #Hddt #Hdtde #Hdedet
  67 elim (tpss_split_up … HU12 (d + e) ? ?) -HU12 // -Hdedet #U #HU1 #HU2
  68 lapply (tpss_weak … HU1 d e ? ?) -HU1 // [ >commutative_plus /2 width=1/ ] -Hddt -Hdtde #HU1
  69 lapply (tpss_inv_lift1_eq … HU1 … HTU1) -HU1 #HU1 destruct
  70 elim (tpss_inv_lift1_ge … HU2 … HLK … HTU1 ?) -HU2 -HLK -HTU1 // <minus_plus_m_m /2 width=3/
  71 qed.
  72
  73 (* Main properties **********************************************************)
  74
  75 theorem tpss_conf_eq: ∀L,T0,T1,d1,e1. L ⊢ T0 ▶* [d1, e1] T1 →
  76                       ∀T2,d2,e2. L ⊢ T0 ▶* [d2, e2] T2 →
  77                       ∃∃T. L ⊢ T1 ▶* [d2, e2] T & L ⊢ T2 ▶* [d1, e1] T.
  78 /3 width=3/ qed.
  79
  80 theorem tpss_conf_neq: ∀L1,T0,T1,d1,e1. L1 ⊢ T0 ▶* [d1, e1] T1 →
  81                        ∀L2,T2,d2,e2. L2 ⊢ T0 ▶* [d2, e2] T2 →
  82                        (d1 + e1 ≤ d2 ∨ d2 + e2 ≤ d1) →
  83                        ∃∃T. L2 ⊢ T1 ▶* [d2, e2] T & L1 ⊢ T2 ▶* [d1, e1] T.
  84 /3 width=3/ qed.
  85
  86 theorem tpss_trans_eq: ∀L,T1,T,T2,d,e.
  87                        L ⊢ T1 ▶* [d, e] T → L ⊢ T ▶* [d, e] T2 →
  88                        L ⊢ T1 ▶* [d, e] T2.
  89 /2 width=3/ qed.
  90
  91 theorem tpss_trans_down: ∀L,T1,T0,d1,e1. L ⊢ T1 ▶* [d1, e1] T0 →
  92                          ∀T2,d2,e2. L ⊢ T0 ▶* [d2, e2] T2 → d2 + e2 ≤ d1 →
  93                          ∃∃T. L ⊢ T1 ▶* [d2, e2] T & L ⊢ T ▶* [d1, e1] T2.
  94 /3 width=3/ qed.