matita/matita/contribs/lambda_delta/ground_2/star.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basics/star.ma".
  16 include "ground_2/xoa_props.ma".
  17 include "ground_2/notation.ma".
  18
  19 (* PROPERTIES OF RELATIONS **************************************************)
  20
  21 definition Decidable: Prop → Prop ≝ λR. R ∨ (R → ⊥).
  22
  23 definition Confluent: ∀A. ∀R: relation A. Prop ≝ λA,R.
  24                       ∀a0,a1. R a0 a1 → ∀a2. R a0 a2 →
  25                       ∃∃a. R a1 a & R a2 a.
  26
  27 definition Transitive: ∀A. ∀R: relation A. Prop ≝ λA,R.
  28                        ∀a1,a0. R a1 a0 → ∀a2. R a0 a2 → R a1 a2.
  29
  30 definition confluent2: ∀A. ∀R1,R2: relation A. Prop ≝ λA,R1,R2.
  31                        ∀a0,a1. R1 a0 a1 → ∀a2. R2 a0 a2 →
  32                        ∃∃a. R2 a1 a & R1 a2 a.
  33
  34 definition transitive2: ∀A. ∀R1,R2: relation A. Prop ≝ λA,R1,R2.
  35                         ∀a1,a0. R1 a1 a0 → ∀a2. R2 a0 a2 →
  36                         ∃∃a. R2 a1 a & R1 a a2.
  37
  38 lemma TC_strip1: ∀A,R1,R2. confluent2 A R1 R2 →
  39                  ∀a0,a1. TC … R1 a0 a1 → ∀a2. R2 a0 a2 →
  40                  ∃∃a. R2 a1 a & TC … R1 a2 a.
  41 #A #R1 #R2 #HR12 #a0 #a1 #H elim H -a1
  42 [ #a1 #Ha01 #a2 #Ha02
  43   elim (HR12 … Ha01 … Ha02) -HR12 -a0 /3 width=3/
  44 | #a #a1 #_ #Ha1 #IHa0 #a2 #Ha02
  45   elim (IHa0 … Ha02) -a0 #a0 #Ha0 #Ha20
  46   elim (HR12 … Ha1 … Ha0) -HR12 -a /4 width=3/
  47 ]
  48 qed.
  49
  50 lemma TC_strip2: ∀A,R1,R2. confluent2 A R1 R2 →
  51                  ∀a0,a2. TC … R2 a0 a2 → ∀a1. R1 a0 a1 →
  52                  ∃∃a. TC … R2 a1 a & R1 a2 a.
  53 #A #R1 #R2 #HR12 #a0 #a2 #H elim H -a2
  54 [ #a2 #Ha02 #a1 #Ha01
  55   elim (HR12 … Ha01 … Ha02) -HR12 -a0 /3 width=3/
  56 | #a #a2 #_ #Ha2 #IHa0 #a1 #Ha01
  57   elim (IHa0 … Ha01) -a0 #a0 #Ha10 #Ha0
  58   elim (HR12 … Ha0 … Ha2) -HR12 -a /4 width=3/
  59 ]
  60 qed.
  61
  62 lemma TC_confluent2: ∀A,R1,R2.
  63                      confluent2 A R1 R2 → confluent2 A (TC … R1) (TC … R2).
  64 #A #R1 #R2 #HR12 #a0 #a1 #H elim H -a1
  65 [ #a1 #Ha01 #a2 #Ha02
  66   elim (TC_strip2 … HR12 … Ha02 … Ha01) -HR12 -a0 /3 width=3/
  67 | #a #a1 #_ #Ha1 #IHa0 #a2 #Ha02
  68   elim (IHa0 … Ha02) -a0 #a0 #Ha0 #Ha20
  69   elim (TC_strip2 … HR12 … Ha0 … Ha1) -HR12 -a /4 width=3/
  70 ]
  71 qed.
  72
  73 lemma TC_strap1: ∀A,R1,R2. transitive2 A R1 R2 →
  74                  ∀a1,a0. TC … R1 a1 a0 → ∀a2. R2 a0 a2 →
  75                  ∃∃a. R2 a1 a & TC … R1 a a2.
  76 #A #R1 #R2 #HR12 #a1 #a0 #H elim H -a0
  77 [ #a0 #Ha10 #a2 #Ha02
  78   elim (HR12 … Ha10 … Ha02) -HR12 -a0 /3 width=3/
  79 | #a #a0 #_ #Ha0 #IHa #a2 #Ha02
  80   elim (HR12 … Ha0 … Ha02) -HR12 -a0 #a0 #Ha0 #Ha02
  81   elim (IHa … Ha0) -a /4 width=3/
  82 ]
  83 qed.
  84
  85 lemma TC_strap2: ∀A,R1,R2. transitive2 A R1 R2 →
  86                  ∀a0,a2. TC … R2 a0 a2 → ∀a1. R1 a1 a0 →
  87                  ∃∃a. TC … R2 a1 a & R1 a a2.
  88 #A #R1 #R2 #HR12 #a0 #a2 #H elim H -a2
  89 [ #a2 #Ha02 #a1 #Ha10
  90   elim (HR12 … Ha10 … Ha02) -HR12 -a0 /3 width=3/
  91 | #a #a2 #_ #Ha02 #IHa #a1 #Ha10
  92   elim (IHa … Ha10) -a0 #a0 #Ha10 #Ha0
  93   elim (HR12 … Ha0 … Ha02) -HR12 -a /4 width=3/
  94 ]
  95 qed.
  96
  97 lemma TC_transitive2: ∀A,R1,R2.
  98                       transitive2 A R1 R2 → transitive2 A (TC … R1) (TC … R2).
  99 #A #R1 #R2 #HR12 #a1 #a0 #H elim H -a0
 100 [ #a0 #Ha10 #a2 #Ha02
 101   elim (TC_strap2 … HR12 … Ha02 … Ha10) -HR12 -a0 /3 width=3/
 102 | #a #a0 #_ #Ha0 #IHa #a2 #Ha02
 103   elim (TC_strap2 … HR12 … Ha02 … Ha0) -HR12 -a0 #a0 #Ha0 #Ha02
 104   elim (IHa … Ha0) -a /4 width=3/
 105 ]
 106 qed.
 107
 108 definition NF: ∀A. relation A → relation A → predicate A ≝
 109    λA,R,S,a1. ∀a2. R a1 a2 → S a2 a1.
 110
 111 inductive SN (A) (R,S:relation A): predicate A ≝
 112 | SN_intro: ∀a1. (∀a2. R a1 a2 → (S a2 a1 → ⊥) → SN A R S a2) → SN A R S a1
 113 .
 114
 115 lemma NF_to_SN: ∀A,R,S,a. NF A R S a → SN A R S a.
 116 #A #R #S #a1 #Ha1
 117 @SN_intro #a2 #HRa12 #HSa12
 118 elim (HSa12 ?) -HSa12 /2 width=1/
 119 qed.
 120
 121 definition NF_sn: ∀A. relation A → relation A → predicate A ≝
 122    λA,R,S,a2. ∀a1. R a1 a2 → S a2 a1.
 123
 124 inductive SN_sn (A) (R,S:relation A): predicate A ≝
 125 | SN_sn_intro: ∀a2. (∀a1. R a1 a2 → (S a2 a1 → ⊥) → SN_sn A R S a1) → SN_sn A R S a2
 126 .
 127
 128 lemma NF_to_SN_sn: ∀A,R,S,a. NF_sn A R S a → SN_sn A R S a.
 129 #A #R #S #a2 #Ha2
 130 @SN_sn_intro #a1 #HRa12 #HSa12
 131 elim (HSa12 ?) -HSa12 /2 width=1/
 132 qed.