matita/matita/contribs/lambdadelta/basic_2/computation/cpxs_cpxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/computation/cpxs_lift.ma".
  16
  17 (* CONTEXT-SENSITIVE EXTENDED PARALLEL COMPUTATION ON TERMS *****************)
  18
  19 (* Main properties **********************************************************)
  20
  21 theorem cpxs_trans: ∀h,g,G,L. Transitive … (cpxs h g G L).
  22 normalize /2 width=3 by trans_TC/ qed-.
  23
  24 theorem cpxs_bind: ∀h,g,a,I,G,L,V1,V2,T1,T2. ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ➡*[h, g] T2 →
  25                    ⦃G, L⦄ ⊢ V1 ➡*[h, g] V2 →
  26                    ⦃G, L⦄ ⊢ ⓑ{a,I}V1.T1 ➡*[h, g] ⓑ{a,I}V2.T2.
  27 #h #g #a #I #G #L #V1 #V2 #T1 #T2 #HT12 #H @(cpxs_ind … H) -V2
  28 /3 width=5 by cpxs_trans, cpxs_bind_dx/
  29 qed.
  30
  31 theorem cpxs_flat: ∀h,g,I,G,L,V1,V2,T1,T2. ⦃G, L⦄ ⊢ T1 ➡*[h, g] T2 →
  32                    ⦃G, L⦄ ⊢ V1 ➡*[h, g] V2 →
  33                    ⦃G, L⦄ ⊢ ⓕ{I}V1.T1 ➡*[h, g] ⓕ{I}V2.T2.
  34 #h #g #I #G #L #V1 #V2 #T1 #T2 #HT12 #H @(cpxs_ind … H) -V2
  35 /3 width=5 by cpxs_trans, cpxs_flat_dx/
  36 qed.
  37
  38 theorem cpxs_beta_rc: ∀h,g,a,G,L,V1,V2,W1,W2,T1,T2.
  39                       ⦃G, L⦄ ⊢ V1 ➡[h, g] V2 → ⦃G, L.ⓛW1⦄ ⊢ T1 ➡*[h, g] T2 → ⦃G, L⦄ ⊢ W1 ➡*[h, g] W2 →
  40                       ⦃G, L⦄ ⊢ ⓐV1.ⓛ{a}W1.T1 ➡*[h, g] ⓓ{a}ⓝW2.V2.T2.
  41 #h #g #a #G #L #V1 #V2 #W1 #W2 #T1 #T2 #HV12 #HT12 #H @(cpxs_ind … H) -W2
  42 /4 width=5 by cpxs_trans, cpxs_beta_dx, cpxs_bind_dx, cpx_pair_sn/
  43 qed.
  44
  45 theorem cpxs_beta: ∀h,g,a,G,L,V1,V2,W1,W2,T1,T2.
  46                    ⦃G, L.ⓛW1⦄ ⊢ T1 ➡*[h, g] T2 → ⦃G, L⦄ ⊢ W1 ➡*[h, g] W2 → ⦃G, L⦄ ⊢ V1 ➡*[h, g] V2 →
  47                    ⦃G, L⦄ ⊢ ⓐV1.ⓛ{a}W1.T1 ➡*[h, g] ⓓ{a}ⓝW2.V2.T2.
  48 #h #g #a #G #L #V1 #V2 #W1 #W2 #T1 #T2 #HT12 #HW12 #H @(cpxs_ind … H) -V2
  49 /4 width=5 by cpxs_trans, cpxs_beta_rc, cpxs_bind_dx, cpx_flat/
  50 qed.
  51
  52 theorem cpxs_theta_rc: ∀h,g,a,G,L,V1,V,V2,W1,W2,T1,T2.
  53                        ⦃G, L⦄ ⊢ V1 ➡[h, g] V → ⇧[0, 1] V ≡ V2 →
  54                        ⦃G, L.ⓓW1⦄ ⊢ T1 ➡*[h, g] T2 → ⦃G, L⦄ ⊢ W1 ➡*[h, g] W2 →
  55                        ⦃G, L⦄ ⊢ ⓐV1.ⓓ{a}W1.T1 ➡*[h, g] ⓓ{a}W2.ⓐV2.T2.
  56 #h #g #a #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #HV1 #HV2 #HT12 #H @(cpxs_ind … H) -W2
  57 /3 width=5 by cpxs_trans, cpxs_theta_dx, cpxs_bind_dx/
  58 qed.
  59
  60 theorem cpxs_theta: ∀h,g,a,G,L,V1,V,V2,W1,W2,T1,T2.
  61                     ⇧[0, 1] V ≡ V2 → ⦃G, L⦄ ⊢ W1 ➡*[h, g] W2 →
  62                     ⦃G, L.ⓓW1⦄ ⊢ T1 ➡*[h, g] T2 → ⦃G, L⦄ ⊢ V1 ➡*[h, g] V →
  63                     ⦃G, L⦄ ⊢ ⓐV1.ⓓ{a}W1.T1 ➡*[h, g] ⓓ{a}W2.ⓐV2.T2.
  64 #h #g #a #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #HV2 #HW12 #HT12 #H @(TC_ind_dx … V1 H) -V1
  65 /3 width=5 by cpxs_trans, cpxs_theta_rc, cpxs_flat_dx/
  66 qed.
  67
  68 (* Advanced inversion lemmas ************************************************)
  69
  70 lemma cpxs_inv_appl1: ∀h,g,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓐV1.T1 ➡*[h, g] U2 →
  71                       ∨∨ ∃∃V2,T2.       ⦃G, L⦄ ⊢ V1 ➡*[h, g] V2 & ⦃G, L⦄ ⊢ T1 ➡*[h, g] T2 &
  72                                         U2 = ⓐV2. T2
  73                        | ∃∃a,W,T.       ⦃G, L⦄ ⊢ T1 ➡*[h, g] ⓛ{a}W.T & ⦃G, L⦄ ⊢ ⓓ{a}ⓝW.V1.T ➡*[h, g] U2
  74                        | ∃∃a,V0,V2,V,T. ⦃G, L⦄ ⊢ V1 ➡*[h, g] V0 & ⇧[0,1] V0 ≡ V2 &
  75                                         ⦃G, L⦄ ⊢ T1 ➡*[h, g] ⓓ{a}V.T & ⦃G, L⦄ ⊢ ⓓ{a}V.ⓐV2.T ➡*[h, g] U2.
  76 #h #g #G #L #V1 #T1 #U2 #H @(cpxs_ind … H) -U2 [ /3 width=5 by or3_intro0, ex3_2_intro/ ]
  77 #U #U2 #_ #HU2 * *
  78 [ #V0 #T0 #HV10 #HT10 #H destruct
  79   elim (cpx_inv_appl1 … HU2) -HU2 *
  80   [ #V2 #T2 #HV02 #HT02 #H destruct /4 width=5 by cpxs_strap1, or3_intro0, ex3_2_intro/
  81   | #a #V2 #W #W2 #T #T2 #HV02 #HW2 #HT2 #H1 #H2 destruct
  82     lapply (cpxs_strap1 … HV10 … HV02) -V0 #HV12
  83     lapply (lsubr_cpx_trans … HT2 (L.ⓓⓝW.V1) ?) -HT2
  84     /5 width=5 by cpxs_bind, cpxs_flat_dx, cpx_cpxs, lsubr_abst, ex2_3_intro, or3_intro1/
  85   | #a #V #V2 #W0 #W2 #T #T2 #HV0 #HV2 #HW02 #HT2 #H1 #H2 destruct
  86     /5 width=10 by cpxs_flat_sn, cpxs_bind_dx, cpxs_strap1, ex4_5_intro, or3_intro2/
  87   ]
  88 | /4 width=9 by cpxs_strap1, or3_intro1, ex2_3_intro/
  89 | /4 width=11 by cpxs_strap1, or3_intro2, ex4_5_intro/
  90 ]
  91 qed-.
  92
  93 (* Properties on sn extended parallel reduction for local environments ******)
  94
  95 lemma llpx_cpx_trans: ∀h,g,G. s_r_transitive … (cpx h g G) (llpx h g G 0).
  96 #h #g #G #L2 #T1 #T2 #HT12 elim HT12 -G -L2 -T1 -T2
  97 [ /2 width=3 by/
  98 | /3 width=2 by cpx_cpxs, cpx_sort/
  99 | #I #G #L2 #K2 #V0 #V2 #W2 #i #HLK2 #_ #HVW2 #IHV02 #L1 #HL12
 100   elim (llpx_inv_lref_ge_dx … HL12 … HLK2) -L2
 101   /5 width=8 by cpxs_delta, cpxs_strap2, llpx_cpx_conf/
 102 | #a #I #G #L2 #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #L1 #HL12
 103   elim (llpx_inv_bind_O … HL12) -HL12 /4 width=1 by cpxs_bind/
 104 | #I #G #L2 #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #L1 #HL12
 105   elim (llpx_inv_flat … HL12) -HL12 /3 width=1 by cpxs_flat/
 106 | #G #L2 #V2 #T1 #T #T2 #_ #HT2 #IHT1 #L1 #HL12
 107   elim (llpx_inv_bind_O … HL12) /3 width=3 by cpxs_zeta/
 108 | #G #L2 #V2 #T1 #T2 #HT12 #IHT12 #L1 #HL12
 109   elim (llpx_inv_flat … HL12) /3 width=1 by cpxs_tau/
 110 | #G #L2 #V1 #V2 #T2 #HV12 #IHV12 #L1 #HL12
 111   elim (llpx_inv_flat … HL12) /3 width=1 by cpxs_ti/
 112 | #a #G #L2 #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #IHV12 #IHW12 #IHT12 #L1 #HL12
 113   elim (llpx_inv_flat … HL12) -HL12 #HV1 #HL12
 114   elim (llpx_inv_bind_O … HL12) /3 width=3 by cpxs_beta/
 115 | #a #G #L2 #V1 #V #V2 #W1 #W2 #T1 #T2 #_ #HV2 #_ #_ #IHV1 #IHW12 #IHT12 #L1 #HL12
 116   elim (llpx_inv_flat … HL12) -HL12 #HV1 #HL12
 117   elim (llpx_inv_bind_O … HL12) /3 width=3 by cpxs_theta/
 118 ]
 119 qed-.
 120
 121 lemma cpx_bind2: ∀h,g,G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ➡[h, g] V2 →
 122                  ∀I,T1,T2. ⦃G, L.ⓑ{I}V2⦄ ⊢ T1 ➡[h, g] T2 →
 123                  ∀a. ⦃G, L⦄ ⊢ ⓑ{a,I}V1.T1 ➡*[h, g] ⓑ{a,I}V2.T2.
 124 /4 width=9 by llpx_cpx_trans, cpxs_bind_dx, llpx_bind_repl_O/ qed.
 125
 126 (* Advanced properties ******************************************************)
 127
 128 lemma cpxs_llpx_trans: ∀h,g,G. s_rs_transitive … (cpx h g G) (llpx h g G 0).
 129 #h #g #G @s_r_trans_LTC1 /2 width=3 by llpx_cpx_trans, llpx_cpx_conf/ (**) (* full auto fails here but works in cprs_cprs *)
 130 qed-.
 131
 132 lemma cpxs_bind2_dx: ∀h,g,G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ➡[h, g] V2 →
 133                      ∀I,T1,T2. ⦃G, L.ⓑ{I}V2⦄ ⊢ T1 ➡*[h, g] T2 →
 134                      ∀a. ⦃G, L⦄ ⊢ ⓑ{a,I}V1.T1 ➡*[h, g] ⓑ{a,I}V2.T2.
 135 /4 width=9 by cpxs_llpx_trans, cpxs_bind_dx, llpx_bind_repl_O/ qed.
 136
 137 (* Properties on supclosure *************************************************)
 138
 139 lemma fqu_cpxs_trans_neq: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃ ⦃G2, L2, T2⦄ →
 140                           ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡*[h, g] U2 → (T2 = U2 → ⊥) →
 141                           ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ➡*[h, g] U1 & T1 = U1 → ⊥ & ⦃G1, L1, U1⦄ ⊃ ⦃G2, L2, U2⦄.
 142 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H elim H -G1 -G2 -L1 -L2 -T1 -T2
 143 [ #I #G #L #V1 #V2 #HV12 #_ elim (lift_total V2 0 1)
 144   #U2 #HVU2 @(ex3_intro … U2)
 145   [1,3: /3 width=7 by fqu_drop, cpxs_delta, ldrop_pair, ldrop_drop/
 146   | #H destruct /2 width=7 by lift_inv_lref2_be/
 147   ]
 148 | #I #G #L #V1 #T #V2 #HV12 #H @(ex3_intro … (②{I}V2.T))
 149   [1,3: /2 width=4 by fqu_pair_sn, cpxs_pair_sn/
 150   | #H0 destruct /2 width=1 by/
 151   ]
 152 | #a #I #G #L #V #T1 #T2 #HT12 #H @(ex3_intro … (ⓑ{a,I}V.T2))
 153   [1,3: /2 width=4 by fqu_bind_dx, cpxs_bind/
 154   | #H0 destruct /2 width=1 by/
 155   ]
 156 | #I #G #L #V #T1 #T2 #HT12 #H @(ex3_intro … (ⓕ{I}V.T2))
 157   [1,3: /2 width=4 by fqu_flat_dx, cpxs_flat/
 158   | #H0 destruct /2 width=1 by/
 159   ]
 160 | #G #L #K #T1 #U1 #e #HLK #HTU1 #T2 #HT12 #H elim (lift_total T2 0 (e+1))
 161   #U2 #HTU2 @(ex3_intro … U2)
 162   [1,3: /2 width=10 by cpxs_lift, fqu_drop/
 163   | #H0 destruct /3 width=5 by lift_inj/
 164 ]
 165 qed-.
 166
 167 lemma fquq_cpxs_trans_neq: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃⸮ ⦃G2, L2, T2⦄ →
 168                            ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡*[h, g] U2 → (T2 = U2 → ⊥) →
 169                            ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ➡*[h, g] U1 & T1 = U1 → ⊥ & ⦃G1, L1, U1⦄ ⊃⸮ ⦃G2, L2, U2⦄.
 170 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H12 #U2 #HTU2 #H elim (fquq_inv_gen … H12) -H12
 171 [ #H12 elim (fqu_cpxs_trans_neq … H12 … HTU2 H) -T2
 172   /3 width=4 by fqu_fquq, ex3_intro/
 173 | * #HG #HL #HT destruct /3 width=4 by ex3_intro/
 174 ]
 175 qed-.
 176
 177 lemma fqup_cpxs_trans_neq: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃+ ⦃G2, L2, T2⦄ →
 178                            ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡*[h, g] U2 → (T2 = U2 → ⊥) →
 179                            ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ➡*[h, g] U1 & T1 = U1 → ⊥ & ⦃G1, L1, U1⦄ ⊃+ ⦃G2, L2, U2⦄.
 180 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind_dx … H) -G1 -L1 -T1
 181 [ #G1 #L1 #T1 #H12 #U2 #HTU2 #H elim (fqu_cpxs_trans_neq … H12 … HTU2 H) -T2
 182   /3 width=4 by fqu_fqup, ex3_intro/
 183 | #G #G1 #L #L1 #T #T1 #H1 #_ #IH12 #U2 #HTU2 #H elim (IH12 … HTU2 H) -T2
 184   #U1 #HTU1 #H #H12 elim (fqu_cpxs_trans_neq … H1 … HTU1 H) -T1
 185   /3 width=8 by fqup_strap2, ex3_intro/
 186 ]
 187 qed-.
 188
 189 lemma fqus_cpxs_trans_neq: ∀h,g,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ⊃* ⦃G2, L2, T2⦄ →
 190                            ∀U2. ⦃G2, L2⦄ ⊢ T2 ➡*[h, g] U2 → (T2 = U2 → ⊥) →
 191                            ∃∃U1. ⦃G1, L1⦄ ⊢ T1 ➡*[h, g] U1 & T1 = U1 → ⊥ & ⦃G1, L1, U1⦄ ⊃* ⦃G2, L2, U2⦄.
 192 #h #g #G1 #G2 #L1 #L2 #T1 #T2 #H12 #U2 #HTU2 #H elim (fqus_inv_gen … H12) -H12
 193 [ #H12 elim (fqup_cpxs_trans_neq … H12 … HTU2 H) -T2
 194   /3 width=4 by fqup_fqus, ex3_intro/
 195 | * #HG #HL #HT destruct /3 width=4 by ex3_intro/
 196 ]
 197 qed-.