matita/matita/contribs/lambdadelta/basic_2/computation/cprs_cprs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/reduction/lpr_lpr.ma".
  16 include "basic_2/computation/cprs_lift.ma".
  17
  18 (* CONTEXT-SENSITIVE PARALLEL COMPUTATION ON TERMS **************************)
  19
  20 (* Main properties **********************************************************)
  21
  22 (* Basic_1: was: pr3_t *)
  23 (* Basic_1: includes: pr1_t *)
  24 theorem cprs_trans: ∀G,L. Transitive … (cprs G L).
  25 normalize /2 width=3 by trans_TC/ qed-.
  26
  27 (* Basic_1: was: pr3_confluence *)
  28 (* Basic_1: includes: pr1_confluence *)
  29 theorem cprs_conf: ∀G,L. confluent2 … (cprs G L) (cprs G L).
  30 normalize /3 width=3 by cpr_conf, TC_confluent2/ qed-.
  31
  32 theorem cprs_bind: ∀a,I,G,L,V1,V2,T1,T2. ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ➡* T2 → ⦃G, L⦄ ⊢ V1 ➡* V2 →
  33                    ⦃G, L⦄ ⊢ ⓑ{a,I}V1.T1 ➡* ⓑ{a,I}V2.T2.
  34 #a #I #G #L #V1 #V2 #T1 #T2 #HT12 #H @(cprs_ind … H) -V2
  35 /3 width=5 by cprs_trans, cprs_bind_dx/
  36 qed.
  37
  38 (* Basic_1: was: pr3_flat *)
  39 theorem cprs_flat: ∀I,G,L,V1,V2,T1,T2. ⦃G, L⦄ ⊢ T1 ➡* T2 → ⦃G, L⦄ ⊢ V1 ➡* V2 →
  40                    ⦃G, L⦄ ⊢ ⓕ{I}V1.T1 ➡* ⓕ{I}V2.T2.
  41 #I #G #L #V1 #V2 #T1 #T2 #HT12 #H @(cprs_ind … H) -V2
  42 /3 width=3 by cprs_flat_dx, cprs_strap1, cpr_pair_sn/
  43 qed.
  44
  45 theorem cprs_beta_rc: ∀a,G,L,V1,V2,W1,W2,T1,T2.
  46                       ⦃G, L⦄ ⊢ V1 ➡ V2 → ⦃G, L.ⓛW1⦄ ⊢ T1 ➡* T2 → ⦃G, L⦄ ⊢ W1 ➡* W2 →
  47                       ⦃G, L⦄ ⊢ ⓐV1.ⓛ{a}W1.T1 ➡* ⓓ{a}ⓝW2.V2.T2.
  48 #a #G #L #V1 #V2 #W1 #W2 #T1 #T2 #HV12 #HT12 #H @(cprs_ind … H) -W2 /2 width=1 by cprs_beta_dx/
  49 #W #W2 #_ #HW2 #IHW1 (**) (* fulla uto too slow 14s *)
  50 @(cprs_trans … IHW1) -IHW1 /3 width=1 by cprs_flat_dx, cprs_bind/
  51 qed.
  52
  53 theorem cprs_beta: ∀a,G,L,V1,V2,W1,W2,T1,T2.
  54                    ⦃G, L.ⓛW1⦄ ⊢ T1 ➡* T2 → ⦃G, L⦄ ⊢ W1 ➡* W2 → ⦃G, L⦄ ⊢ V1 ➡* V2 →
  55                    ⦃G, L⦄ ⊢ ⓐV1.ⓛ{a}W1.T1 ➡* ⓓ{a}ⓝW2.V2.T2.
  56 #a #G #L #V1 #V2 #W1 #W2 #T1 #T2 #HT12 #HW12 #H @(cprs_ind … H) -V2 /2 width=1 by cprs_beta_rc/
  57 #V #V2 #_ #HV2 #IHV1
  58 @(cprs_trans … IHV1) -IHV1 /3 width=1 by cprs_flat_sn, cprs_bind/
  59 qed.
  60
  61 theorem cprs_theta_rc: ∀a,G,L,V1,V,V2,W1,W2,T1,T2.
  62                        ⦃G, L⦄ ⊢ V1 ➡ V → ⇧[0, 1] V ≡ V2 → ⦃G, L.ⓓW1⦄ ⊢ T1 ➡* T2 →
  63                        ⦃G, L⦄ ⊢ W1 ➡* W2 → ⦃G, L⦄ ⊢ ⓐV1.ⓓ{a}W1.T1 ➡* ⓓ{a}W2.ⓐV2.T2.
  64 #a #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #HV1 #HV2 #HT12 #H @(cprs_ind … H) -W2
  65 /3 width=5 by cprs_trans, cprs_theta_dx, cprs_bind_dx/
  66 qed.
  67
  68 theorem cprs_theta: ∀a,G,L,V1,V,V2,W1,W2,T1,T2.
  69                     ⇧[0, 1] V ≡ V2 → ⦃G, L⦄ ⊢ W1 ➡* W2 → ⦃G, L.ⓓW1⦄ ⊢ T1 ➡* T2 →
  70                     ⦃G, L⦄ ⊢ V1 ➡* V → ⦃G, L⦄ ⊢ ⓐV1.ⓓ{a}W1.T1 ➡* ⓓ{a}W2.ⓐV2.T2.
  71 #a #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #HV2 #HW12 #HT12 #H @(cprs_ind_dx … H) -V1
  72 /3 width=3 by cprs_trans, cprs_theta_rc, cprs_flat_dx/
  73 qed.
  74
  75 (* Advanced inversion lemmas ************************************************)
  76
  77 (* Basic_1: was pr3_gen_appl *)
  78 lemma cprs_inv_appl1: ∀G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓐV1.T1 ➡* U2 →
  79                       ∨∨ ∃∃V2,T2.       ⦃G, L⦄ ⊢ V1 ➡* V2 & ⦃G, L⦄ ⊢ T1 ➡* T2 &
  80                                         U2 = ⓐV2. T2
  81                        | ∃∃a,W,T.       ⦃G, L⦄ ⊢ T1 ➡* ⓛ{a}W.T &
  82                                         ⦃G, L⦄ ⊢ ⓓ{a}ⓝW.V1.T ➡* U2
  83                        | ∃∃a,V0,V2,V,T. ⦃G, L⦄ ⊢ V1 ➡* V0 & ⇧[0,1] V0 ≡ V2 &
  84                                         ⦃G, L⦄ ⊢ T1 ➡* ⓓ{a}V.T &
  85                                         ⦃G, L⦄ ⊢ ⓓ{a}V.ⓐV2.T ➡* U2.
  86 #G #L #V1 #T1 #U2 #H @(cprs_ind … H) -U2 /3 width=5 by or3_intro0, ex3_2_intro/
  87 #U #U2 #_ #HU2 * *
  88 [ #V0 #T0 #HV10 #HT10 #H destruct
  89   elim (cpr_inv_appl1 … HU2) -HU2 *
  90   [ #V2 #T2 #HV02 #HT02 #H destruct /4 width=5 by cprs_strap1, or3_intro0, ex3_2_intro/
  91   | #a #V2 #W #W2 #T #T2 #HV02 #HW2 #HT2 #H1 #H2 destruct
  92     lapply (cprs_strap1 … HV10 … HV02) -V0 #HV12
  93     lapply (lsubr_cpr_trans … HT2 (L.ⓓⓝW.V1) ?) -HT2
  94     /5 width=5 by cprs_bind, cprs_flat_dx, cpr_cprs, lsubr_beta, ex2_3_intro, or3_intro1/
  95   | #a #V #V2 #W0 #W2 #T #T2 #HV0 #HV2 #HW02 #HT2 #H1 #H2 destruct
  96     /5 width=10 by cprs_flat_sn, cprs_bind_dx, cprs_strap1, ex4_5_intro, or3_intro2/
  97   ]
  98 | /4 width=9 by cprs_strap1, or3_intro1, ex2_3_intro/
  99 | /4 width=11 by cprs_strap1, or3_intro2, ex4_5_intro/
 100 ]
 101 qed-.
 102
 103 (* Properties concerning sn parallel reduction on local environments ********)
 104
 105 (* Basic_1: was just: pr3_pr2_pr2_t *)
 106 (* Basic_1: includes: pr3_pr0_pr2_t *)
 107 lemma lpr_cpr_trans: ∀G. s_r_transitive … (cpr G) (λ_. lpr G).
 108 #G #L2 #T1 #T2 #HT12 elim HT12 -G -L2 -T1 -T2
 109 [ /2 width=3 by/
 110 | #G #L2 #K2 #V0 #V2 #W2 #i #HLK2 #_ #HVW2 #IHV02 #L1 #HL12
 111   elim (lpr_drop_trans_O1 … HL12 … HLK2) -L2 #X #HLK1 #H
 112   elim (lpr_inv_pair2 … H) -H #K1 #V1 #HK12 #HV10 #H destruct
 113   /4 width=6 by cprs_strap2, cprs_delta/
 114 |3,7: /4 width=1 by lpr_pair, cprs_bind, cprs_beta/
 115 |4,6: /3 width=1 by cprs_flat, cprs_eps/
 116 |5,8: /4 width=3 by lpr_pair, cprs_zeta, cprs_theta, cprs_strap1/
 117 ]
 118 qed-.
 119
 120 lemma cpr_bind2: ∀G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ➡ V2 → ∀I,T1,T2. ⦃G, L.ⓑ{I}V2⦄ ⊢ T1 ➡ T2 →
 121                  ∀a. ⦃G, L⦄ ⊢ ⓑ{a,I}V1.T1 ➡* ⓑ{a,I}V2.T2.
 122 /4 width=5 by lpr_cpr_trans, cprs_bind_dx, lpr_pair/ qed.
 123
 124 (* Advanced properties ******************************************************)
 125
 126 (* Basic_1: was only: pr3_pr2_pr3_t pr3_wcpr0_t *)
 127 lemma lpr_cprs_trans: ∀G. s_rs_transitive … (cpr G) (λ_. lpr G).
 128 #G @s_r_trans_LTC1 /2 width=3 by lpr_cpr_trans/ (**) (* full auto fails *)
 129 qed-.
 130
 131 (* Basic_1: was: pr3_strip *)
 132 (* Basic_1: includes: pr1_strip *)
 133 lemma cprs_strip: ∀G,L. confluent2 … (cprs G L) (cpr G L).
 134 normalize /4 width=3 by cpr_conf, TC_strip1/ qed-.
 135
 136 lemma cprs_lpr_conf_dx: ∀G,L0,T0,T1. ⦃G, L0⦄ ⊢ T0 ➡* T1 → ∀L1. ⦃G, L0⦄ ⊢ ➡ L1 →
 137                         ∃∃T. ⦃G, L1⦄ ⊢ T1 ➡* T & ⦃G, L1⦄ ⊢ T0 ➡* T.
 138 #G #L0 #T0 #T1 #H @(cprs_ind … H) -T1 /2 width=3 by ex2_intro/
 139 #T #T1 #_ #HT1 #IHT0 #L1 #HL01 elim (IHT0 … HL01)
 140 #T2 #HT2 #HT02 elim (lpr_cpr_conf_dx … HT1 … HL01) -L0
 141 #T3 #HT3 #HT13 elim (cprs_strip … HT2 … HT3) -T
 142 /4 width=5 by cprs_strap2, cprs_strap1, ex2_intro/
 143 qed-.
 144
 145 lemma cprs_lpr_conf_sn: ∀G,L0,T0,T1. ⦃G, L0⦄ ⊢ T0 ➡* T1 →
 146                         ∀L1. ⦃G, L0⦄ ⊢ ➡ L1 →
 147                         ∃∃T. ⦃G, L0⦄ ⊢ T1 ➡* T & ⦃G, L1⦄ ⊢ T0 ➡* T.
 148 #G #L0 #T0 #T1 #HT01 #L1 #HL01 elim (cprs_lpr_conf_dx … HT01 … HL01) -HT01
 149 /3 width=3 by lpr_cprs_trans, ex2_intro/
 150 qed-.
 151
 152 lemma cprs_bind2_dx: ∀G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ➡ V2 →
 153                      ∀I,T1,T2. ⦃G, L.ⓑ{I}V2⦄ ⊢ T1 ➡* T2 →
 154                      ∀a. ⦃G, L⦄ ⊢ ⓑ{a,I}V1.T1 ➡* ⓑ{a,I}V2.T2.
 155 /4 width=5 by lpr_cprs_trans, cprs_bind_dx, lpr_pair/ qed.