matita/matita/contribs/lambda_delta/ground_2/star.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basics/star.ma".
  16 include "ground_2/xoa_props.ma".
  17 include "ground_2/notation.ma".
  18
  19 (* PROPERTIES OF RELATIONS **************************************************)
  20
  21 definition Decidable: Prop → Prop ≝ λR. R ∨ (R → ⊥).
  22
  23 definition confluent2: ∀A. ∀R1,R2: relation A. Prop ≝ λA,R1,R2.
  24                        ∀a0,a1. R1 a0 a1 → ∀a2. R2 a0 a2 →
  25                        ∃∃a. R2 a1 a & R1 a2 a.
  26
  27 definition transitive2: ∀A. ∀R1,R2: relation A. Prop ≝ λA,R1,R2.
  28                         ∀a1,a0. R1 a1 a0 → ∀a2. R2 a0 a2 →
  29                         ∃∃a. R2 a1 a & R1 a a2.
  30
  31 lemma TC_strip1: ∀A,R1,R2. confluent2 A R1 R2 →
  32                  ∀a0,a1. TC … R1 a0 a1 → ∀a2. R2 a0 a2 →
  33                  ∃∃a. R2 a1 a & TC … R1 a2 a.
  34 #A #R1 #R2 #HR12 #a0 #a1 #H elim H -a1
  35 [ #a1 #Ha01 #a2 #Ha02
  36   elim (HR12 … Ha01 … Ha02) -HR12 -a0 /3 width=3/
  37 | #a #a1 #_ #Ha1 #IHa0 #a2 #Ha02
  38   elim (IHa0 … Ha02) -a0 #a0 #Ha0 #Ha20
  39   elim (HR12 … Ha1 … Ha0) -HR12 -a /4 width=3/
  40 ]
  41 qed.
  42
  43 lemma TC_strip2: ∀A,R1,R2. confluent2 A R1 R2 →
  44                  ∀a0,a2. TC … R2 a0 a2 → ∀a1. R1 a0 a1 →
  45                  ∃∃a. TC … R2 a1 a & R1 a2 a.
  46 #A #R1 #R2 #HR12 #a0 #a2 #H elim H -a2
  47 [ #a2 #Ha02 #a1 #Ha01
  48   elim (HR12 … Ha01 … Ha02) -HR12 -a0 /3 width=3/
  49 | #a #a2 #_ #Ha2 #IHa0 #a1 #Ha01
  50   elim (IHa0 … Ha01) -a0 #a0 #Ha10 #Ha0
  51   elim (HR12 … Ha0 … Ha2) -HR12 -a /4 width=3/
  52 ]
  53 qed.
  54
  55 lemma TC_confluent2: ∀A,R1,R2.
  56                      confluent2 A R1 R2 → confluent2 A (TC … R1) (TC … R2).
  57 #A #R1 #R2 #HR12 #a0 #a1 #H elim H -a1
  58 [ #a1 #Ha01 #a2 #Ha02
  59   elim (TC_strip2 … HR12 … Ha02 … Ha01) -HR12 -a0 /3 width=3/
  60 | #a #a1 #_ #Ha1 #IHa0 #a2 #Ha02
  61   elim (IHa0 … Ha02) -a0 #a0 #Ha0 #Ha20
  62   elim (TC_strip2 … HR12 … Ha0 … Ha1) -HR12 -a /4 width=3/
  63 ]
  64 qed.
  65
  66 lemma TC_strap1: ∀A,R1,R2. transitive2 A R1 R2 →
  67                  ∀a1,a0. TC … R1 a1 a0 → ∀a2. R2 a0 a2 →
  68                  ∃∃a. R2 a1 a & TC … R1 a a2.
  69 #A #R1 #R2 #HR12 #a1 #a0 #H elim H -a0
  70 [ #a0 #Ha10 #a2 #Ha02
  71   elim (HR12 … Ha10 … Ha02) -HR12 -a0 /3 width=3/
  72 | #a #a0 #_ #Ha0 #IHa #a2 #Ha02
  73   elim (HR12 … Ha0 … Ha02) -HR12 -a0 #a0 #Ha0 #Ha02
  74   elim (IHa … Ha0) -a /4 width=3/
  75 ]
  76 qed.
  77
  78 lemma TC_strap2: ∀A,R1,R2. transitive2 A R1 R2 →
  79                  ∀a0,a2. TC … R2 a0 a2 → ∀a1. R1 a1 a0 →
  80                  ∃∃a. TC … R2 a1 a & R1 a a2.
  81 #A #R1 #R2 #HR12 #a0 #a2 #H elim H -a2
  82 [ #a2 #Ha02 #a1 #Ha10
  83   elim (HR12 … Ha10 … Ha02) -HR12 -a0 /3 width=3/
  84 | #a #a2 #_ #Ha02 #IHa #a1 #Ha10
  85   elim (IHa … Ha10) -a0 #a0 #Ha10 #Ha0
  86   elim (HR12 … Ha0 … Ha02) -HR12 -a /4 width=3/
  87 ]
  88 qed.
  89
  90 lemma TC_transitive2: ∀A,R1,R2.
  91                       transitive2 A R1 R2 → transitive2 A (TC … R1) (TC … R2).
  92 #A #R1 #R2 #HR12 #a1 #a0 #H elim H -a0
  93 [ #a0 #Ha10 #a2 #Ha02
  94   elim (TC_strap2 … HR12 … Ha02 … Ha10) -HR12 -a0 /3 width=3/
  95 | #a #a0 #_ #Ha0 #IHa #a2 #Ha02
  96   elim (TC_strap2 … HR12 … Ha02 … Ha0) -HR12 -a0 #a0 #Ha0 #Ha02
  97   elim (IHa … Ha0) -a /4 width=3/
  98 ]
  99 qed.
 100
 101 definition NF: ∀A. relation A → relation A → predicate A ≝
 102    λA,R,S,a1. ∀a2. R a1 a2 → S a2 a1.
 103
 104 inductive SN (A) (R,S:relation A): predicate A ≝
 105 | SN_intro: ∀a1. (∀a2. R a1 a2 → (S a2 a1 → ⊥) → SN A R S a2) → SN A R S a1
 106 .
 107
 108 lemma NF_to_SN: ∀A,R,S,a. NF A R S a → SN A R S a.
 109 #A #R #S #a1 #Ha1
 110 @SN_intro #a2 #HRa12 #HSa12
 111 elim (HSa12 ?) -HSa12 /2 width=1/
 112 qed.
 113
 114 definition NF_sn: ∀A. relation A → relation A → predicate A ≝
 115    λA,R,S,a2. ∀a1. R a1 a2 → S a2 a1.
 116
 117 inductive SN_sn (A) (R,S:relation A): predicate A ≝
 118 | SN_sn_intro: ∀a2. (∀a1. R a1 a2 → (S a2 a1 → ⊥) → SN_sn A R S a1) → SN_sn A R S a2
 119 .
 120
 121 lemma NF_to_SN_sn: ∀A,R,S,a. NF_sn A R S a → SN_sn A R S a.
 122 #A #R #S #a2 #Ha2
 123 @SN_sn_intro #a1 #HRa12 #HSa12
 124 elim (HSa12 ?) -HSa12 /2 width=1/
 125 qed.