matita/matita/contribs/lambdadelta/basic_2/computation/cpxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/predstar_6.ma".
  16 include "basic_2/reduction/cnx.ma".
  17 include "basic_2/computation/cprs.ma".
  18
  19 (* CONTEXT-SENSITIVE EXTENDED PARALLEL COMPUTATION ON TERMS *****************)
  20
  21 definition cpxs: ∀h. sd h → relation4 genv lenv term term ≝
  22                  λh,g,G. LTC … (cpx h g G).
  23
  24 interpretation "extended context-sensitive parallel computation (term)"
  25    'PRedStar h g G L T1 T2 = (cpxs h g G L T1 T2).
  26
  27 (* Basic eliminators ********************************************************)
  28
  29 lemma cpxs_ind: ∀h,g,G,L,T1. ∀R:predicate term. R T1 →
  30                 (∀T,T2. ⦃G, L⦄ ⊢ T1 ➡*[h, g] T → ⦃G, L⦄ ⊢ T ➡[h, g] T2 → R T → R T2) →
  31                 ∀T2. ⦃G, L⦄ ⊢ T1 ➡*[h, g] T2 → R T2.
  32 #h #g #L #G #T1 #R #HT1 #IHT1 #T2 #HT12
  33 @(TC_star_ind … HT1 IHT1 … HT12) //
  34 qed-.
  35
  36 lemma cpxs_ind_dx: ∀h,g,G,L,T2. ∀R:predicate term. R T2 →
  37                    (∀T1,T. ⦃G, L⦄ ⊢ T1 ➡[h, g] T → ⦃G, L⦄ ⊢ T ➡*[h, g] T2 → R T → R T1) →
  38                    ∀T1. ⦃G, L⦄ ⊢ T1 ➡*[h, g] T2 → R T1.
  39 #h #g #G #L #T2 #R #HT2 #IHT2 #T1 #HT12
  40 @(TC_star_ind_dx … HT2 IHT2 … HT12) //
  41 qed-.
  42
  43 (* Basic properties *********************************************************)
  44
  45 lemma cpxs_refl: ∀h,g,G,L,T. ⦃G, L⦄ ⊢ T ➡*[h, g] T.
  46 /2 width=1 by inj/ qed.
  47
  48 lemma cpx_cpxs: ∀h,g,G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡[h, g] T2 → ⦃G, L⦄ ⊢ T1 ➡*[h, g] T2.
  49 /2 width=1 by inj/ qed.
  50
  51 lemma cpxs_strap1: ∀h,g,G,L,T1,T. ⦃G, L⦄ ⊢ T1 ➡*[h, g] T →
  52                    ∀T2. ⦃G, L⦄ ⊢ T ➡[h, g] T2 → ⦃G, L⦄ ⊢ T1 ➡*[h, g] T2.
  53 normalize /2 width=3 by step/ qed.
  54
  55 lemma cpxs_strap2: ∀h,g,G,L,T1,T. ⦃G, L⦄ ⊢ T1 ➡[h, g] T →
  56                    ∀T2. ⦃G, L⦄ ⊢ T ➡*[h, g] T2 → ⦃G, L⦄ ⊢ T1 ➡*[h, g] T2.
  57 normalize /2 width=3 by TC_strap/ qed.
  58
  59 lemma lsubr_cpxs_trans: ∀h,g,G. lsub_trans … (cpxs h g G) lsubr.
  60 /3 width=5 by lsubr_cpx_trans, LTC_lsub_trans/
  61 qed-.
  62
  63 lemma cprs_cpxs: ∀h,g,G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡* T2 → ⦃G, L⦄ ⊢ T1 ➡*[h, g] T2.
  64 #h #g #G #L #T1 #T2 #H @(cprs_ind … H) -T2 /3 width=3 by cpxs_strap1, cpr_cpx/
  65 qed.
  66
  67 lemma cpxs_sort: ∀h,g,G,L,k,d1. deg h g k d1 →
  68                  ∀d2. d2 ≤ d1 → ⦃G, L⦄ ⊢ ⋆k ➡*[h, g] ⋆((next h)^d2 k).
  69 #h #g #G #L #k #d1 #Hkd1 #d2 @(nat_ind_plus … d2) -d2 /2 width=1 by cpx_cpxs/
  70 #d2 #IHd2 #Hd21 >iter_SO
  71 @(cpxs_strap1 … (⋆(iter d2 ℕ (next h) k)))
  72 [ /3 width=3 by lt_to_le/
  73 | @(cpx_st … (d1-d2-1)) <plus_minus_m_m
  74   /2 width=1 by deg_iter, monotonic_le_minus_r/
  75 ]
  76 qed.
  77
  78 lemma cpxs_bind_dx: ∀h,g,G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ➡[h, g] V2 →
  79                     ∀I,T1,T2. ⦃G, L. ⓑ{I}V1⦄ ⊢ T1 ➡*[h, g] T2 →
  80                     ∀a. ⦃G, L⦄ ⊢ ⓑ{a,I}V1.T1 ➡*[h, g] ⓑ{a,I}V2.T2.
  81 #h #g #G #L #V1 #V2 #HV12 #I #T1 #T2 #HT12 #a @(cpxs_ind_dx … HT12) -T1
  82 /3 width=3 by cpxs_strap2, cpx_cpxs, cpx_pair_sn, cpx_bind/
  83 qed.
  84
  85 lemma cpxs_flat_dx: ∀h,g,G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ➡[h, g] V2 →
  86                     ∀T1,T2. ⦃G, L⦄ ⊢ T1 ➡*[h, g] T2 →
  87                     ∀I. ⦃G, L⦄ ⊢ ⓕ{I}V1.T1 ➡*[h, g] ⓕ{I}V2.T2.
  88 #h #g #G #L #V1 #V2 #HV12 #T1 #T2 #HT12 @(cpxs_ind … HT12) -T2
  89 /3 width=5 by cpxs_strap1, cpx_cpxs, cpx_pair_sn, cpx_flat/
  90 qed.
  91
  92 lemma cpxs_flat_sn: ∀h,g,G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡[h, g] T2 →
  93                     ∀V1,V2. ⦃G, L⦄ ⊢ V1 ➡*[h, g] V2 →
  94                     ∀I. ⦃G, L⦄ ⊢ ⓕ{I}V1.T1 ➡*[h, g] ⓕ{I}V2.T2.
  95 #h #g #G #L #T1 #T2 #HT12 #V1 #V2 #H @(cpxs_ind … H) -V2
  96 /3 width=5 by cpxs_strap1, cpx_cpxs, cpx_pair_sn, cpx_flat/
  97 qed.
  98
  99 lemma cpxs_pair_sn: ∀h,g,I,G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ➡*[h, g] V2 →
 100                     ∀T. ⦃G, L⦄ ⊢ ②{I}V1.T ➡*[h, g] ②{I}V2.T.
 101 #h #g #I #G #L #V1 #V2 #H @(cpxs_ind … H) -V2
 102 /3 width=3 by cpxs_strap1, cpx_pair_sn/
 103 qed.
 104
 105 lemma cpxs_zeta: ∀h,g,G,L,V,T1,T,T2. ⬆[0, 1] T2 ≡ T →
 106                  ⦃G, L.ⓓV⦄ ⊢ T1 ➡*[h, g] T → ⦃G, L⦄ ⊢ +ⓓV.T1 ➡*[h, g] T2.
 107 #h #g #G #L #V #T1 #T #T2 #HT2 #H @(cpxs_ind_dx … H) -T1
 108 /3 width=3 by cpxs_strap2, cpx_cpxs, cpx_bind, cpx_zeta/
 109 qed.
 110
 111 lemma cpxs_eps: ∀h,g,G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡*[h, g] T2 →
 112                 ∀V. ⦃G, L⦄ ⊢ ⓝV.T1 ➡*[h, g] T2.
 113 #h #g #G #L #T1 #T2 #H @(cpxs_ind … H) -T2
 114 /3 width=3 by cpxs_strap1, cpx_cpxs, cpx_eps/
 115 qed.
 116
 117 lemma cpxs_ct: ∀h,g,G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ➡*[h, g] V2 →
 118                ∀T. ⦃G, L⦄ ⊢ ⓝV1.T ➡*[h, g] V2.
 119 #h #g #G #L #V1 #V2 #H @(cpxs_ind … H) -V2
 120 /3 width=3 by cpxs_strap1, cpx_cpxs, cpx_ct/
 121 qed.
 122
 123 lemma cpxs_beta_dx: ∀h,g,a,G,L,V1,V2,W1,W2,T1,T2.
 124                     ⦃G, L⦄ ⊢ V1 ➡[h, g] V2 → ⦃G, L.ⓛW1⦄ ⊢ T1 ➡*[h, g] T2 → ⦃G, L⦄ ⊢ W1 ➡[h, g] W2 →
 125                     ⦃G, L⦄ ⊢ ⓐV1.ⓛ{a}W1.T1 ➡*[h, g] ⓓ{a}ⓝW2.V2.T2.
 126 #h #g #a #G #L #V1 #V2 #W1 #W2 #T1 #T2 #HV12 * -T2
 127 /4 width=7 by cpx_cpxs, cpxs_strap1, cpxs_bind_dx, cpxs_flat_dx, cpx_beta/
 128 qed.
 129
 130 lemma cpxs_theta_dx: ∀h,g,a,G,L,V1,V,V2,W1,W2,T1,T2.
 131                      ⦃G, L⦄ ⊢ V1 ➡[h, g] V → ⬆[0, 1] V ≡ V2 → ⦃G, L.ⓓW1⦄ ⊢ T1 ➡*[h, g] T2 →
 132                      ⦃G, L⦄ ⊢ W1 ➡[h, g] W2 → ⦃G, L⦄ ⊢ ⓐV1.ⓓ{a}W1.T1 ➡*[h, g] ⓓ{a}W2.ⓐV2.T2.
 133 #h #g #a #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #HV1 #HV2 * -T2
 134 /4 width=9 by cpx_cpxs, cpxs_strap1, cpxs_bind_dx, cpxs_flat_dx, cpx_theta/
 135 qed.
 136
 137 (* Basic inversion lemmas ***************************************************)
 138
 139 lemma cpxs_inv_sort1: ∀h,g,G,L,U2,k. ⦃G, L⦄ ⊢ ⋆k ➡*[h, g] U2 →
 140                       ∃∃n,d. deg h g k (n+d) & U2 = ⋆((next h)^n k).
 141 #h #g #G #L #U2 #k #H @(cpxs_ind … H) -U2
 142 [ elim (deg_total h g k) #d #Hkd
 143   @(ex2_2_intro … 0 … Hkd) -Hkd //
 144 | #U #U2 #_ #HU2 * #n #d #Hknd #H destruct
 145   elim (cpx_inv_sort1 … HU2) -HU2
 146   [ #H destruct /2 width=4 by ex2_2_intro/
 147   | * #d0 #Hkd0 #H destruct -d
 148     @(ex2_2_intro … (n+1) d0) /2 width=1 by deg_inv_prec/ >iter_SO //
 149   ]
 150 ]
 151 qed-.
 152
 153 lemma cpxs_inv_cast1: ∀h,g,G,L,W1,T1,U2. ⦃G, L⦄ ⊢ ⓝW1.T1 ➡*[h, g] U2 →
 154                       ∨∨ ∃∃W2,T2. ⦃G, L⦄ ⊢ W1 ➡*[h, g] W2 & ⦃G, L⦄ ⊢ T1 ➡*[h, g] T2 & U2 = ⓝW2.T2
 155                        | ⦃G, L⦄ ⊢ T1 ➡*[h, g] U2
 156                        | ⦃G, L⦄ ⊢ W1 ➡*[h, g] U2.
 157 #h #g #G #L #W1 #T1 #U2 #H @(cpxs_ind … H) -U2 /3 width=5 by or3_intro0, ex3_2_intro/
 158 #U2 #U #_ #HU2 * /3 width=3 by cpxs_strap1, or3_intro1, or3_intro2/ *
 159 #W #T #HW1 #HT1 #H destruct
 160 elim (cpx_inv_cast1 … HU2) -HU2 /3 width=3 by cpxs_strap1, or3_intro1, or3_intro2/ *
 161 #W2 #T2 #HW2 #HT2 #H destruct
 162 lapply (cpxs_strap1 … HW1 … HW2) -W
 163 lapply (cpxs_strap1 … HT1 … HT2) -T /3 width=5 by or3_intro0, ex3_2_intro/
 164 qed-.
 165
 166 lemma cpxs_inv_cnx1: ∀h,g,G,L,T,U. ⦃G, L⦄ ⊢ T ➡*[h, g] U → ⦃G, L⦄ ⊢ ➡[h, g] 𝐍⦃T⦄ → T = U.
 167 #h #g #G #L #T #U #H @(cpxs_ind_dx … H) -T //
 168 #T0 #T #H1T0 #_ #IHT #H2T0
 169 lapply (H2T0 … H1T0) -H1T0 #H destruct /2 width=1 by/
 170 qed-.
 171
 172 lemma cpxs_neq_inv_step_sn: ∀h,g,G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡*[h, g] T2 → (T1 = T2 → ⊥) →
 173                             ∃∃T. ⦃G, L⦄ ⊢ T1 ➡[h, g] T & T1 = T → ⊥ & ⦃G, L⦄ ⊢ T ➡*[h, g] T2.
 174 #h #g #G #L #T1 #T2 #H @(cpxs_ind_dx … H) -T1
 175 [ #H elim H -H //
 176 | #T1 #T #H1 #H2 #IH2 #H12 elim (eq_term_dec T1 T) #H destruct
 177   [ -H1 -H2 /3 width=1 by/
 178   | -IH2 /3 width=4 by ex3_intro/ (**) (* auto fails without clear *)
 179   ]
 180 ]
 181 qed-.